Skip to content

Demonstration queries

Jump to bottom
Jim Balhoff edited this page Sep 30, 2017 · 24 revisions

This page documents some demonstration queries which can be run against the NCIt OBO Edition graphstore. Each query can be run via the YASGUI SPARQL interface by following the link in the question:

Find disease associations

What diseases are associated with Lymphedema?

PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX lymphedema: <http://purl.obolibrary.org/obo/NCIT_C3207>
PREFIX DiseaseHasAssociatedDisease: <http://purl.obolibrary.org/obo/NCIT_R126>
SELECT DISTINCT ?disease ?disease_label 
FROM <http://purl.obolibrary.org/obo/ncit.owl>
FROM <http://purl.obolibrary.org/obo/ncit/ncit-property-graph-redundant.ttl>
WHERE {
?disease DiseaseHasAssociatedDisease: lymphedema: .
?disease rdfs:label ?disease_label .
}

Find diseases related to a particular anatomic site

What disease have the reproductive system as the primary anatomic site?

PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX repro: <http://purl.obolibrary.org/obo/NCIT_C12841>
PREFIX HasPrimaryAnatomicSite: <http://purl.obolibrary.org/obo/NCIT_R101>
SELECT DISTINCT ?disease ?disease_label
FROM <http://purl.obolibrary.org/obo/ncit.owl>
FROM <http://purl.obolibrary.org/obo/ncit/ncit-property-graph-redundant.ttl>
WHERE {
?disease HasPrimaryAnatomicSite: repro: .
?disease rdfs:label ?disease_label .
}

What diseases have the primary anatomic site of the lung?

PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX lung: <http://purl.obolibrary.org/obo/NCIT_C12468>
PREFIX HasPrimaryAnatomicSite: <http://purl.obolibrary.org/obo/NCIT_R101>
SELECT DISTINCT ?disease ?disease_label
FROM <http://purl.obolibrary.org/obo/ncit.owl>
FROM <http://purl.obolibrary.org/obo/ncit/ncit-property-graph-redundant.ttl>
WHERE {
?disease HasPrimaryAnatomicSite: lung: .
?disease rdfs:label ?disease_label .
}

Find procedures that target a particular anatomical site

What are procedures target the colon?

PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX colon: <http://purl.obolibrary.org/obo/NCIT_C12382>
PREFIX ProcedureHasTarget: <http://purl.obolibrary.org/obo/NCIT_R163>
SELECT DISTINCT ?procedure ?procedure_label
FROM <http://purl.obolibrary.org/obo/ncit.owl>
FROM <http://purl.obolibrary.org/obo/ncit/ncit-property-graph-redundant.ttl>
WHERE {
?disease ProcedureHasTarget: colon: .
?disease rdfs:label ?procedure_label .
}

What are procedures target the lung?

PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX lung: <http://purl.obolibrary.org/obo/NCIT_C12468>
PREFIX ProcedureHasTarget: <http://purl.obolibrary.org/obo/NCIT_R163>
SELECT DISTINCT ?procedure ?procedure_label
FROM <http://purl.obolibrary.org/obo/ncit.owl>
FROM <http://purl.obolibrary.org/obo/ncit/ncit-property-graph-redundant.ttl>
WHERE {
?disease ProcedureHasTarget: lung: .
?disease rdfs:label ?procedure_label .
}

Find regimens containing specific components

What regimens include Declopramide?

PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX Declopramide: <http://purl.obolibrary.org/obo/NCIT_C1772>
PREFIX ChemotherapyRegimenHasComponent: <http://purl.obolibrary.org/obo/NCIT_R123>
SELECT DISTINCT ?regimen ?regimen_label
FROM <http://purl.obolibrary.org/obo/ncit.owl>
FROM <http://purl.obolibrary.org/obo/ncit/ncit-property-graph-redundant.ttl>
WHERE {
?regimen ChemotherapyRegimenHasComponent: Declopramide: .
?regimen rdfs:label ?regimen_label .
}

What regimens include cisplatin?

PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX Cisplatin: <http://purl.obolibrary.org/obo/NCIT_C376>
PREFIX ChemotherapyRegimenHasComponent: <http://purl.obolibrary.org/obo/NCIT_R123>
SELECT DISTINCT ?regimen ?regimen_label
FROM <http://purl.obolibrary.org/obo/ncit.owl>
FROM <http://purl.obolibrary.org/obo/ncit/ncit-property-graph-redundant.ttl>
WHERE {
?regimen ChemotherapyRegimenHasComponent: Cisplatin: .
?regimen rdfs:label ?regimen_label .
}

