Add Mix.Tasks.Compile.reenable

lib/mix/lib/mix/task.compiler.ex

@@ -162,4 +162,33 @@ defmodule Mix.Task.Compiler do
         {:noop, []}
     end
   end
+
+  @doc """
+  Reenables given compilers so they can be executed again down the stack.
+
+  If an umbrella project reenables compilers, they are re-enabled for all
+  child projects.
+
+  Default is `[]`, for none compilers to be reenabled.
+  This task always re-enables `"compiler.all"`.
+  """
+  @spec reenable([{:compilers, compilers}]) :: :ok when compilers: :all | [Mix.Task.task_name()]
+  def reenable(opts \\ []) do
+    if not Keyword.keyword?(opts) do
+      IO.warn(
+        "Mix.Task.Compiler.reenable/1 expects a keyword list " <>
+          "as an argument with compilers: [compiler()], " <>
+          "reenabling no compiler"
+      )
+    else
+      compilers =
+        case Keyword.get(opts, :compilers, []) do
+          :all -> Mix.Tasks.Compile.compilers()
+          list when is_list(list) -> list
+        end
+
+      Enum.each(["loadpaths", "compile", "compile.all"], &Mix.Task.reenable(&1))
+      Enum.each(compilers, &Mix.Task.reenable("compile.#{&1}"))
+    end
+  end
 end

lib/mix/lib/mix/task.ex

@@ -613,8 +613,11 @@ defmodule Mix.Task do
   child projects.
   """
   @spec reenable(task_name) :: :ok
-  def reenable(task) when is_binary(task) or is_atom(task) do
-    task = to_string(task)
+  def reenable(task) when is_atom(task) do
+    task |> to_string() |> reenable()
+  end
+
+  def reenable(task) when is_binary(task) do
     proj = Mix.Project.get()
     recursive = (module = get(task)) && recursive(module)
 

lib/mix/test/mix/tasks/compile.elixir_test.exs

@@ -874,6 +874,33 @@ defmodule Mix.Tasks.Compile.ElixirTest do
     end)
   end
 
+  test "recompiles newly created files" do
+    in_fixture("no_mixfile", fn ->
+      Mix.Project.push(MixTest.Case.Sample)
+
+      assert Mix.Tasks.Compile.Elixir.run(["--verbose"]) == {:ok, []}
+      assert_received {:mix_shell, :info, ["Compiled lib/a.ex"]}
+      assert_received {:mix_shell, :info, ["Compiled lib/b.ex"]}
+
+      Mix.shell().flush()
+
+      File.write!("lib/z.ex", """
+      defmodule Z do
+        def ok, do: :ok
+      end
+      """)
+
+      Mix.Task.reenable("compile.elixir")
+      assert {:ok, []} = Mix.Tasks.Compile.Elixir.run(["--verbose"])
+
+      assert_received {:mix_shell, :info, ["Compiled lib/z.ex"]}
+      refute_received {:mix_shell, :info, ["Compiled lib/a.ex"]}
+      refute_received {:mix_shell, :info, ["Compiled lib/b.ex"]}
+
+      assert File.regular?("_build/dev/lib/sample/ebin/Elixir.Z.beam")
+    end)
+  end
+
   test "recompiles dependent changed modules" do
     in_fixture("no_mixfile", fn ->
       Mix.Project.push(MixTest.Case.Sample)

lib/mix/test/mix/tasks/compile_test.exs

@@ -125,6 +125,35 @@ defmodule Mix.Tasks.CompileTest do
     end)
   end
 
+  test "recompiles newly created files" do
+    in_fixture("no_mixfile", fn ->
+      assert Mix.Tasks.Compile.run(["--verbose"]) == {:ok, []}
+      Mix.shell().flush()
+
+      File.write!("lib/z.ex", """
+      defmodule Z do
+        def ok, do: :ok
+      end
+      """)
+
+      assert :ok = Mix.Task.reenable("compile")
+      assert {:noop, []} = Mix.Task.run("compile")
+      refute File.regular?("_build/dev/lib/sample/ebin/Elixir.Z.beam")
+
+      assert :ok = Mix.Task.Compiler.reenable()
+      assert {:noop, []} = Mix.Task.run("compile")
+      refute File.regular?("_build/dev/lib/sample/ebin/Elixir.Z.beam")
+
+      assert :ok = Mix.Task.Compiler.reenable(compilers: ["erlang"])
+      assert {:noop, []} = Mix.Task.run("compile")
+      refute File.regular?("_build/dev/lib/sample/ebin/Elixir.Z.beam")
+
+      assert :ok = Mix.Task.Compiler.reenable(compilers: ["elixir", "erlang"])
+      assert {:ok, []} = Mix.Task.run("compile")
+      assert File.regular?("_build/dev/lib/sample/ebin/Elixir.Z.beam")
+    end)
+  end
+
   test "recompiles app cache if manifest changes" do
     in_fixture("no_mixfile", fn ->
       Mix.Tasks.Compile.run(["--force"])