Fix gradle scripts for SDK 34

OsmAnd-java/build.gradle

@@ -6,19 +6,18 @@ configurations {
 	android
 }
 
-//tasks.withType(JavaCompile) {
-//	sourceCompatibility = "1.7"
-//	targetCompatibility = "1.7"
-//	options.encoding = 'UTF-8'
-//}
+tasks.withType(JavaCompile).configureEach {
+	sourceCompatibility = "17"
+	targetCompatibility = "17"
+}
 
-task collectRoutingResources(type: Sync) {
+tasks.register('collectRoutingResources', Sync) {
 	from "../../resources/routing"
 	into "src/main/resources/net/osmand/router"
 	include "*.xml"
 }
 
-task collectMiscResources(type: Copy) {
+tasks.register('collectMiscResources', Copy) {
 	into "src/main/resources/net/osmand/osm"
 	from("../../resources/obf_creation") {
 		include "rendering_types.xml"
@@ -28,27 +27,27 @@ task collectMiscResources(type: Copy) {
 	}
 }
 
-task collectRenderingStylesResources(type: Sync) {
+tasks.register('collectRenderingStylesResources', Sync) {
 	from "../../resources/rendering_styles"
 	into "src/main/resources/net/osmand/render"
 	include "*.xml"
 }
 
-task collectRegionsInfoResources(type: Download)  {
+tasks.register('collectRegionsInfoResources', Download) {
 	src 'https://creator.osmand.net/basemap/regions.ocbf'
 	dest 'src/main/resources/net/osmand/map/regions.ocbf'
 	onlyIfModified true
 }
 
 
-task collectTestPhrasesResources(type: Copy) {
+tasks.register('collectTestPhrasesResources', Copy) {
 	into "src/test/resources/phrases/en/"
 	from("../OsmAnd/res/values") {
 		include "phrases.xml"
 	}
 }
 
-task collectTestResources(type: Copy) {
+tasks.register('collectTestResources', Copy) {
 	into "src/test/resources/"
 	from("../../resources/test-resources") {
 		include "*"
@@ -71,23 +70,23 @@ processTestResources {
 	dependsOn collectTestResources, collectTestPhrasesResources
 }
 
-task collectExternalResources {
+tasks.register('collectExternalResources') {
 	dependsOn collectRoutingResources,
-		collectRenderingStylesResources,
-		collectRegionsInfoResources,
-		collectTestResources,
-		collectTestPhrasesResources,
-		collectMiscResources
+			collectRenderingStylesResources,
+			collectRegionsInfoResources,
+			collectTestResources,
+			collectTestPhrasesResources,
+			collectMiscResources
 }
 
-task androidJar(type: Jar) {
+tasks.register('androidJar', Jar) {
 	if (!project.hasProperty('osmandCoreSimple')) {
 		dependsOn collectExternalResources, build
 	} else {
 		dependsOn build
 	}
 	archiveAppendix = "android"
-	from (sourceSets.main.java.classesDirectory) {
+	from(sourceSets.main.java.classesDirectory) {
 		exclude("**/PlatformUtil.*")
 	}
 	from sourceSets.main.resources

OsmAnd-shared/build.gradle.kts

@@ -8,7 +8,7 @@ kotlin {
     androidTarget {
         compilations.all {
             kotlinOptions {
-                jvmTarget = "11"
+                jvmTarget = "17"
             }
         }
     }
@@ -45,10 +45,10 @@ android {
     namespace = "net.osmand.shared"
     compileSdk = 34
     compileOptions {
-        sourceCompatibility = JavaVersion.VERSION_11
-        targetCompatibility = JavaVersion.VERSION_11
+        sourceCompatibility = JavaVersion.VERSION_17
+        targetCompatibility = JavaVersion.VERSION_17
     }
     defaultConfig {
-        minSdk = 23
+        minSdk = 24
     }
 }

OsmAnd-telegram/build.gradle

@@ -4,13 +4,16 @@ apply plugin: 'kotlin-android'
 android {
 	compileSdk 34
 	buildToolsVersion = "34.0.0"
-
 	namespace = "net.osmand.telegram"
 
+	compileOptions {
+		sourceCompatibility = JavaVersion.VERSION_17
+		targetCompatibility = JavaVersion.VERSION_17
+	}
+
 	sourceSets {
 		main {
 			manifest.srcFile "AndroidManifest.xml"
-			jni.srcDirs = []
 			jniLibs.srcDirs = ["libs"]
 			aidl.srcDirs = ["src"]
 			java.srcDirs = ["src"]
@@ -56,6 +59,7 @@ android {
 			dimension "abi"
 		}
 	}
+
 	signingConfigs {
 		development {
 			storeFile file("../keystores/debug.keystore")
@@ -101,58 +105,60 @@ android {
 		def variant = it
 		def taskName = variant.name.capitalize()
 		def mergeAssetsTaskName = "merge${taskName}Assets"
-		def osmandTask = tasks.findByName(mergeAssetsTaskName)
-		if (osmandTask != null) {
+		tasks.named(mergeAssetsTaskName).configure { osmandTask ->
 			println(osmandTask.getName())
 			osmandTask.dependsOn(collectFonts)
 		}
 		def mapSourceSetPathsName= "map${taskName}SourceSetPaths"
-		osmandTask = tasks.findByName(mapSourceSetPathsName)
-		if(osmandTask != null) {
+		tasks.named(mapSourceSetPathsName).configure { osmandTask ->
 			println(osmandTask.getName())
 		}
 	}
 
 }
 
-task downloadTdLibzip {
+tasks.register('downloadTdLibzip') {
 	doLast {
 		ant.get(src: 'https://osmand.net/uploads/libs/tdlib.zip', dest: 'tdlib.zip', skipexisting: 'true')
 		ant.unzip(src: 'tdlib.zip', dest: 'tdlib/')
 	}
 }
 
-task copyNativeLibs(type: Copy) {
+tasks.register('copyNativeLibs', Copy) {
 	dependsOn downloadTdLibzip
 	from "tdlib/tdlib/libs"
 	into "libs"
 }
 
-task copyJavaSources(type: Copy) {
+tasks.register('copyJavaSources', Copy) {
 	dependsOn downloadTdLibzip
 	from "tdlib/tdlib/java"
 	into "src"
 }
 
-task downloadPrebuiltTelegram {
+tasks.register('downloadPrebuiltTelegram') {
 	dependsOn downloadTdLibzip, copyNativeLibs, copyJavaSources
 }
 
-task collectFonts(type: Copy) {
+tasks.register('collectFonts', Copy) {
 	from "../../resources/fonts"
 	from "../../resources/fonts-telegram"
 	into "assets/fonts"
 	include "*.ttf"
 }
 
-task collectExternalResources {
+tasks.register('collectExternalResources') {
 	dependsOn collectFonts
 }
 
 afterEvaluate {
-	android.applicationVariants.all { variant ->
-		variant.javaCompiler.dependsOn(downloadPrebuiltTelegram, collectExternalResources)
-		variant.preBuild.dependsOn(downloadPrebuiltTelegram)
+	android.applicationVariants.configureEach { variant ->
+		variant.javaCompileProvider.configure { compileTask ->
+			compileTask.dependsOn downloadPrebuiltTelegram, collectExternalResources
+		}
+		variant.preBuildProvider.configure { preBuildTask ->
+			preBuildTask.dependsOn downloadPrebuiltTelegram
+		}
 	}
 }