Add Mix.Tasks.Compile.reenable

lib/mix/lib/mix/tasks/compile.ex

@@ -98,6 +98,27 @@ defmodule Mix.Tasks.Compile do
     |> maybe_prepend(:yecc)
   end
 
+  @doc """
+  Reenables given compilers so they can be executed again down the stack.
+
+  If an umbrella project reenables compilers, they are re-enabled for all
+  child projects.
+
+  Default is `[]`, for none compilers to be reenabled.
+  This task always re-enables `"compiler.all"`.
+  """
+  @spec reenable([{:compilers, compilers}]) :: :ok when compilers: :all | [Mix.Task.task_name()]
+  def reenable(opts \\ []) do
+    compilers =
+      case Keyword.get(opts, :compilers, :all) do
+        :all -> compilers()
+        list when is_list(list) -> list
+      end
+
+    Enum.each(["compile", "compile.all"], &Mix.Task.reenable(&1))
+    Enum.each(compilers, &Mix.Task.reenable("compile.#{&1}"))
+  end
+
   defp maybe_prepend(compilers, compiler) do
     if compiler in compilers do
       compilers

lib/mix/test/mix/tasks/compile.elixir_test.exs

@@ -874,6 +874,33 @@ defmodule Mix.Tasks.Compile.ElixirTest do
     end)
   end
 
+  test "recompiles newly created files" do
+    in_fixture("no_mixfile", fn ->
+      Mix.Project.push(MixTest.Case.Sample)
+
+      assert Mix.Tasks.Compile.Elixir.run(["--verbose"]) == {:ok, []}
+      assert_received {:mix_shell, :info, ["Compiled lib/a.ex"]}
+      assert_received {:mix_shell, :info, ["Compiled lib/b.ex"]}
+
+      Mix.shell().flush()
+
+      File.write!("lib/z.ex", """
+      defmodule Z do
+        def ok, do: :ok
+      end
+      """)
+
+      Mix.Task.reenable("compile.elixir")
+      assert {:ok, []} = Mix.Tasks.Compile.Elixir.run(["--verbose"])
+
+      assert_received {:mix_shell, :info, ["Compiled lib/z.ex"]}
+      refute_received {:mix_shell, :info, ["Compiled lib/a.ex"]}
+      refute_received {:mix_shell, :info, ["Compiled lib/b.ex"]}
+
+      assert File.regular?("_build/dev/lib/sample/ebin/Elixir.Z.beam")
+    end)
+  end
+
   test "recompiles dependent changed modules" do
     in_fixture("no_mixfile", fn ->
       Mix.Project.push(MixTest.Case.Sample)

lib/mix/test/mix/tasks/compile_test.exs

@@ -125,6 +125,37 @@ defmodule Mix.Tasks.CompileTest do
     end)
   end
 
+  test "recompiles newly created files" do
+    in_fixture("no_mixfile", fn ->
+      assert Mix.Tasks.Compile.run(["--verbose"]) == {:ok, []}
+      Mix.shell().flush()
+
+      File.mkdir_p!("lib/foo")
+
+      File.write!("lib/foo/z.ex", """
+      defmodule Z do
+        def ok, do: :ok
+      end
+      """)
+
+      assert :ok = Mix.Task.reenable("compile")
+      assert {:noop, []} = Mix.Task.run("compile")
+      refute File.regular?("_build/dev/lib/sample/ebin/Elixir.Z.beam")
+
+      assert :ok = Mix.Tasks.Compile.reenable(compilers: [])
+      assert {:noop, []} = Mix.Task.run("compile")
+      refute File.regular?("_build/dev/lib/sample/ebin/Elixir.Z.beam")
+
+      assert :ok = Mix.Tasks.Compile.reenable(compilers: ["erlang"])
+      assert {:noop, []} = Mix.Task.run("compile")
+      refute File.regular?("_build/dev/lib/sample/ebin/Elixir.Z.beam")
+
+      assert :ok = Mix.Tasks.Compile.reenable()
+      assert {:ok, []} = Mix.Task.run("compile")
+      assert File.regular?("_build/dev/lib/sample/ebin/Elixir.Z.beam")
+    end)
+  end
+
   test "recompiles app cache if manifest changes" do
     in_fixture("no_mixfile", fn ->
       Mix.Tasks.Compile.run(["--force"])