Add Nix flake.

.gitignore

@@ -1 +1,2 @@
 target/
+/result

flake.nix

@@ -0,0 +1,64 @@
+{
+  description = "Settings daemon for the COSMIC desktop environment";
+
+  inputs = {
+    nixpkgs.url = "github:NixOS/nixpkgs/nixpkgs-unstable";
+    flake-utils.url = "github:numtide/flake-utils";
+    nix-filter.url = "github:numtide/nix-filter";
+    crane = {
+      url = "github:ipetkov/crane";
+      inputs.nixpkgs.follows = "nixpkgs";
+    };
+    fenix = {
+      url = "github:nix-community/fenix";
+      inputs.nixpkgs.follows = "nixpkgs";
+    };
+  };
+
+  outputs = { self, nixpkgs, flake-utils, nix-filter, crane, fenix }:
+    flake-utils.lib.eachSystem [ "x86_64-linux" "aarch64-linux" ] (system:
+      let
+        pkgs = nixpkgs.legacyPackages.${system};
+        craneLib = crane.lib.${system}.overrideToolchain fenix.packages.${system}.stable.toolchain;
+
+        pkgDef = {
+          src = nix-filter.lib.filter {
+            root = ./.;
+            include = [
+              ./src
+              ./Cargo.toml
+              ./Cargo.lock
+            ];
+          };
+          nativeBuildInputs = with pkgs; [ pkg-config ];
+          buildInputs = with pkgs; [
+            systemd # For libudev
+          ];
+        };
+
+        cargoArtifacts = craneLib.buildDepsOnly pkgDef;
+        cosmic-settings-daemon = craneLib.buildPackage (pkgDef // {
+          inherit cargoArtifacts;
+        });
+      in {
+        checks = {
+          inherit cosmic-settings-daemon;
+        };
+
+        packages.default = cosmic-settings-daemon;
+
+        apps.default = flake-utils.lib.mkApp {
+          drv = cosmic-settings-daemon;
+        };
+
+        devShells.default = pkgs.mkShell {
+          inputsFrom = builtins.attrValues self.checks.${system};
+        };
+      });
+
+  nixConfig = {
+    # Cache for the Rust toolchain in fenix
+    extra-substituters = [ "https://nix-community.cachix.org" ];
+    extra-trusted-public-keys = [ "nix-community.cachix.org-1:mB9FSh9qf2dCimDSUo8Zy7bkq5CX+/rkCWyvRCYg3Fs=" ];
+  };
+}