[ML] Portability improvements

3rd_party/CMakeLists.txt

@@ -28,7 +28,7 @@ add_custom_target(
     eigen
     DEPENDS 3rd_party.sh pull-eigen.sh
     COMMAND bash -c "./3rd_party.sh --add ${INSTALL_DIR}"
-    COMMAND bash -c "./pull-eigen.sh"
+    COMMAND ${CMAKE_COMMAND} -P "./pull-eigen.cmake"
     WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
 )
 

3rd_party/pull-eigen.cmake

@@ -0,0 +1,45 @@
+#
+# Copyright Elasticsearch B.V. and/or licensed to Elasticsearch B.V. under one
+# or more contributor license agreements. Licensed under the Elastic License
+# 2.0 and the following additional limitation. Functionality enabled by the
+# files subject to the Elastic License 2.0 may only be used in production when
+# invoked by an Elasticsearch process with a license key installed that permits
+# use of machine learning features. You may not use this file except in
+# compliance with the Elastic License 2.0 and the foregoing additional
+# limitation.
+#
+
+# Script to get the appropriate version of Eigen, if not already present.
+#
+# If updating this script ensure the license information is correct in the
+# licenses sub-directory.
+
+# This cmake script is expected to be called from a target or custom command with WORKING_DIRECTORY set to this file's location
+
+# This is the file where Eigen stores its version
+set(VERSION_FILE "eigen/Eigen/src/Core/util/Macros.h")
+
+if(EXISTS ${VERSION_FILE})
+
+  file(READ ${VERSION_FILE} TMPTXT)
+
+  # We want Eigen version 3.4.0 for our current branch
+  string(FIND "${TMPTXT}" "#define EIGEN_WORLD_VERSION 3" world)
+  string(FIND "${TMPTXT}" "#define EIGEN_MAJOR_VERSION 4" major)
+  string(FIND "${TMPTXT}" "#define EIGEN_MINOR_VERSION 0" minor)
+
+  if(${world} EQUAL -1 OR ${major} EQUAL -1 OR ${minor} EQUAL -1)
+    set(PULL_EIGEN TRUE)
+  endif ()
+else()
+  set(PULL_EIGEN TRUE)
+endif()
+
+if(PULL_EIGEN)
+  execute_process(
+    COMMAND ${CMAKE_COMMAND} -E rm -rf eigen
+    )
+  execute_process(
+    COMMAND git -c advice.detachedHead=false clone --depth=1 --branch=3.4.0 https://gitlab.com/libeigen/eigen.git
+    )
+endif()

cmake/compiler/vs2019.cmake

@@ -15,20 +15,36 @@ else()
   set (VS2019_VARIABLES_ 1)
 endif()
 
-set(ROOT "/c")
+# TODO: when everything else that needs to be consistent is ready, set this to the current drive instead of hard coding C:
+set(ROOT "C:")
 if(DEFINED ENV{ROOT})
   set(ROOT $ENV{ROOT})
 endif()
 
-execute_process(COMMAND bash -c "cygpath -m -s \"${ROOT}/Program Files (x86)/Microsoft Visual Studio/2019/Professional\"" OUTPUT_VARIABLE VCBASE OUTPUT_STRIP_TRAILING_WHITESPACE)
-execute_process(COMMAND bash -c "cygpath -m -s \"${ROOT}/Program Files (x86)/Windows Kits\"" OUTPUT_VARIABLE WINSDKBASE OUTPUT_STRIP_TRAILING_WHITESPACE)
-execute_process(COMMAND bash -c "cygpath -m -s \"${ROOT}/Program Files (x86)\"" OUTPUT_VARIABLE PFX86_DIR OUTPUT_STRIP_TRAILING_WHITESPACE)
-execute_process(COMMAND bash -c "cd ${PFX86_DIR} && cygpath -m -s \"Microsoft Visual Studio\"" OUTPUT_VARIABLE MSVC_DIR OUTPUT_STRIP_TRAILING_WHITESPACE)
-execute_process(COMMAND bash -c "cd ${PFX86_DIR} && cygpath -m -s \"Windows Kits\"" OUTPUT_VARIABLE WIN_KITS_DIR OUTPUT_STRIP_TRAILING_WHITESPACE)
-execute_process(COMMAND bash -c "/bin/ls -1 ${PFX86_DIR}/${MSVC_DIR}/2019/Professional/VC/Tools/MSVC" COMMAND bash -c "tail -1" OUTPUT_VARIABLE VCVER OUTPUT_STRIP_TRAILING_WHITESPACE)
-execute_process(COMMAND bash -c "/bin/ls -1 ${WINSDKBASE}/10/Include" COMMAND bash -c "tail -1" OUTPUT_VARIABLE UCRTVER OUTPUT_STRIP_TRAILING_WHITESPACE)
+set(PFX86_DIR "${ROOT}/Program Files (x86)")
+set(MSVC_DIR "${PFX86_DIR}/Microsoft Visual Studio")
+set(VCBASE "${MSVC_DIR}/2019/Professional")
+set(WINSDKBASE "${PFX86_DIR}/Windows Kits")
+set(WIN_KITS_DIR "${PFX86_DIR}/Windows Kits")
 
