Route53

Aws/Route53.hs

@@ -0,0 +1,12 @@
+-- ------------------------------------------------------ --
+-- Copyright © 2012 AlephCloud Systems, Inc.
+-- ------------------------------------------------------ --
+
+module Aws.Route53
+( module Aws.Route53.Commands
+, module Aws.Route53.Core
+)
+where
+
+import Aws.Route53.Commands
+import Aws.Route53.Core

Aws/Route53/Commands.hs

@@ -0,0 +1,30 @@
+-- ------------------------------------------------------ --
+-- Copyright © 2012 AlephCloud Systems, Inc.
+-- ------------------------------------------------------ --
+
+module Aws.Route53.Commands
+( -- * Actions on Hosted Zones
+  module Aws.Route53.Commands.CreateHostedZone
+, module Aws.Route53.Commands.GetHostedZone
+, module Aws.Route53.Commands.DeleteHostedZone
+, module Aws.Route53.Commands.ListHostedZones
+
+  -- * Actions on Resource Record Sets
+, module Aws.Route53.Commands.ChangeResourceRecordSets
+, module Aws.Route53.Commands.ListResourceRecordSets
+, module Aws.Route53.Commands.GetChange
+
+  -- * Other Commands
+, module Aws.Route53.Commands.GetDate
+)
+where
+
+import Aws.Route53.Commands.CreateHostedZone
+import Aws.Route53.Commands.GetHostedZone
+import Aws.Route53.Commands.DeleteHostedZone
+import Aws.Route53.Commands.ListHostedZones
+import Aws.Route53.Commands.ChangeResourceRecordSets
+import Aws.Route53.Commands.ListResourceRecordSets
+import Aws.Route53.Commands.GetChange
+import Aws.Route53.Commands.GetDate
+

Aws/Route53/Commands/ChangeResourceRecordSets.hs

@@ -0,0 +1,67 @@
+-- ------------------------------------------------------ --
+-- Copyright © 2012 AlephCloud Systems, Inc.
+-- ------------------------------------------------------ --
+
+-- | POST ChangeResourceRecordSetrs
+--
+--   Creates, changes, or deletes resource records sets.
+--
+--   <http://docs.amazonwebservices.com/Route53/latest/APIReference/API_ChangeResourceRecordSets.html>
+--
+module Aws.Route53.Commands.ChangeResourceRecordSets where
+
+import           Aws.Route53.Core
+import           Aws.Core
+import           Text.Hamlet.XML            (xml)
+import qualified Data.Text                  as T
+import qualified Data.Text.Encoding         as T
+import           Data.Map                   (empty)
+import qualified Text.XML                   as XML
+import qualified Data.ByteString            as B
+
+data ACTION = CREATE | DELETE 
+            deriving (Show)
+
+-- TODO enforce constrains either via type or dynamically on creation or usage
+data ChangeResourceRecordSets = ChangeResourceRecordSets
+                      { crrHostedZoneId :: HostedZoneId
+                      , crrComment :: Maybe T.Text
+                      , crrsChanges :: [(ACTION, ResourceRecordSet)]
+                      } deriving (Show)
+
+data ChangeResourceRecordSetsResponse = ChangeResourceRecordSetsResponse
+  { crrsrChangeInfo :: ChangeInfo
+  } deriving (Show)
+
+-- | ServiceConfiguration: 'Route53Configuration'
+instance SignQuery ChangeResourceRecordSets where
+    type ServiceConfiguration ChangeResourceRecordSets = Route53Configuration
+    signQuery ChangeResourceRecordSets{..} = route53SignQuery method resource query body
+      where
+      method = Post
+      resource = (T.encodeUtf8 . qualifiedIdText) crrHostedZoneId `B.append` "/rrset"
+      query = []
+      body = Just $ XML.Element "ChangeResourceRecordSetsRequest" empty
+             [xml|
+             <ChangeBatch>
+               $maybe c <- crrComment
+                 <Comment>#{c}
+               <Changes>
+                 $forall change <- crrsChanges
+                   <Change>
+                     <Action>#{T.pack (show (fst change))}
+                     ^{[XML.NodeElement (toXml (snd change))]}
+             |]
+
+instance ResponseConsumer r ChangeResourceRecordSetsResponse where
+    type ResponseMetadata ChangeResourceRecordSetsResponse = Route53Metadata
+
+    responseConsumer _ = route53ResponseConsumer parse
+        where 
+        parse cursor = do
+            route53CheckResponseType () "ChangeResourceRecordSetsResponse" cursor
+            changeInfo <- r53Parse cursor
+            return $ ChangeResourceRecordSetsResponse changeInfo
+
+instance Transaction ChangeResourceRecordSets ChangeResourceRecordSetsResponse
+

