Add Utilities.sorted_list_of_model_attributes

docs/src/submodules/Utilities/reference.md

@@ -80,6 +80,8 @@ Utilities.IndexMap
 Utilities.identity_index_map
 Utilities.ModelFilter
 Utilities.loadfromstring!
+Utilities.sorted_list_of_model_attributes
+Utilities.sorted_list_of_model_attributes_weight
 ```
 
 ## Penalty relaxation

src/Utilities/copy.jl

@@ -9,9 +9,39 @@
 
 include("copy/index_map.jl")
 
-_sort_priority(::Any) = 2
-_sort_priority(::MOI.UserDefinedFunction) = 0
-_sort_priority(::MOI.ObjectiveSense) = 1
+"""
+    sorted_list_of_model_attributes(model::MOI.ModelLike)
+
+Return the vector of [`MOI.ListOfModelAttributesSet`](@ref), except that the
+elements are sorted according to [`sorted_list_of_model_attributes`](@ref).
+
+During [`MOI.copy_to`](@ref), we need to copy [`MOI.UserDefinedFunction`](@ref)s
+first, so that they are in the model before we deal with the objective function
+or the constraints. Similarly, we need to [`MOI.ObjectiveSense`](@ref) to be set
+before [`MOI.ObjectiveFunction`](@ref) so that bridges which depend on the sense
+can be used.
+"""
+function sorted_list_of_model_attributes(model::MOI.ModelLike)
+    attrs = MOI.get(model, MOI.ListOfModelAttributesSet())
+    return sort(attrs; by = sorted_list_of_model_attributes_weight)
+end
+
+"""
+    sorted_list_of_model_attributes_weight(::MOI.AbstractModelAttribute) --> Float64
+
+The weights used to sort elements in [`sorted_list_of_model_attributes`](@ref).
+
+The default weights are:
+
+ * `sorted_list_of_model_attributes_weight(::MOI.UserDefinedFunction) = 0.0`
+ * `sorted_list_of_model_attributes_weight(::MOI.ObjectiveSense) = 10.0`
+ * `sorted_list_of_model_attributes_weight(::MOI.ObjectiveFunction) = 20.0`
+ * `sorted_list_of_model_attributes_weight(::MOI.AbstractModelAttribute) = 30.0`
+"""
+sorted_list_of_model_attributes_weight(::MOI.UserDefinedFunction) = 0.0
+sorted_list_of_model_attributes_weight(::MOI.ObjectiveSense) = 10.0
+sorted_list_of_model_attributes_weight(::MOI.ObjectiveFunction) = 20.0
+sorted_list_of_model_attributes_weight(::MOI.AbstractModelAttribute) = 30.0
 
 """
     pass_attributes(
@@ -27,12 +57,7 @@
     src::MOI.ModelLike,
     index_map::IndexMap,
 )
-    attrs = MOI.get(src, MOI.ListOfModelAttributesSet())
-    # We need to deal with the UserDefinedFunctions first, so that they are in
-    # the model before we deal with the objective function or the constraints.
-    # We also need `ObjectiveSense` to be set before `ObjectiveFunction`.
-    sort!(attrs; by = _sort_priority)
-    for attr in attrs
+    for attr in sorted_list_of_model_attributes(src)
         if !MOI.supports(dest, attr)
             if attr == MOI.Name()
                 continue  # Skipping names is okay.

test/Utilities/copy.jl

@@ -935,6 +935,30 @@ function test_sorted_variable_sets_by_cost_2()
     return
 end
 
+function test_sorted_copy_to()
+    src = MOI.Utilities.UniversalFallback(MOI.Utilities.Model{Float64}())
+    x = MOI.add_variable(src)
+    f = MOI.ScalarNonlinearFunction(:sqr, Any[x])
+    attr_1 = MOI.UserDefinedFunction(:sqr, 1)
+    attr_2 = MOI.ObjectiveSense()
+    attr_3 = MOI.ObjectiveFunction{typeof(f)}()
+    attr_4 = MOI.Name()
+    MOI.set(src, attr_4, "abc")
+    MOI.set(src, attr_1, (sqrt,))
+    MOI.set(src, attr_3, f)
+    MOI.set(src, attr_2, MOI.MAX_SENSE)
+    @test MOI.Utilities.sorted_list_of_model_attributes(src) ==
+          [attr_1, attr_2, attr_3, attr_4]
+    dest = MOI.Utilities.UniversalFallback(MOI.Utilities.Model{Float64}())
+    index_map = MOI.copy_to(dest, src)
+    @test MOI.get(dest, attr_1) == (sqrt,)
+    @test MOI.get(dest, attr_2) == MOI.MAX_SENSE
+    g = MOI.ScalarNonlinearFunction(:sqr, Any[index_map[x]])
+    @test ≈(g, MOI.get(dest, attr_3))
+    @test MOI.get(dest, attr_4) == "abc"
+    return
+end
+
 end  # module
 
 TestCopy.runtests()