Refactor connection pool

config/config.example.yml

@@ -145,7 +145,7 @@ https_only: false
 #disable_proxy: false
 
 ##
-## Size of the HTTP pool used to connect to youtube. Each
+## Max size of the HTTP pool used to connect to youtube. Each
 ## domain ('youtube.com', 'ytimg.com', ...) has its own pool.
 ##
 ## Accepted values: a positive integer
@@ -154,6 +154,35 @@ https_only: false
 #pool_size: 100
 
 
+##
+## Max idle size of the HTTP pool used to connect to youtube. Each
+## domain ('youtube.com', 'ytimg.com', ...) has its own pool.
+##
+## This means that when releasing a connection back into the pool, it will
+## be closed if there are already more than idle_pool_size connections within
+## the pool
+##
+## Do note that idle connections are kept around forever without any way of
+## timing them out.
+##
+## When unset this value has the same value as pool_size 
+##
+## Accepted values: a positive integer
+## Default: <none> (internally this means that it has the same value as pool_size)
+##
+#idle_pool_size:
+
+##
+## Amount of seconds to wait for a client to be free from the pool
+## before raising an error
+##
+##
+## Accepted values: a positive integer
+## Default: 5
+##
+#pool_checkout_timeout: 5
+
+
 ##
 ## Additional cookies to be sent when requesting the youtube API.
 ##

src/invidious.cr

@@ -35,6 +35,7 @@ require "protodec/utils"
 
 require "./invidious/database/*"
 require "./invidious/database/migrations/*"
+require "./invidious/connection/*"
 require "./invidious/http_server/*"
 require "./invidious/helpers/*"
 require "./invidious/yt_backend/*"
@@ -91,11 +92,21 @@ SOFTWARE = {
   "branch"  => "#{CURRENT_BRANCH}",
 }
 
-YT_POOL = YoutubeConnectionPool.new(YT_URL, capacity: CONFIG.pool_size)
+YT_POOL = Invidious::ConnectionPool::Pool.new(
+  YT_URL,
+  max_capacity: CONFIG.pool_size,
+  idle_capacity: CONFIG.idle_pool_size,
+  timeout: CONFIG.pool_checkout_timeout
+)
 
 # Image request pool
 
-GGPHT_POOL = YoutubeConnectionPool.new(URI.parse("https://yt3.ggpht.com"), capacity: CONFIG.pool_size)
+GGPHT_POOL = Invidious::ConnectionPool::Pool.new(
+  URI.parse("https://yt3.ggpht.com"),
+  max_capacity: CONFIG.pool_size,
+  idle_capacity: CONFIG.idle_pool_size,
+  timeout: CONFIG.pool_checkout_timeout
+)
 
 # CLI
 Kemal.config.extra_options do |parser|

src/invidious/config.cr

@@ -138,8 +138,15 @@ class Config
   property port : Int32 = 3000
   # Host to bind (overridden by command line argument)
   property host_binding : String = "0.0.0.0"
-  # Pool size for HTTP requests to youtube.com and ytimg.com (each domain has a separate pool of `pool_size`)
+  # Max pool size for HTTP requests to youtube.com and ytimg.com (each domain has a separate pool)
   property pool_size : Int32 = 100
+
+  # Idle pool size for HTTP requests to youtube.com and ytimg.com (each domain has a separate pool)
+  property idle_pool_size : Int32? = nil
+
+  # Amount of seconds to wait for a client to be free from the pool before rasing an error
+  property pool_checkout_timeout : Int32 = 5
+
   # HTTP Proxy configuration
   property http_proxy : HTTPProxyConfig? = nil
 

src/invidious/yt_backend/connection_pool.cr → src/invidious/connection/client.cr

@@ -1,51 +1,3 @@
-# Mapping of subdomain => YoutubeConnectionPool
-# This is needed as we may need to access arbitrary subdomains of ytimg
-private YTIMG_POOLS = {} of String => YoutubeConnectionPool
-
-struct YoutubeConnectionPool
-  property! url : URI
-  property! capacity : Int32
-  property! timeout : Float64
-  property pool : DB::Pool(HTTP::Client)
-
-  def initialize(url : URI, @capacity = 5, @timeout = 5.0)
-    @url = url
-    @pool = build_pool()
-  end
-
-  def client(&)
-    conn = pool.checkout
-    # Proxy needs to be reinstated every time we get a client from the pool
-    conn.proxy = make_configured_http_proxy_client() if CONFIG.http_proxy
-
-    begin
-      response = yield conn
-    rescue ex
-      conn.close
-      conn = make_client(url, force_resolve: true)
-
-      response = yield conn
-    ensure
-      pool.release(conn)
-    end
-
-    response
-  end
-
-  private def build_pool
-    options = DB::Pool::Options.new(
-      initial_pool_size: 0,
-      max_pool_size: capacity,
-      max_idle_pool_size: capacity,
-      checkout_timeout: timeout
-    )
-
-    DB::Pool(HTTP::Client).new(options) do
-      next make_client(url, force_resolve: true)
-    end
-  end
-end
-
 def add_yt_headers(request)
   request.headers.delete("User-Agent") if request.headers["User-Agent"] == "Crystal"
   request.headers["User-Agent"] ||= "Mozilla/5.0 (Windows NT 10.0; Win64; x64) AppleWebKit/537.36 (KHTML, like Gecko) Chrome/128.0.0.0 Safari/537.36"