Aws/Route53/Commands/CreateHostedZone.hs

@@ -0,0 +1,64 @@
+-- ------------------------------------------------------ --
+-- Copyright © 2012 AlephCloud Systems, Inc.
+-- ------------------------------------------------------ --
+
+-- | POST CreateHostedZone
+--
+--   Create a new Route53 hosted zone.
+--
+--   <http://docs.amazonwebservices.com/Route53/latest/APIReference/API_CreateHostedZone.html>
+--
+module Aws.Route53.Commands.CreateHostedZone where
+
+import           Aws.Core
+import           Aws.Route53.Core
+import           Text.Hamlet.XML            (xml)
+import qualified Data.Text                  as T
+import           Data.Map                   (empty)
+import qualified Text.XML                   as XML
+
+data CreateHostedZone = CreateHostedZone
+                      { chzName :: Domain
+                      , chzCallerReference :: T.Text
+                      , chzComment :: T.Text
+                      } deriving (Show)
+
+data CreateHostedZoneResponse = CreateHostedZoneResponse
+                              { chzrHostedZone :: HostedZone
+                              , chzrChangeInfo :: ChangeInfo
+                              , chzrDelegationSet :: DelegationSet
+                              } deriving (Show)
+
+createHostedZone :: Domain -> T.Text -> T.Text -> CreateHostedZone
+createHostedZone name callerReference comment = CreateHostedZone name callerReference comment
+
+-- | ServiceConfiguration: 'Route53Configuration'
+instance SignQuery CreateHostedZone where
+    type ServiceConfiguration CreateHostedZone = Route53Configuration
+    signQuery CreateHostedZone{..} = route53SignQuery method resource query body
+      where
+      method = Post
+      resource = "/hostedzone"
+      query = []
+      body = Just $ XML.Element "CreateHostedZoneRequest" empty
+             [xml|
+             <Name>#{dText chzName}
+             <CallerReference>#{chzCallerReference}
+             <HostedZoneConfig>
+               <Comment>#{chzComment}
+             |]
+
+instance ResponseConsumer r CreateHostedZoneResponse where
+    type ResponseMetadata CreateHostedZoneResponse = Route53Metadata
+
+    responseConsumer _ = route53ResponseConsumer parse
+        where 
+        parse cursor = do
+            route53CheckResponseType () "GetHostedZoneResponse" cursor
+            zone <- r53Parse cursor
+            changeInfo <- r53Parse cursor
+            delegationSet <- r53Parse cursor
+            return $ CreateHostedZoneResponse zone changeInfo delegationSet
+
+instance Transaction CreateHostedZone CreateHostedZoneResponse
+

Aws/Route53/Commands/DeleteHostedZone.hs