What regimens include Doxorubicin?

PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX Doxorubicin: <http://purl.obolibrary.org/obo/NCIT_C456>
PREFIX ChemotherapyRegimenHasComponent: <http://purl.obolibrary.org/obo/NCIT_R123>
SELECT DISTINCT ?regimen ?regimen_label
FROM <http://purl.obolibrary.org/obo/ncit.owl>
FROM <http://purl.obolibrary.org/obo/ncit/ncit-property-graph-redundant.ttl>
WHERE {
?regimen ChemotherapyRegimenHasComponent: Doxorubicin: .
?regimen rdfs:label ?regimen_label .
}

What regimens include Leucovorin Calcium?

PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX LeucovorinCalcium: <http://purl.obolibrary.org/obo/NCIT_C607>
PREFIX ChemotherapyRegimenHasComponent: <http://purl.obolibrary.org/obo/NCIT_R123>
SELECT DISTINCT ?regimen ?regimen_label
FROM <http://purl.obolibrary.org/obo/ncit.owl>
FROM <http://purl.obolibrary.org/obo/ncit/ncit-property-graph-redundant.ttl>
WHERE {
?regimen ChemotherapyRegimenHasComponent: LeucovorinCalcium: .
?regimen rdfs:label ?regimen_label .
}

What regimens include Dexamethasone?

PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX Dexamethasone: <http://purl.obolibrary.org/obo/NCIT_C422>
PREFIX ChemotherapyRegimenHasComponent: <http://purl.obolibrary.org/obo/NCIT_R123>
SELECT DISTINCT ?regimen ?regimen_label
FROM <http://purl.obolibrary.org/obo/ncit.owl>
FROM <http://purl.obolibrary.org/obo/ncit/ncit-property-graph-redundant.ttl>
WHERE {
?regimen ChemotherapyRegimenHasComponent: Dexamethasone: .
?regimen rdfs:label ?regimen_label .
}

Find regimens specific to a particular disease

What regimens are accepted for use with Breast Carcinoma?

PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX BreastCancer: <http://purl.obolibrary.org/obo/NCIT_C4872>
PREFIX RegimenHasAcceptedUseForDisease: <http://purl.obolibrary.org/obo/NCIT_R172>
SELECT DISTINCT ?regimen ?regimen_label
FROM <http://purl.obolibrary.org/obo/ncit.owl>
FROM <http://purl.obolibrary.org/obo/ncit/ncit-property-graph-redundant.ttl>
WHERE {
?regimen RegimenHasAcceptedUseForDisease: BreastCancer: .
?regimen rdfs:label ?regimen_label .
}

Find a regimen specific to a disease, and that has a particular component

What regimens are accepted for use with Breast Carcinoma and contain doxorubicin?

PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX Disease_Has_Associated_Anatomic_Site: <http://purl.obolibrary.org/obo/NCIT_R100>
PREFIX BreastCarcinoma: <http://purl.obolibrary.org/obo/NCIT_C4872>
PREFIX Doxorubicin: <http://purl.obolibrary.org/obo/NCIT_C456>
PREFIX RegimenHasAcceptedUseForDisease: <http://purl.obolibrary.org/obo/NCIT_R172>
PREFIX ChemotherapyRegimenHasComponent: <http://purl.obolibrary.org/obo/NCIT_R123>
SELECT DISTINCT ?regimen ?label 
FROM <http://purl.obolibrary.org/obo/ncit.owl>
FROM <http://purl.obolibrary.org/obo/ncit/ncit-property-graph-redundant.ttl>
WHERE { 
  ?regimen RegimenHasAcceptedUseForDisease: BreastCarcinoma: .
  ?regimen ChemotherapyRegimenHasComponent: Doxorubicin: .
  ?regimen rdfs:label ?label .
}

Genetic-based queries

What are the oncogenes?

PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX oncogene: <http://purl.obolibrary.org/obo/NCIT_C19540>
SELECT DISTINCT ?oncogene ?oncogene_label
FROM <http://purl.obolibrary.org/obo/ncit.owl>
FROM <http://purl.obolibrary.org/obo/ncit/ncit-property-graph-redundant.ttl>
WHERE {
?oncogene rdfs:subClassOf* oncogene: .
?oncogene rdfs:label ?oncogene_label .
}