@@ -99,18 +51,3 @@ def make_configured_http_proxy_client
     password: config_proxy.password,
   )
 end
-
-# Fetches a HTTP pool for the specified subdomain of ytimg.com
-#
-# Creates a new one when the specified pool for the subdomain does not exist
-def get_ytimg_pool(subdomain)
-  if pool = YTIMG_POOLS[subdomain]?
-    return pool
-  else
-    LOGGER.info("ytimg_pool: Creating a new HTTP pool for \"https://#{subdomain}.ytimg.com\"")
-    pool = YoutubeConnectionPool.new(URI.parse("https://#{subdomain}.ytimg.com"), capacity: CONFIG.pool_size)
-    YTIMG_POOLS[subdomain] = pool
-
-    return pool
-  end
-end

src/invidious/connection/pool.cr

@@ -0,0 +1,88 @@
+module Invidious::ConnectionPool
+  struct Pool
+    property! url : URI
+    property! max_capacity : Int32
+    property! idle_capacity : Int32
+    property! timeout : Float64
+    property pool : DB::Pool(HTTP::Client)
+
+    def initialize(
+      url : URI,
+      *,
+      @max_capacity : Int32 = 5,
+      idle_capacity : Int32? = nil,
+      @timeout : Float64 = 5.0
+    )
+      if idle_capacity.nil?
+        @idle_capacity = @max_capacity
+      else
+        @idle_capacity = idle_capacity
+      end
+
+      @url = url
+
+      @pool = build_pool()
+    end
+
+    # Checks out a client in the pool
+    def client(&)
+      pool.checkout do |http_client|
+        # Proxy needs to be reinstated every time we get a client from the pool
+        http_client.proxy = make_configured_http_proxy_client() if CONFIG.http_proxy
+
+        response = yield http_client
+
+        return response
+      rescue ex
+        # Prevent broken client from being checked back into the pool
+        pool.delete(http_client)
+        raise ConnectionPool::Error.new(ex.message, cause: ex)
+      end
+    rescue ex : DB::PoolTimeout
+      # Failed to checkout a client
+      raise ConnectionPool::Error.new(ex.message, cause: ex)
+    end
+
+    private def build_pool
+      # We call the getter for the instance variables instead of using them directly
+      # because the getters defined by property! ensures that the value is not a nil
+      options = DB::Pool::Options.new(
+        initial_pool_size: 0,
+        max_pool_size: max_capacity,
+        max_idle_pool_size: idle_capacity,
+        checkout_timeout: timeout
+      )
+
+      DB::Pool(HTTP::Client).new(options) do
+        next make_client(url, force_resolve: true)
+      end
+    end
+  end
+
+  class Error < Exception
+  end
+
+  # Mapping of subdomain => Invidious::ConnectionPool::Pool
+  # This is needed as we may need to access arbitrary subdomains of ytimg
+  private YTIMG_POOLS = {} of String => Invidious::ConnectionPool::Pool
+
+  # Fetches a HTTP pool for the specified subdomain of ytimg.com
+  #
+  # Creates a new one when the specified pool for the subdomain does not exist
+  def self.get_ytimg_pool(subdomain)
+    if pool = YTIMG_POOLS[subdomain]?
+      return pool
+    else
+      LOGGER.info("ytimg_pool: Creating a new HTTP pool for \"https://#{subdomain}.ytimg.com\"")
+      pool = Invidious::ConnectionPool::Pool.new(
+        URI.parse("https://#{subdomain}.ytimg.com"),
+        max_capacity: CONFIG.pool_size,
+        idle_capacity: CONFIG.idle_pool_size,
+        timeout: CONFIG.pool_checkout_timeout
+      )
+      YTIMG_POOLS[subdomain] = pool
+
+      return pool
+    end
+  end
+end

src/invidious/routes/images.cr

@@ -42,7 +42,7 @@ module Invidious::Routes::Images
     end
 
     begin
-      get_ytimg_pool(authority).client &.get(url, headers) do |resp|
+      Invidious::ConnectionPool.get_ytimg_pool(authority).client &.get(url, headers) do |resp|
         env.response.headers["Connection"] = "close"
         return self.proxy_image(env, resp)
       end
@@ -65,7 +65,7 @@ module Invidious::Routes::Images
     end
 
     begin
-      get_ytimg_pool("i9").client &.get(url, headers) do |resp|
+      Invidious::ConnectionPool.get_ytimg_pool("i9").client &.get(url, headers) do |resp|
         return self.proxy_image(env, resp)
       end
     rescue ex
@@ -111,7 +111,7 @@ module Invidious::Routes::Images
     if name == "maxres.jpg"
       build_thumbnails(id).each do |thumb|
         thumbnail_resource_path = "/vi/#{id}/#{thumb[:url]}.jpg"
-        if get_ytimg_pool("i9").client &.head(thumbnail_resource_path, headers).status_code == 200
+        if Invidious::ConnectionPool.get_ytimg_pool("i9").client &.head(thumbnail_resource_path, headers).status_code == 200
           name = thumb[:url] + ".jpg"
           break
         end
@@ -127,7 +127,7 @@ module Invidious::Routes::Images
     end
 
     begin
-      get_ytimg_pool("i").client &.get(url, headers) do |resp|
+      Invidious::ConnectionPool.get_ytimg_pool("i").client &.get(url, headers) do |resp|
         return self.proxy_image(env, resp)
       end
     rescue ex