@@ -0,0 +1,57 @@
+-- ------------------------------------------------------ --
+-- Copyright © 2012 AlephCloud Systems, Inc.
+-- ------------------------------------------------------ --
+
+-- | DELETE DeleteHostedZone
+--
+--   Delete a particular Route53 hosted zone identified through its 'hostedZoneId'.
+--   The HostedZoneId is obtained in the response to 'Aws.Route53.Commands.CreateHostedZone'
+--   or 'Aws.Route53.Commands.ListHostedZones'
+--
+--   Note that the hosted zone can be delete only after deleting all resource records other than
+--   the default SOA record and the NS records.
+--
+--   <http://docs.amazonwebservices.com/Route53/latest/APIReference/API_DeleteHostedZone.html>
+--
+module Aws.Route53.Commands.DeleteHostedZone where
+
+import           Aws.Core
+import           Aws.Route53.Core
+import qualified Data.Text.Encoding         as T
+
+data DeleteHostedZone = DeleteHostedZone
+                   { dhzHostedZoneId :: HostedZoneId
+                   } deriving (Show)
+
+data DeleteHostedZoneResponse = DeleteHostedZoneResponse
+                              { dhzrChangeInfo :: ChangeInfo
+                              } deriving (Show)
+
+deleteHostedZone :: HostedZoneId -> DeleteHostedZone
+deleteHostedZone hostedZoneId = DeleteHostedZone hostedZoneId
+
+-- Delete add convenience methods:
+-- * Delete non-empty hosted zone
+
+-- | ServiceConfiguration: 'Route53Configuration'
+instance SignQuery DeleteHostedZone where
+    type ServiceConfiguration DeleteHostedZone = Route53Configuration
+    signQuery DeleteHostedZone{..} = route53SignQuery method resource query body
+      where
+      method = Delete
+      resource = T.encodeUtf8 . qualifiedIdText $ dhzHostedZoneId
+      query = []
+      body = Nothing
+
+instance ResponseConsumer r DeleteHostedZoneResponse where
+    type ResponseMetadata DeleteHostedZoneResponse = Route53Metadata
+
+    responseConsumer _ = route53ResponseConsumer parse
+        where 
+        parse cursor = do
+            route53CheckResponseType () "DeleteHostedZoneResponse" cursor
+            changeInfo <- r53Parse cursor
+            return $ DeleteHostedZoneResponse changeInfo
+
+instance Transaction DeleteHostedZone DeleteHostedZoneResponse
+

Aws/Route53/Commands/GetChange.hs

@@ -0,0 +1,49 @@
+-- ------------------------------------------------------ --
+-- Copyright © 2012 AlephCloud Systems, Inc.
+-- ------------------------------------------------------ --
+
+-- | GET GetChange
+--
+--   Returns the current status of change batch request.
+--
+--   <http://docs.amazonwebservices.com/Route53/latest/APIReference/API_GetChange.html>
+--
+module Aws.Route53.Commands.GetChange where
+
+import           Aws.Core
+import           Aws.Route53.Core
+import qualified Data.Text.Encoding         as T
+
+data GetChange = GetChange
+               { changeId :: ChangeId
+               } deriving (Show)
+
+data GetChangeResponse = GetChangeResponse
+                       { gcrChangeInfo :: ChangeInfo
+                       } deriving (Show)
+
+getChange :: ChangeId -> GetChange
+getChange changeId = GetChange changeId
+
+-- | ServiceConfiguration: 'Route53Configuration'
+instance SignQuery GetChange where
+    type ServiceConfiguration GetChange = Route53Configuration
+    signQuery GetChange{..} = route53SignQuery method resource query body
+      where
+      method = Get
+      resource = T.encodeUtf8 . qualifiedIdText $ changeId
+      query = []
+      body = Nothing
+
+instance ResponseConsumer r GetChangeResponse where
+    type ResponseMetadata GetChangeResponse = Route53Metadata
+
+    responseConsumer _ = route53ResponseConsumer parse
+        where 
+        parse cursor = do
+            route53CheckResponseType () "GetChangeResponse" cursor
+            changeInfo <- r53Parse cursor
+            return $ GetChangeResponse changeInfo
+
+instance Transaction GetChange GetChangeResponse
+

Aws/Route53/Commands/GetDate.hs