+file(GLOB MSVC_VERS "${VCBASE}/VC/Tools/MSVC/*")
+list(GET MSVC_VERS -1 MSVC_VER)
+if(${MSVC_VER} MATCHES "/([^/]+)$")
+  set(VCVER ${CMAKE_MATCH_1})
+endif()
+
+file(GLOB WINSDK_VERS "${WINSDKBASE}/10/Include/*")
+list(GET WINSDK_VERS -1 WINSDK_VER)
+message(STATUS "WINSDK_VER ${WINSDK_VER}")
+if(${WINSDK_VER} MATCHES "/([^/]+)$")
+  set(UCRTVER ${CMAKE_MATCH_1})
+endif()
+
+message(STATUS "VCBASE ${VCBASE}")
+message(STATUS "WINSDKBASE ${WINSDKBASE}")
 message(STATUS "VCVER ${VCVER}")
+message(STATUS "UCRTVER ${UCRTVER}")
+
 STRING(REGEX MATCH "^([0-9]+)\\.([0-9]+)\\.([0-9]+)" VCVER_REGEX_MATCH  ${VCVER})
 set(VCVER_MAJOR ${CMAKE_MATCH_1})
 set(VCVER_MINOR ${CMAKE_MATCH_2})

cmake/variables.cmake

@@ -18,8 +18,11 @@ set(SNAPSHOT yes)
 
 set(ML_APP_NAME controller)
 
-execute_process(COMMAND awk -F= "/elasticsearchVersion/ {gsub(/-.*/,\"\"); print $2}"
-  $ENV{CPP_SRC_HOME}/gradle.properties OUTPUT_VARIABLE ML_VERSION_NUM OUTPUT_STRIP_TRAILING_WHITESPACE)
+file(READ ${CMAKE_SOURCE_DIR}/gradle.properties GRADLE_PROPERTIES)
+if(${GRADLE_PROPERTIES} MATCHES "elasticsearchVersion=([0-9\.]+)")
+  set(ML_VERSION_NUM "${CMAKE_MATCH_1}")
+endif()
+
 message(STATUS "ML_VERSION_NUM ${ML_VERSION_NUM}")
 
 message(STATUS "CMAKE_CXX_COMPILER_VERSION ${CMAKE_CXX_COMPILER_VERSION}")
@@ -41,6 +44,8 @@ else()
   set(CMAKE_INSTALL_PREFIX $ENV{CMAKE_INSTALL_PREFIX})
 endif()
 
+string(REPLACE "\\" "/" CMAKE_INSTALL_PREFIX ${CMAKE_INSTALL_PREFIX})
+message(STATUS "CMAKE_INSTALL_PREFIX ${CMAKE_INSTALL_PREFIX}")
 
 if (CMAKE_SYSTEM_NAME STREQUAL "Darwin")
   if (CMAKE_CROSSCOMPILING)

lib/ver/CMakeLists.txt

@@ -12,14 +12,22 @@
 project("ML Ver")
 
 # Prepare values to substitute into the template
-execute_process(COMMAND date "+%Y" OUTPUT_VARIABLE BUILD_YEAR OUTPUT_STRIP_TRAILING_WHITESPACE)
-execute_process(COMMAND id COMMAND awk -F ")" "{ print $1 }" COMMAND awk -F "(" "{ print $2 }" OUTPUT_VARIABLE USER_NAME
-  OUTPUT_STRIP_TRAILING_WHITESPACE)
-execute_process(COMMAND awk -F= "/elasticsearchVersion/ {gsub(/-.*/,\"\"); print $2}"
-  $ENV{CPP_SRC_HOME}/gradle.properties OUTPUT_VARIABLE PRODUCT_VERSION OUTPUT_STRIP_TRAILING_WHITESPACE)
-
-if(${VERSION_QUALIFIER})
-  set(PRODUCT_VERSION "${PRODUCT_VERSION}-${VERSION_QUALIFIER}")
+string(TIMESTAMP BUILD_YEAR "%Y")
+
+if(WIN32)
+  set(USER_NAME $ENV{USERNAME})
+else()
+  execute_process(COMMAND id COMMAND awk -F ")" "{ print $1 }" COMMAND awk -F "(" "{ print $2 }" OUTPUT_VARIABLE USER_NAME
+    OUTPUT_STRIP_TRAILING_WHITESPACE)
+endif()
+set(PRODUCT_VERSION "${ML_VERSION_NUM}")
+
+message(STATUS "PRODUCT_VERSION ${PRODUCT_VERSION}")
+message(STATUS "USER_NAME ${USER_NAME}")
+message(STATUS "BUILD_YEAR ${BUILD_YEAR}")
+
+if($ENV{VERSION_QUALIFIER})
+  set(PRODUCT_VERSION "${PRODUCT_VERSION}-$ENV{VERSION_QUALIFIER}")
 endif()
 
 if(SNAPSHOT STREQUAL "yes")

test/CMakeLists.txt

@@ -21,8 +21,8 @@ ml_add_test(bin/controller/unittest controller)
 ml_add_test(bin/pytorch_inference/unittest pytorch_inference)
 
 add_custom_target(build_tests
-    DEPENDS ${ML_BUILD_TEST_DEPENDS}
-)
+  DEPENDS ${ML_BUILD_TEST_DEPENDS}
+  )
 add_custom_target(test
-    DEPENDS ${ML_TEST_DEPENDS}
-)
+  DEPENDS ${ML_TEST_DEPENDS}
+  )