n8n: new service

docs/individual-docs/services/n8n.md

@@ -0,0 +1,5 @@
+
+
+[comment]: # (Please add your documentation on top of this line)
+
+@AUTOGEN_OPTIONS@

examples/n8n/devenv.nix

@@ -0,0 +1,2 @@
+{ ... }:
+{ }

examples/n8n/devenv.yaml

@@ -0,0 +1 @@
+allowUnfree: true

src/modules/services/n8n.nix

@@ -0,0 +1,77 @@
+{ config
+, lib
+, pkgs
+, ...
+}:
+
+let
+  inherit (lib) types;
+  cfg = config.services.n8n;
+  format = pkgs.formats.json { };
+  configFile = format.generate "n8n.json" cfg.settings;
+in
+{
+  options = {
+    services.n8n = {
+      enable = lib.mkEnableOption "n8n";
+
+      address = lib.mkOption {
+        type = types.str;
+        description = "Listen address";
+        default = "127.0.0.1";
+      };
+
+      port = lib.mkOption {
+        type = types.port;
+        default = 5678;
+        description = ''
+          The TCP port to accept connections.
+        '';
+      };
+
+      webhookUrl = lib.mkOption {
+        type = types.nullOr types.str;
+        default = null;
+        description = ''
+          WEBHOOK_URL for n8n, in case we're running behind a reverse proxy.
+          This cannot be set through configuration and must reside in an environment variable.
+        '';
+      };
+
+      settings = lib.mkOption {
+        type = format.type;
+        default = { };
+        description = ''
+          Configuration for n8n, see <https://docs.n8n.io/hosting/environment-variables/configuration-methods/>
+          for supported values.
+        '';
+      };
+    };
+  };
+
+  config = lib.mkIf cfg.enable {
+    env = {
+      N8N_PORT = cfg.port;
+      N8N_LISTEN_ADDRESS = cfg.address;
+      WEBHOOK_URL = "${cfg.webhookUrl}";
+      N8N_CONFIG_FILES = "${configFile}";
+    };
+
+    processes.n8n = {
+      exec = "${pkgs.n8n}/bin/n8n";
+
+      process-compose = {
+        readiness_probe = {
+          exec.command = "${pkgs.curl}/bin/curl -f -k ${cfg.address}:${toString cfg.port}";
+          initial_delay_seconds = 1;
+          period_seconds = 10;
+          timeout_seconds = 2;
+          success_threshold = 1;
+          failure_threshold = 5;
+        };
+
+        availability.restart = "on_failure";
+      };
+    };
+  };
+}

tests/n8n/devenv.nix

@@ -0,0 +1,7 @@
+{
+  services.n8n = {
+    enable = true;
+    address = "0.0.0.0";
+    port = 5678;
+  };
+}

tests/n8n/devenv.yaml

@@ -0,0 +1 @@
+allowUnfree: true