build.gradle

buildscript {
    repositories {
        mavenCentral()
    }
    dependencies {
        classpath 'com.github.townsfolk:gradle-release:1.2'
    }
}

repositories {
    mavenCentral()
}

ext {
    sonatypeUser = System.env.SONATYPE_USER
    sonatypePass = System.env.SONATYPE_PASS
}

apply plugin: 'idea'
apply plugin: 'maven'
apply plugin: 'groovy'
apply plugin: 'release'

group 'org.scoverage'

configurations {
    scoverage
    compile.extendsFrom scoverage
}

dependencies {
    compile gradleApi()
    compile localGroovy()
    scoverage 'org.scoverage:scalac-scoverage-plugin_2.10:0.99.5'
}

task groovydocJar(type: Jar, dependsOn: groovydoc) {
    classifier = 'groovydoc'
    from "$buildDir/docs/groovydoc"
}

task sourcesJar(type: Jar) {
    from sourceSets.main.allSource
    classifier = 'sources'
}

test {
    dependsOn jar
}

artifacts {
    archives jar
    archives groovydocJar
    archives sourcesJar
}

if (project.properties.containsKey('signing.keyId')) {
    apply plugin: 'signing'
    signing {
        sign configurations.archives
    }
}

uploadArchives {
    repositories {
        mavenDeployer {
            if (project.properties.containsKey('signing.keyId')) {
              beforeDeployment { MavenDeployment deployment -> signing.signPom(deployment) }
            }

            snapshotRepository(url: 'https://oss.sonatype.org/content/repositories/snapshots') {
                authentication(userName: sonatypeUser, password: sonatypePass)
            }

            repository(url: "https://oss.sonatype.org/service/local/staging/deploy/maven2/") {
                authentication(userName: sonatypeUser, password: sonatypePass)
            }

            pom.project {
                name 'GradleScoverage'
                description 'gradle-scoverage is a Gradle plugin for calculating code coverage using Scoverage'
                url 'http://scoverage.org'

                scm {
                    url 'scm:git:https://github.com/scoverage/gradle-scoverage.git'
                    developerConnection 'scm:git:https://github.com/scoverage/gradle-scoverage.git'
                }

                licenses {
                    license {
                        name 'The Apache Software License, Version 2.0'
                        url 'http://www.apache.org/licenses/LICENSE-2.0.txt'
                        distribution 'repo'
                    }
                }

                developers {
                    developer {
                        id 'maiflai'
                    }
                    developer {
                        id 'ubourdon'
                    }
                    developer {
                        id 'D-Roch'
                    }
                }
            }
        }
    }
}