MineTweaker Support

Cauldron

import mods.betterwithmods.Cauldron;

// addUnstoked(IItemStack[] outputs, IIngredient[] inputs)
Cauldron.addUnstoked([<minecraft:gold_ingot>], [<ore:ingotIron>, <minecraft:skull>, <minecraft:apple>]);

// addStoked(IItemStack[] outputs, IIngredient[] inputs)
Cauldron.addStoked([<minecraft:diamond>], [<minecraft:dirt> * 8]);

// remove(IItemStack output, boolean stoked)
// removes every recipe that outputs gunpowder
Cauldron.remove(<minecraft:gunpowder>, false);

// removeAll(boolean stoked)
Cauldron.removeAll(true);

// tiny 1337 convenience hack, add this directly to your zs script file
function replaceCauldron(outputs as IItemStack[], inputs as IIngredient[], stoked as bool) {
	Cauldron.remove(outputs[0], stoked);
	if (stoked) {
		Cauldron.addStoked(outputs, inputs);
	} else {
		Cauldron.addUnstoked(outputs, inputs);
	}
}

Crucible

import mods.betterwithmods.Crucible;

// addUnstoked(IItemStack[] outputs, IIngredient[] inputs)
Crucible.addUnstoked([<minecraft:gold_ingot>], [<ore:ingotIron>, <minecraft:skull>, <minecraft:apple>]);

// addStoked(IItemStack[] outputs, IIngredient[] inputs)
Crucible.addStoked([<minecraft:diamond>], [<minecraft:dirt> * 8]);

// remove(IItemStack output, boolean stoked)
// removes every recipe that outputs gunpowder
Crucible.remove(<minecraft:gunpowder>, false);

// removeAll(boolean stoked)
Crucible.removeAll(true);

Heat Registry

import mods.betterwithmods.HeatRegistry;

// addHeatSource(IItemStack block, int heat)
// 3 = vanilla fire
// 8 = stoked fire
HeatRegistry.addHeatSource(<minecraft:cactus>, 8);

// pass wildcard meta to register every possible state of one block as a single Heat Source
HeatRegistry.addHeatSource(<minecraft:wool>.anyDamage(), 1);
// or
HeatRegistry.addHeatSource(<minecraft:wool:32767>, 1);

Kiln

import mods.betterwithmods.Kiln;

// add(IItemStack[] output, IIngredient block)
Kiln.add([<minecraft:iron_bars> * 2], <ore:oreIron>);

Kiln.add([<minecraft:sand>], <minecraft:stained_glass>.anyDamage());

// remove(IIngredient input)
Kiln.remove(<minecraft:clay>);

// removeAll()
Kiln.removeAll();

Mill

import mods.betterwithmods.Mill;

// add(IItemStack[] outputs, IIngredient[] inputs)
Mill.add([<minecraft:gold_nugget> * 3], [<minecraft:gold_ore>]);

// remove(IItemStack output)
Mill.remove(<minecraft:sugar>);

// removeAll()
Mill.removeAll();

Saw

import mods.betterwithmods.Saw;

// add(IItemStack[] outputs, IIngredient block);
Saw.add([<minecraft:dye:4> * 9], <minecraft:lapis_block>);

Saw.add([<minecraft:string> * 4>], <minecraft:wool>.anyDamage());

// addEntity(string entityName, boolean choppingBlock, IItemStack[] drops, int dropChance)
// you can get every vanilla entityName in the game through the /summon command, modded entities are seemingly only partially printed with /mt entities
// if choppingBlock is true, the specified drops *only* drop when a chopping block is under the entity
Saw.addEntity("Sheep", true, [<minecraft:gold_ingot>], 100);

// addEntity(string entityName, IItemStack[] regularDrops, int dropChance, IItemStack[] chopDrops, int chopChance)
// both kinds of drops for the same entity
Saw.addEntity("Zombie", [<minecraft:dirt>], 15, [<minecraft:diamond>], 5);

Turntable

import mods.betterwithmods.Turntable;

// add(IItemStack[] output, IIngredient block)
Turntable.add([<minecraft:skull>, <minecraft:coal:1> * 3], <ore:logWood>);

Turntable.add([<minecraft:hardened_clay>], <minecraft:stained_hardened_clay>.anyDamage());

// remove(IIngredient input)
Turntable.remove(<minecraft:clay>);

// removeAll()
Turntable.removeAll();

HCFurnace

import mods.betterwithmods.HCFurnace;

// add(IIngredient input, int ticks)
HCFurnace.add(<minecraft:clay>, 1600);

// remove(IIngredient input)
HCFurnace.remove(<ore:oreIron>);