Linsen, you have arrived

mat-chalmers.cabal

@@ -24,6 +24,7 @@ library
   exposed-modules: Model
                  , Model.Types
                  , Model.Karen
+                 , Model.Linsen
                  , Model.Wijkanders
                  , View
                  , Config

src/Model.hs

@@ -56,6 +56,7 @@ import           Config
 import           Model.Types
 import           Model.Karen
 import           Model.Wijkanders
+import           Model.Linsen
 
 -- | Refreshes menus.
 -- The refresh function evaluates to `Some monad m => m (View model, Update signal)`,
@@ -108,6 +109,7 @@ update = do
     , karenR "L's Kitchen" "ls-kitchen" "c74da2cf-aa1a-4d3a-9ba6-08d5569587a1"
     , Restaurant "Wijkanders" (fromStrict $ renderUrl wijkandersAPIURL) .
       getWijkanders day' . responseBody <$> req GET wijkandersAPIURL NoReqBody lbsResponse mempty
+    , fetchAndCreateLinsen day'
     ]
 
   for_ rest $ \r -> case menu r of

src/Model/Linsen.hs

@@ -0,0 +1,101 @@
+{-# LANGUAGE FlexibleContexts, OverloadedStrings, LambdaCase  #-}
+
+module Model.Linsen
+  (
+    parse
+  , fetchAndCreateLinsen
+  )
+where
+
+import           Control.Monad                            ( (>=>)
+                                                          , (<=<)
+                                                          , zipWithM
+                                                          , ap
+                                                          )
+import           Control.Monad.Catch                      ( MonadThrow )
+import           Control.Monad.IO.Class                   ( MonadIO )
+import           Data.Aeson                               ( (.:)
+                                                          , withObject
+                                                          , Value
+                                                          )
+import           Data.Aeson.Types                         ( Parser
+                                                          , parseEither
+                                                          )
+import           Data.Bifunctor                           ( first )
+import qualified Data.ByteString.Lazy.Char8    as BL8
+import           Data.Functor                             ( (<&>) )
+import           Data.Text.Lazy                           ( Text
+                                                          , replace
+                                                          , strip )
+import           Data.Thyme.Calendar                      ( Day )
+import           Network.HTTP.Req
+import           Model.Types                              ( NoMenu(..)
+                                                          , Menu(..)
+                                                          , Restaurant
+                                                            ( Restaurant
+                                                            )
+                                                          )
+import           Util                                     ( menusToEitherNoLunch )
+import           Data.Thyme.Calendar.WeekDate             ( toWeekDate )
+
+fetch
+  :: (MonadHttp m, MonadIO m, MonadThrow m)
+  => m Value  -- ^ A JSON response or horrible crash
+fetch =
+  req
+    GET
+    (https "cafe-linsen.se" /: "api" /: "menu")
+    NoReqBody
+    jsonResponse
+    mempty
+  <&> responseBody
+
+parse
+  :: Day                  -- ^ Day to parse
+  -> Value                -- ^ JSON result from `fetch`
+  -> Either NoMenu [Menu] -- ^ Either list of parsed `Menu`s or `NoMenu` error
+parse day =
+    failWithNoMenu
+      (parseEither
+        (   withObject "Parse meals"
+        $   (.: "docs")
+        >=> (pure . (!! (6 - (\(_,_,a) -> a) (toWeekDate day))))
+        >=> (.: "richText")
+        >=> (.: "root")
+        >=> (.: "children")
+        >=> menuParser
+        )
+      )
+    >=> menusToEitherNoLunch
+ where
+  failWithNoMenu :: Show a => (a -> Either String b) -> a -> Either NoMenu b
+  failWithNoMenu action x =
+    first (\msg -> NMParseError msg . BL8.pack . show $ x) (action x)
+
+  menuParser :: [Value] -> Parser [Menu]
+  menuParser = pure . (zip [0 :: Integer ..] >=> \case
+                          (2 ,vs) -> [vs]
+                          (6 ,vs) -> [vs]
+                          (10,vs) -> [vs]
+                          _       -> []) <=< ap (zipWithM sumFood) tail
+
+  sumFood :: Value -> Value -> Parser Menu
+  sumFood a b = Menu <$> getFood a <*> getFood b
+
+  getFood :: Value -> Parser Text
+  getFood = withObject "Menu Object"
+            $   (.: "children")
+            >=> \case
+                  [] -> pure mempty
+                  vs -> last vs .: "text"
+                    <&> strip . replace "/ " ", "
+
+fetchAndCreateLinsen
+  :: (MonadHttp m, MonadIO m, MonadThrow m)
+  => Day          -- ^ Day
+  -> m Restaurant -- ^ Fetched Restaurant
+fetchAndCreateLinsen day =
+  Restaurant
+      "Café Linsen"
+      "https://plateimpact-screen.azurewebsites.net/menu/week/"
+    <$> fmap (parse day) fetch

test/Main.hs

@@ -5,6 +5,7 @@ import           Data.Aeson                               ( decode )
 import           Data.Maybe                               ( fromJust )
 import           Data.Thyme.Time.Core                     ( fromGregorian )
 import           Model.Karen                              ( parse )
+import qualified Model.Linsen                  as L       ( parse )
 import           Model.Types                              ( Menu(..)
                                                           , NoMenu
                                                           )
@@ -48,6 +49,25 @@ main = hspec $ do
         )
     )
 
+  describe "Cafe Linsen" $ it
+    "parses a blob of JSON without error"
+    (do
+      s1 <- BL.readFile "test/linsen.json"
+      testFun
+        [ Menu
+            (T.pack "Natt Överbakad Högrev.")
+            (T.pack "Rotfrukter, Timjansky, Persilja, Pommes Chateau.")
+        , Menu
+            (T.pack "Stekt Fisk.")
+            (T.pack "Remouladsås, Citron, Dill, Picklade Morötter, Rostad Potatis.")
+        , Menu
+            (T.pack "Chana Masala.")
+            (T.pack "Kikärtor, Grönsaker, Potatis Pakora, Nannbröd, Ris")
+        ] (L.parse
+              (fromGregorian 2024 05 31)
+              (fromJust $ decode s1))
+    )
+
   describe "The Wijkander's"
     $ it "Parses two blobs of HTML correctly on fridays"
     $ do