@@ -0,0 +1,61 @@
+-- ------------------------------------------------------ --
+-- Copyright © 2012 AlephCloud Systems, Inc.
+-- ------------------------------------------------------ --
+
+-- | GET GetDate
+--
+--   Receive current date string from Route53 service that can be used as date string for
+--   authenticating REST requests to Route53.
+--
+--   <http://docs.amazonwebservices.com/Route53/latest/DeveloperGuide/RESTAuthentication.html>
+-- 
+module Aws.Route53.Commands.GetDate where
+
+import           Aws.Core
+import           Aws.Route53.Core
+import           Data.Maybe
+import           Data.Time                  (UTCTime)
+import           Data.Time.Format           (parseTime)
+import           System.Locale              (defaultTimeLocale)
+import           Data.ByteString.Char8      (unpack)
+import qualified Network.HTTP.Types         as HTTP
+
+data GetDate = GetDate deriving (Show)
+
+newtype GetDateResponse = GetDateResponse { date :: UTCTime } deriving (Show)
+
+-- | ServiceConfiguration: 'Route53Configuration'
+instance SignQuery GetDate where
+  type ServiceConfiguration GetDate = Route53Configuration
+  signQuery GetDate info sd = SignedQuery 
+    { sqMethod = Get
+    , sqProtocol = route53Protocol info
+    , sqHost = route53Endpoint info
+    , sqPort = route53Port info
+    , sqPath = "/date/"
+    , sqQuery = []
+    , sqDate = Just $ signatureTime sd
+    , sqAuthorization = Nothing
+    , sqContentType = Nothing
+    , sqContentMd5 = Nothing
+    , sqAmzHeaders = []
+    , sqOtherHeaders = []
+    , sqBody = Nothing
+    , sqStringToSign = ""
+    }
+
+instance ResponseConsumer r GetDateResponse where
+  type ResponseMetadata GetDateResponse = ()
+  responseConsumer _ _ _ headers _ = return $ GetDateResponse date
+    where
+    -- TODO add proper error handling
+    date = fromJust $ do 
+      str <- findHeaderValue headers HTTP.hDate
+      -- FIXME: this is probably to restrictive. We should support full rfc1123
+      parseTime defaultTimeLocale "%a, %d %b %Y %H:%M:%S %Z" (unpack str)
+
+getDate :: GetDate
+getDate = GetDate
+
+instance Transaction GetDate GetDateResponse
+

Aws/Route53/Commands/GetHostedZone.hs

@@ -0,0 +1,52 @@
+-- ------------------------------------------------------ --
+-- Copyright © 2012 AlephCloud Systems, Inc.
+-- ------------------------------------------------------ --
+
+-- | GET GetHostedZone
+--
+--   Get a particular Route53 hosted zone identified through its 'hostedZoneId'.
+--   The HostedZoneId is obtained in the response to 'Aws.Route53.Commands.CreateHostedZone'
+--   or 'Aws.Route53.Commands.ListHostedZones'
+--
+--   <http://docs.amazonwebservices.com/Route53/latest/APIReference/API_GetHostedZone.html>
+--
+module Aws.Route53.Commands.GetHostedZone where
+
+import           Aws.Core
+import           Aws.Route53.Core
+import qualified Data.Text.Encoding         as T
+
+data GetHostedZone = GetHostedZone
+                   { hostedZoneId :: HostedZoneId
+                   } deriving (Show)
+
+data GetHostedZoneResponse = GetHostedZoneResponse
+                             { ghzrHostedZone :: HostedZone
+                             , ghzrDelegationSet :: DelegationSet
+                             } deriving (Show)
+
+getHostedZone :: HostedZoneId -> GetHostedZone
+getHostedZone hostedZoneId = GetHostedZone hostedZoneId
+
+-- | ServiceConfiguration: 'Route53Configuration'
+instance SignQuery GetHostedZone where
+    type ServiceConfiguration GetHostedZone = Route53Configuration
+    signQuery GetHostedZone{..} = route53SignQuery method resource query Nothing
+      where
+      method = Get
+      resource = T.encodeUtf8 . qualifiedIdText $ hostedZoneId
+      query = []
+
+instance ResponseConsumer r GetHostedZoneResponse where
+    type ResponseMetadata GetHostedZoneResponse = Route53Metadata
+
+    responseConsumer _ = route53ResponseConsumer parse
+        where 
+        parse cursor = do
+            route53CheckResponseType () "GetHostedZoneResponse" cursor
+            zone <- r53Parse cursor
+            delegationSet <- r53Parse cursor
+            return $ GetHostedZoneResponse zone delegationSet
+
+instance Transaction GetHostedZone GetHostedZoneResponse
+