What are the gene fusions?

PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX FusionGene: <http://purl.obolibrary.org/obo/NCIT_C28510>
SELECT DISTINCT ?fusion ?fusion_label
FROM <http://purl.obolibrary.org/obo/ncit.owl>
FROM <http://purl.obolibrary.org/obo/ncit/ncit-property-graph-redundant.ttl>
WHERE {
?fusion rdfs:subClassOf* FusionGene: .
?fusion rdfs:label ?fusion_label .
}

What are the genetic abnormalities in ETV6?

PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX ETV6: <http://purl.obolibrary.org/obo/NCIT_C18312>
PREFIX MolecularAbnormalityInvolvesGene: <http://purl.obolibrary.org/obo/NCIT_R177>
SELECT DISTINCT ?abnormality ?abnormality_label
FROM <http://purl.obolibrary.org/obo/ncit.owl>
FROM <http://purl.obolibrary.org/obo/ncit/ncit-property-graph-redundant.ttl>
WHERE {
?abnormality MolecularAbnormalityInvolvesGene: ETV6: .
?abnormality rdfs:label ?abnormality_label .
}

What genes are involved in non-small cell lung cancer pathways?

PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX NSCLCPathway: <http://purl.obolibrary.org/obo/NCIT_C91445>
PREFIX GeneIsElementInPathway: <http://purl.obolibrary.org/obo/NCIT_R130>
SELECT DISTINCT ?gene ?gene_label
FROM <http://purl.obolibrary.org/obo/ncit.owl>
FROM <http://purl.obolibrary.org/obo/ncit/ncit-property-graph-redundant.ttl>
WHERE {
?gene GeneIsElementInPathway: NSCLCPathway: .
?gene rdfs:label ?gene_label .
}

What diseases map to the HBB gene?

PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX HBBGene: <http://purl.obolibrary.org/obo/NCIT_C84951>
PREFIX DiseaseMappedToGene: <http://purl.obolibrary.org/obo/NCIT_R176>
SELECT DISTINCT ?disease ?disease_label
FROM <http://purl.obolibrary.org/obo/ncit.owl>
FROM <http://purl.obolibrary.org/obo/ncit/ncit-property-graph-redundant.ttl>
WHERE {
?disease DiseaseMappedToGene: HBBGene: .
?disease rdfs:label ?disease_label .
}

What are the disease/biomarker mappings?

PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX Gene_Product_Is_Biomarker_Of:  <http://purl.obolibrary.org/obo/NCIT_R47>
PREFIX Gene_Is_Biomarker_Of:  <http://purl.obolibrary.org/obo/NCIT_R39>

SELECT DISTINCT ?diseaseLabel ?pLabel ?geneOrProductLabel
FROM <http://purl.obolibrary.org/obo/ncit.owl>
FROM <http://purl.obolibrary.org/obo/ncit/ncit-property-graph.ttl>
WHERE {
VALUES ?property {
   Gene_Product_Is_Biomarker_Of:
   Gene_Is_Biomarker_Of:
  }
?geneOrProduct ?property ?disease .
?disease rdfs:label ?diseaseLabel .
?property rdfs:label ?pLabel .
?geneOrProduct rdfs:label ?geneOrProductLabel .
}
ORDERBY ?diseaseLabel

Drug-related queries

What are the mappings between disease and chemo regimen drug targets (genes)?

PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX DiseaseClass: <http://purl.obolibrary.org/obo/NCIT_C2991>
PREFIX RegimenHasAcceptedUseForDisease: <http://purl.obolibrary.org/obo/NCIT_R172>
PREFIX ChemicalOrDrugAffectsGeneProduct: <http://purl.obolibrary.org/obo/NCIT_R146>
PREFIX ChemicalOrDrugIsMetabolizedByEnzyme: <http://purl.obolibrary.org/obo/NCIT_R122>
PREFIX GeneProductIsEncodedByGene: <http://purl.obolibrary.org/obo/NCIT_R54>
PREFIX ChemotherapyRegimenHasComponent: <http://purl.obolibrary.org/obo/NCIT_R123>
SELECT DISTINCT ?disease_label ?gene_label 
FROM <http://purl.obolibrary.org/obo/ncit.owl>
FROM <http://purl.obolibrary.org/obo/ncit/ncit-property-graph.ttl>
WHERE { 
  ?disease rdfs:subClassOf* DiseaseClass: .
  ?disease rdfs:label ?disease_label .
  ?therapy RegimenHasAcceptedUseForDisease: ?disease .
  ?therapy ChemotherapyRegimenHasComponent: ?chemical .
  ?chemical ChemicalOrDrugAffectsGeneProduct: | ChemicalOrDrugIsMetabolizedByEnzyme: ?protein .
  ?protein GeneProductIsEncodedByGene: ?gene .
  ?gene rdfs:label ?gene_label . 
}

