nixosTests: WIP integration tests

.github/workflows/build.yml

@@ -22,3 +22,17 @@ jobs:
     - uses: DeterminateSystems/magic-nix-cache-action@v7
     - name: Build some-pkgs
       run: nix run github:Mic92/nix-fast-build -- --skip-cached --no-nom --flake ".#packages"
+  nix-flake-check:
+    strategy:
+      fail-fast: false
+      matrix:
+        os: [ ubuntu-latest ]
+    runs-on: ${{ matrix.os }}
+    steps:
+    - name: Checkout repository
+      uses: actions/checkout@v4
+    - name: Install Nix
+      uses: DeterminateSystems/nix-installer-action@v13
+    - uses: DeterminateSystems/magic-nix-cache-action@v7
+    - name: Build the checks
+      run: nix run github:Mic92/nix-fast-build -- --skip-cached --no-nom --flake ".#checks.$(nix eval --raw --impure --expr builtins.currentSystem)"

flake.nix

@@ -27,6 +27,7 @@
 
             inputsFrom = [ self.packages.${system}.evanix ];
             packages = with pkgs; [
+              nixfmt-rfc-style
               gdb
               ccls
               valgrind
@@ -63,5 +64,30 @@
             });
         }
       );
+      legacyPackages = forAllSystems (
+        { pkgs, ... }:
+        {
+          nixosTests = import ./nixos/tests/all-tests.nix pkgs;
+        }
+      );
+      checks = forAllSystems (
+        { system, pkgs, ... }:
+        let
+          inherit (pkgs.lib)
+            filterAttrs
+            isDerivation
+            mapAttrs'
+            nameValuePair
+            pipe
+            ;
+        in
+        pipe self.legacyPackages.${system}.nixosTests [
+          (filterAttrs (_: p: isDerivation p))
+          (mapAttrs' (name: nameValuePair "nixosTests-${name}"))
+        ]
+        // {
+          inherit (self.packages.${system}) evanix evanix-py;
+        }
+      );
     };
 }

nixos/tests/README.md

@@ -0,0 +1,14 @@
+Synthetic integration tests for "real" nix stores and substituters
+
+Usage
+---
+
+```console
+$ nix build .#nixosTests.diamond-unbuilt-2
+```
+
+Development
+---
+
+The `.#nixosTests` attrset is defined in [`all-tests.nix`](./all-tests.nix).
+In [dsl.nix](./dsl.nix) we define the helper for generating NixOS tests from DAGs.

nixos/tests/all-tests.nix

@@ -0,0 +1,118 @@
+pkgs:
+
+let
+  dsl = ./dsl.nix;
+  diamond.dag = {
+    nodes.a = { };
+    nodes.b.inputs.a = { }; # b->a
+    nodes.c.inputs.a = { }; # c->a
+    nodes.d.inputs.b = { }; # d->b
+    nodes.d.inputs.c = { }; # d->c
+  };
+
+  #   A   B   C     D   E
+  #   \   |  /      |   |
+  #     U  V        W   X
+  sunset.dag = {
+    nodes =
+      let
+        abcInputs = {
+          u = { };
+          v = { };
+        };
+      in
+      {
+        a = {
+          request = true;
+          inputs = abcInputs;
+        };
+        b = {
+          request = true;
+          inputs = abcInputs;
+        };
+        c = {
+          request = true;
+          inputs = abcInputs;
+        };
+
+        d = {
+          request = true;
+          inputs.w = { };
+        };
+        e = {
+          request = true;
+          inputs.x = { };
+        };
+
+        u = { };
+        v = { };
+        w = { };
+        x = { };
+      };
+  };
+in
+builtins.mapAttrs
+  (
+    name: value:
+    pkgs.testers.runNixOSTest (
+      {
+        inherit name;
+        testScript = ''
+          start_all()
+          substituter.wait_for_unit("nix-serve.service")
+          builder.succeed("dag-test")
+        '';
+      }
+      // value
+      // {
+        imports = value.imports ++ [ dsl ];
+      }
+    )
+  )
+  {
+    diamond-unbuilt-0 = {
+      imports = [
+        {
+          dag.needBuilds = 0;
+          dag.needDownloads = 0;
+        }
+        diamond
+      ];
+    };
+    diamond-unbuilt-2 = {
+      imports = [
+        {
+          dag.nodes.a.cache = "remote";
+          dag.nodes.b.cache = "remote";
+          dag.nodes.d.request = true;
+          dag.needBuilds = 2;
+          dag.needDownloads = 2;
+        }
+        diamond
+      ];
+    };
+    diamond-unbuilt-4 = {
+      imports = [
+        {
+          dag.nodes.d.request = true;
+          dag.needBuilds = 4;
+          dag.needDownloads = 0;
+        }
+        diamond
+      ];
+    };
+
+    sunset-unbuilt-0 = {
+      imports = [
+        {
+          # all builds
+          dag.needBuilds = 9;
+          # all builds allowed
+          dag.allowBuilds = 5;
+          # chosen builds requested
+          dag.choseBuilds = 3;
+        }
+        sunset
+      ];
+    };
+  }