Package with nix

.envrc

@@ -0,0 +1 @@
+use flake

.gitignore

@@ -5,3 +5,5 @@ resource/private
 *.bs.js
 lib/bs
 node_modules/
+result
+.direnv

bin/sdl2/dune

@@ -1,4 +1,5 @@
 (executables
  (names main bench)
+ (public_names camlboy-sdl camlboy-sdl-bench)
  (ocamlopt_flags -O3)
  (libraries camlboy_lib tsdl))

dune

@@ -0,0 +1,11 @@
+(data_only_dirs chain node_modules)
+
+(env
+ (static
+  (flags
+   (:standard -ccopt -static))
+  (ocamlopt_flags
+   (:standard -O3 -unbox-closures)))
+ (release
+  (ocamlopt_flags
+   (:standard -O3 -unbox-closures))))

flake.nix

@@ -0,0 +1,49 @@
+{
+  inputs = {
+    nixpkgs.url = "github:nixos/nixpkgs/nixos-unstable";
+    flake-utils.url = "github:numtide/flake-utils";
+
+    ocaml-overlay.url = "github:anmonteiro/nix-overlays";
+    ocaml-overlay.inputs.flake-utils.follows = "flake-utils";
+
+    nix-filter.url = "github:numtide/nix-filter";
+  };
+
+  outputs = { self, nixpkgs, flake-utils, ocaml-overlay, nix-filter }:
+    let
+      supported_ocaml_versions = [ "ocamlPackages_4_12" "ocamlPackages_4_13" "ocamlPackages_5_00" ];
+      out = system:
+        let
+          pkgs = import nixpkgs {
+            inherit system;
+            overlays = [ ocaml-overlay.overlay ];
+          };
+          inherit (pkgs) lib;
+          myPkgs = pkgs.recurseIntoAttrs (import ./nix {
+            inherit pkgs nix-filter;
+            doCheck = true;
+          }).native;
+          myDrvs = lib.filterAttrs (_: value: lib.isDerivation value) myPkgs;
+        in
+        {
+          devShell = (pkgs.mkShell {
+            inputsFrom = lib.attrValues myDrvs;
+            buildInputs = with pkgs;
+              with ocamlPackages; [
+                ocaml-lsp
+                ocamlformat
+                odoc
+                ocaml
+                dune_3
+                nixfmt
+                utop
+              ];
+          });
+
+          defaultPackage = myPkgs.camlboy;
+        };
+    in
+    with flake-utils.lib; eachSystem defaultSystems out // {
+      overlays = { default = import ./nix/overlay.nix supported_ocaml_versions nix-filter; };
+    };
+}

lib/dune

@@ -1,5 +1,6 @@
 (library
  (name camlboy_lib)
+ (public_name camlboy)
  (libraries bigstringaf))
 
 (include_subdirs unqualified)

nix/camlboy.nix

@@ -0,0 +1,43 @@
+{ pkgs, nix-filter, stdenv, lib, ocamlPackages, static ? false, doCheck }:
+
+with ocamlPackages;
+buildDunePackage {
+  pname = "camlboy";
+  version = "0.1.0";
+
+  src = nix-filter.lib.filter {
+    root = ../.;
+    # TODO: package the brr and include the browser front end
+    include = [
+      "lib"
+      "bin/sdl2"
+      "dune"
+      "dune-project"
+      "camlboy.opam"
+      "resources"
+    ];
+  };
+
+  # Static builds support, note that you need a static profile in your dune file
+  buildPhase = ''
+    echo "running ${if static then "static" else "release"} build"
+    dune build --profile=${if static then "static" else "release"}
+  '';
+
+  checkInputs = [ ];
+
+  propagatedBuildInputs = [
+    ppx_deriving
+    tsdl
+    base
+    bigstringaf
+    ppx_jane
+    odoc
+  ];
+
+  inherit doCheck;
+
+  meta = {
+    description = "A Game Boy emulator written in OCaml that runs in your browser";
+  };
+}

nix/default.nix

@@ -0,0 +1,22 @@
+{ pkgs ? import ./sources.nix { }, nix-filter, doCheck ? false }:
+
+{
+  native = {
+    camlboy = pkgs.callPackage ./camlboy.nix {
+      inherit doCheck nix-filter;
+    };
+  };
+
+  musl64 =
+    let
+      pkgsCross = pkgs.pkgsCross.musl64.pkgsStatic;
+
+    in
+    {
+      camlboy = pkgsCross.callPackage ./camlboy.nix {
+        static = true;
+        inherit doCheck;
+        ocamlPackages = pkgsCross.ocamlPackages;
+      };
+    };
+}

nix/overlay.nix

@@ -0,0 +1,19 @@
+supported_ocaml_versions: nix-filter:
+
+final: prev: {
+  ocaml-ng = builtins.mapAttrs
+    (name: ocamlVersion:
+      # If the current ocamlVersion exists in supported versions
+      (if (builtins.any (x: x == name) supported_ocaml_versions) then
+        ocamlVersion.overrideScope'
+          (oself: osuper: {
+            camlboy = (prev.callPackage ./camlboy.nix {
+              inherit nix-filter;
+              ocamlPackages = oself;
+              doCheck = true;
+            });
+          })
+      else
+        ocamlVersion))
+    prev.ocaml-ng;
+}