What are the diseases that have drugs with gene targets?

PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX DiseaseClass: <http://purl.obolibrary.org/obo/NCIT_C2991>
PREFIX RegimenHasAcceptedUseForDisease: <http://purl.obolibrary.org/obo/NCIT_R172>
PREFIX ChemicalOrDrugAffectsGeneProduct: <http://purl.obolibrary.org/obo/NCIT_R146>
PREFIX ChemicalOrDrugIsMetabolizedByEnzyme: <http://purl.obolibrary.org/obo/NCIT_R122>
PREFIX GeneProductIsEncodedByGene: <http://purl.obolibrary.org/obo/NCIT_R54>
PREFIX ChemotherapyRegimenHasComponent: <http://purl.obolibrary.org/obo/NCIT_R123>
SELECT DISTINCT ?disease_label ?disease
FROM <http://purl.obolibrary.org/obo/ncit.owl>
FROM <http://purl.obolibrary.org/obo/ncit/ncit-property-graph.ttl>
WHERE { 
  ?disease rdfs:subClassOf* DiseaseClass: .
  ?disease rdfs:label ?disease_label .
  ?therapy RegimenHasAcceptedUseForDisease: ?disease .
  ?therapy ChemotherapyRegimenHasComponent: ?chemical .
  ?chemical ChemicalOrDrugAffectsGeneProduct: | ChemicalOrDrugIsMetabolizedByEnzyme: ?protein .
  ?protein GeneProductIsEncodedByGene: ?gene .
  ?gene rdfs:label ?gene_label . 
}

What genes are targeted by drugs used to treat breast cancer?

PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX BreastCarcinoma: <http://purl.obolibrary.org/obo/NCIT_C4872>
PREFIX ChemotherapyRegimenHasComponent: <http://purl.obolibrary.org/obo/NCIT_R123>
PREFIX RegimenHasAcceptedUseForDisease: <http://purl.obolibrary.org/obo/NCIT_R172>
PREFIX ChemicalOrDrugAffectsGeneProduct: <http://purl.obolibrary.org/obo/NCIT_R146>
PREFIX ChemicalOrDrugIsMetabolizedByEnzyme: <http://purl.obolibrary.org/obo/NCIT_R122>
PREFIX GeneProductIsEncodedByGene: <http://purl.obolibrary.org/obo/NCIT_R54>
SELECT DISTINCT ?gene_label
FROM <http://purl.obolibrary.org/obo/ncit.owl>
FROM <http://purl.obolibrary.org/obo/ncit/ncit-property-graph.ttl>
WHERE { 
  ?therapy RegimenHasAcceptedUseForDisease: BreastCarcinoma: .
  ?therapy ChemotherapyRegimenHasComponent: ?chemical .
  ?chemical ChemicalOrDrugAffectsGeneProduct: | ChemicalOrDrugIsMetabolizedByEnzyme: ?protein .
  ?protein GeneProductIsEncodedByGene: ?gene .
  ?gene rdfs:label ?gene_label .
}

What genes are targeted by drugs used to treat prostate cancer?

PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX ProstateCarcinoma: <http://purl.obolibrary.org/obo/NCIT_C4863>
PREFIX ChemotherapyRegimenHasComponent: <http://purl.obolibrary.org/obo/NCIT_R123>
PREFIX RegimenHasAcceptedUseForDisease: <http://purl.obolibrary.org/obo/NCIT_R172>
PREFIX ChemicalOrDrugAffectsGeneProduct: <http://purl.obolibrary.org/obo/NCIT_R146>
PREFIX ChemicalOrDrugIsMetabolizedByEnzyme: <http://purl.obolibrary.org/obo/NCIT_R122>
PREFIX GeneProductIsEncodedByGene: <http://purl.obolibrary.org/obo/NCIT_R54>
SELECT DISTINCT ?gene_label
FROM <http://purl.obolibrary.org/obo/ncit.owl>
FROM <http://purl.obolibrary.org/obo/ncit/ncit-property-graph.ttl>
WHERE { 
  ?therapy RegimenHasAcceptedUseForDisease: ProstateCarcinoma: .
  ?therapy ChemotherapyRegimenHasComponent: ?chemical .
  ?chemical ChemicalOrDrugAffectsGeneProduct: | ChemicalOrDrugIsMetabolizedByEnzyme: ?protein .
  ?protein GeneProductIsEncodedByGene: ?gene .
  ?gene rdfs:label ?gene_label .
}

What chemo regimen components are used to treat prostate cancer?

PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX ProstateCarcinoma: <http://purl.obolibrary.org/obo/NCIT_C4863>
PREFIX ChemotherapyRegimenHasComponent: <http://purl.obolibrary.org/obo/NCIT_R123>
PREFIX RegimenHasAcceptedUseForDisease: <http://purl.obolibrary.org/obo/NCIT_R172>
SELECT DISTINCT ?component_label
FROM <http://purl.obolibrary.org/obo/ncit.owl>
FROM <http://purl.obolibrary.org/obo/ncit/ncit-property-graph-redundant.ttl>
WHERE { 
  ?therapy RegimenHasAcceptedUseForDisease: ProstateCarcinoma: .
  ?therapy ChemotherapyRegimenHasComponent: ?component .
  ?component rdfs:label ?component_label .
  FILTER NOT EXISTS {
   ?therapy ChemotherapyRegimenHasComponent: ?component2 .
   ?component2 rdfs:subClassOf+ ?component .
  }
}

What chemo regimen components that are used to treat prostate cancer have gene targets?

PREFIX ProstateCarcinoma: <http://purl.obolibrary.org/obo/NCIT_C4863>
PREFIX ChemotherapyRegimenHasComponent: <http://purl.obolibrary.org/obo/NCIT_R123>
PREFIX RegimenHasAcceptedUseForDisease: <http://purl.obolibrary.org/obo/NCIT_R172>
PREFIX ChemicalOrDrugAffectsGeneProduct: <http://purl.obolibrary.org/obo/NCIT_R146>
PREFIX ChemicalOrDrugIsMetabolizedByEnzyme: <http://purl.obolibrary.org/obo/NCIT_R122>
PREFIX GeneProductIsEncodedByGene: <http://purl.obolibrary.org/obo/NCIT_R54>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
SELECT DISTINCT ?chemical_label
FROM <http://purl.obolibrary.org/obo/ncit.owl>
FROM <http://purl.obolibrary.org/obo/ncit/ncit-property-graph-redundant.ttl>
WHERE { 
  ?therapy RegimenHasAcceptedUseForDisease: ProstateCarcinoma: .
  ?therapy ChemotherapyRegimenHasComponent: ?chemical .
  ?chemical ChemicalOrDrugAffectsGeneProduct: | ChemicalOrDrugIsMetabolizedByEnzyme: ?protein .
  ?chemical rdfs:label ?chemical_label .
  FILTER NOT EXISTS {
    ?therapy ChemotherapyRegimenHasComponent: ?chemical2 .
    ?chemical2 rdfs:subClassOf+ ?chemical .
  }
}

What are the targeted chemo regimen components used to treat prostate cancer, and what are their targets?

PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX ProstateCarcinoma: <http://purl.obolibrary.org/obo/NCIT_C4863>
PREFIX RegimenHasAcceptedUseForDisease: <http://purl.obolibrary.org/obo/NCIT_R172>
PREFIX ChemicalOrDrugAffectsGeneProduct: <http://purl.obolibrary.org/obo/NCIT_R146>
PREFIX ChemicalOrDrugIsMetabolizedByEnzyme: <http://purl.obolibrary.org/obo/NCIT_R122>
PREFIX GeneProductIsEncodedByGene: <http://purl.obolibrary.org/obo/NCIT_R54>
PREFIX ChemotherapyRegimenHasComponent: <http://purl.obolibrary.org/obo/NCIT_R123>
SELECT DISTINCT ?chemical_label ?gene_label
FROM <http://purl.obolibrary.org/obo/ncit.owl>
FROM <http://purl.obolibrary.org/obo/ncit/ncit-property-graph-redundant.ttl>
WHERE { 
  ?therapy RegimenHasAcceptedUseForDisease: ProstateCarcinoma: .
  ?therapy ChemotherapyRegimenHasComponent: ?chemical .
  ?chemical ChemicalOrDrugAffectsGeneProduct: | ChemicalOrDrugIsMetabolizedByEnzyme: ?protein .
  ?protein GeneProductIsEncodedByGene: ?gene .
  ?chemical rdfs:label ?chemical_label .
  ?gene rdfs:label ?gene_label . 
  FILTER NOT EXISTS {
    ?therapy ChemotherapyRegimenHasComponent: ?chemical2 .
    ?chemical2 ChemicalOrDrugAffectsGeneProduct: | ChemicalOrDrugIsMetabolizedByEnzyme: ?protein2 .
    ?protein2 GeneProductIsEncodedByGene: ?gene2 .
    { ?chemical2 rdfs:subClassOf+ ?chemical . } UNION { ?gene2 rdfs:subClassOf+ ?gene . } 
  }
}

Queries bridging NCIt to external data sources via Uberon and Cell Ontology integration

Find genes and their orthologs expressed in a given anatomical structure (e.g. primary anatomic site of a tumor, such as the salivary gland for a Salivary Gland Myoepithelial Tumor)?

PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX Disease_Has_Normal_Cell_Origin: <http://purl.obolibrary.org/obo/NCIT_R104>
PREFIX Disease_Has_Primary_Anatomic_Site: <http://purl.obolibrary.org/obo/NCIT_R101>
PREFIX derives_from: <http://purl.obolibrary.org/obo/RO_0001000>
PREFIX SalivaryGlandMyoepithelialTumor: <http://purl.obolibrary.org/obo/NCIT_C40393>
PREFIX OBAN: <http://purl.org/oban/>
PREFIX expressed_in: <http://purl.obolibrary.org/obo/RO_0002206>
PREFIX part_of: <http://purl.obolibrary.org/obo/BFO_0000050>
SELECT DISTINCT ?gene
FROM <http://purl.obolibrary.org/obo/ncit-plus.owl>
FROM <http://purl.obolibrary.org/obo/ncit/ncit-plus-property-graph.ttl>
FROM <https://data.monarchinitiative.org/ttl/bgee.ttl>
WHERE { 
  SalivaryGlandMyoepithelialTumor: Disease_Has_Primary_Anatomic_Site: ?site .
  ?assoc OBAN:association_has_object ?specific_site .
  ?specific_site (rdfs:subClassOf*)|(rdfs:subClassOf*/part_of:) ?site .
  ?assoc OBAN:association_has_predicate expressed_in: .
  ?assoc OBAN:association_has_subject ?gene .
}
LIMIT 200

Connect Neoplasm concepts to cell lines derived from their cell origin

PREFIX Disease_Has_Normal_Cell_Origin: <http://purl.obolibrary.org/obo/NCIT_R104>
PREFIX Disease_Has_Primary_Anatomic_Site: <http://purl.obolibrary.org/obo/NCIT_R101>
PREFIX derives_from: <http://purl.obolibrary.org/obo/RO_0001000>
PREFIX OBAN: <http://purl.org/oban/>
PREFIX expressed_in: <http://purl.obolibrary.org/obo/RO_0002206>
PREFIX part_of: <http://purl.obolibrary.org/obo/BFO_0000050>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
SELECT DISTINCT ?disease_label ?cell_type_label ?cell_line
FROM <http://purl.obolibrary.org/obo/ncit/ncit-plus.owl>
FROM <http://purl.obolibrary.org/obo/ncit/ncit-plus-property-graph.ttl>
FROM <https://data.monarchinitiative.org/ttl/coriell.ttl>
WHERE { 
  ?cell_line derives_from:/rdfs:subClassOf* ?cell_type .
  ?disease Disease_Has_Normal_Cell_Origin: ?cell_type .
  ?disease rdfs:label ?disease_label .
  ?cell_type rdfs:label ?cell_type_label .
  FILTER(?cell_type != <http://purl.obolibrary.org/obo/CL_0000000>)
}
LIMIT 100
Clone this wiki locally