Add nix/flake support

Example:

nix build github:mimblewimble/grin-wallet

./result/bin/grin-wallet --help

flake.nix

@@ -0,0 +1,55 @@
+{
+  description = "Reference Grin Wallet.";
+
+  inputs = {
+    nixpkgs.url = "github:NixOS/nixpkgs/release-22.11";
+  };
+
+  outputs = { self, nixpkgs, }:
+    let
+      forAllSystems = with nixpkgs;
+        lib.genAttrs lib.systems.flakeExposed;
+
+      nixpkgsFor = forAllSystems (system: import nixpkgs
+        { inherit system; overlays = [ self.overlay ]; }
+      );
+    in
+    {
+      overlay = final: prev:
+        with final;
+        {
+          grin-wallet = pkgs.rustPlatform.buildRustPackage {
+            pname = "grin-wallet";
+            version = "5.1.0";
+            src = ./.;
+
+            cargoLock = {
+              lockFile = ./Cargo.lock;
+              outputHashes = {
+                "grin_api-5.2.0-alpha.1" = "sha256-/cdspz637KXrbo/ckmpubHttOBtP5VTnyuLuFqVqZ/w=";
+              };
+            };
+
+            nativeBuildInputs = with pkgs;
+              [
+                pkg-config
+                llvmPackages_latest.clang
+              ];
+
+            buildInputs = [ pkgs.openssl ];
+
+            LIBCLANG_PATH =
+              "${pkgs.llvmPackages_latest.libclang.lib}/lib";
+
+            # do not let test results block the build process
+            doCheck = false;
+          };
+        };
+
+      packages = forAllSystems (
+        system: {
+          default = nixpkgsFor.${system}.grin-wallet;
+        }
+      );
+    };
+}