Merge #56

56: add formatter schema r=roberth a=zimbatm This is needed for flakes that want to support `nix fmt`. Right now it's missing some testing as I didn't find a test framework for it. Needed by numtide/treefmt#169 Co-authored-by: zimbatm <[email protected]> Co-authored-by: Jonas Chevalier <[email protected]>
hercules-ci · Sep 20, 2022 · f17e9db · f17e9db
2 parents 89cce58 + d6fdbbc
commit f17e9db
Show file tree

Hide file tree

Showing 2 changed files with 56 additions and 0 deletions.
diff --git a/all-modules.nix b/all-modules.nix
@@ -6,6 +6,7 @@
     ./modules/darwinModules.nix
     ./modules/devShells.nix
     ./modules/flake.nix
+    ./modules/formatter.nix
     ./modules/legacyPackages.nix
     ./modules/moduleWithSystem.nix
     ./modules/nixosConfigurations.nix

diff --git a/modules/formatter.nix b/modules/formatter.nix
@@ -0,0 +1,55 @@
+{ config, lib, flake-parts-lib, ... }:
+let
+  inherit (lib)
+    filterAttrs
+    mapAttrs
+    mkOption
+    optionalAttrs
+    types
+    ;
+  inherit (flake-parts-lib)
+    mkSubmoduleOptions
+    mkPerSystemOption
+    ;
+in
+{
+  options = {
+    flake = mkSubmoduleOptions {
+      formatter = mkOption {
+        type = types.lazyAttrsOf types.package;
+        default = { };
+        description = ''
+          Per system package used by <literal>nix fmt</literal>.
+        '';
+      };
+    };
+
+    perSystem = mkPerSystemOption ({ config, ... }: {
+      _file = ./formatter.nix;
+      options = {
+        formatter = mkOption {
+          type = types.nullOr types.package;
+          default = null;
+          description = ''
+            A package used by <literal>nix fmt</literal>.
+          '';
+        };
+      };
+    });
+  };
+  config = {
+    flake.formatter =
+      mapAttrs
+        (k: v: v.formatter)
+        (filterAttrs
+          (k: v: v.formatter != null)
+          config.allSystems
+        );
+
+    perInput = system: flake:
+      optionalAttrs (flake?formatter.${system}) {
+        formatter = flake.formatter.${system};
+      };
+
+  };
+}