On the curation page for chemicals, add panel for work with titles containing the chemical name but with no corresponding main subject tag

[Adafede]

What kind of panel would you like to add to which Scholia aspect?

A panel that assists in finding works that are candidates for being tagged with the chemical as main subject.

What kind of information should the panel provide, and which of the visualization options (e.g. table, bubble chart, map) should it use?

Here is a draft query:

PREFIX target: <http://www.wikidata.org/entity/Q2079986>

SELECT DISTINCT 
?item ?itemLabel ?chemicalname
  (REPLACE(STR(?item), ".*Q", "Q") AS ?work) 
  ("P921" AS ?main_subject)
  (REPLACE(STR(target: ), ".*Q", "Q") AS ?chemical)
  ("S887" AS ?heuristic)
  ("Q69652283" AS ?deduced)

WITH
{ SELECT  ?item ?chemicalname WHERE {
  VALUES ?chemicals {
    wd:Q11173 # chemical compounds
    wd:Q59199015 # group of stereoisomers
  }
  target: rdfs:label ?chemicalname .
  target: wdt:P31 ?chemicals. # comment out or adapt as necessary

  SERVICE wikibase:mwapi
  {
    bd:serviceParam wikibase:endpoint "www.wikidata.org";
      wikibase:api "Generator";
      mwapi:generator "search";
      mwapi:gsrsearch ?chemicalname;
      mwapi:gsrlimit "max".
    ?item wikibase:apiOutputItem mwapi:title.
  }
  ?item wdt:P1476 ?title .
  
  MINUS {?item wdt:P921 target: }

  FILTER (REGEX(LCASE(?title), LCASE(CONCAT( "\\", "b", ?chemicalname ,"\\", "b"))))
  }
  LIMIT 200
}
AS %items
WHERE {
  INCLUDE %items
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
LIMIT 200

Which Wikidata entries would be good candidates to explore such visualizations?

Chemicals that are common in titles of publications, e.g. https://w.wiki/4y5S.

Anything else?

I am not sure how safe this is, I dislike working with chemicals labels but we do not have the equivalent of taxon name as in #1903.
This might end but with articles about (+)-Quassin being tagged with Quassin as the topic, which is not the best we can do but completely incorrect either (see query).
On the other hand, it allows finding articles where the chemical name is maybe not the most used one (eg. acetylsalicylic acid/aspirin).
tagging @egonw for his expertise here.

[egonw]

I wonder if this cannot create a bit of QuickStatements ...

[Adafede]

@egonw Sure!

PREFIX target: <http://www.wikidata.org/entity/Q2079986>

SELECT DISTINCT 
  (REPLACE(STR(?item), ".*Q", "Q") AS ?qid) 
  (REPLACE(STR(target: ), ".*Q", "Q") AS ?P921)
  ("Q69652283" AS ?S887)

WITH
{ SELECT  ?item ?chemicalname WHERE {
  VALUES ?chemicals {
    wd:Q11173 # chemical compounds
    wd:Q59199015 # group of stereoisomers
  }
  target: rdfs:label ?chemicalname .
  target: wdt:P31 ?chemicals. # comment out or adapt as necessary

  SERVICE wikibase:mwapi
  {
    bd:serviceParam wikibase:endpoint "www.wikidata.org";
      wikibase:api "Generator";
      mwapi:generator "search";
      mwapi:gsrsearch ?chemicalname;
      mwapi:gsrlimit "max".
    ?item wikibase:apiOutputItem mwapi:title.
  }
  ?item wdt:P1476 ?title .
  
  MINUS {?item wdt:P921 target: }

  FILTER (REGEX(LCASE(?title), LCASE(CONCAT( "\\", "b", ?chemicalname ,"\\", "b"))))
  }
  LIMIT 200
}
AS %items
WHERE {
  INCLUDE %items
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
LIMIT 200

⚠️ The example highlights some of the limitations for example (-)-chemical-name, etc.

[egonw]

This version is slightly faster and outputs QuickStatements:

PREFIX target: <http://www.wikidata.org/entity/Q2079986>

SELECT DISTINCT ?item ?itemLabel ?chemicalname
  (CONCAT("qid,P921,S887\n", SUBSTR(STR(?item),32), ",Q2079986,Q69652283") AS ?quickStatements)
WITH {
  SELECT  ?item ?chemicalname WHERE {
    VALUES ?chemicalType {
      wd:Q113145171 # type of a chemical entity
      wd:Q59199015 # group of stereoisomers
    }
    target: wdt:P31 ?chemicalType ; rdfs:label ?chemicalname .
    FILTER(lang(?chemicalname) = "en")
    SERVICE wikibase:mwapi {
      bd:serviceParam wikibase:endpoint "www.wikidata.org";
      wikibase:api "Generator";
      mwapi:generator "search";
      mwapi:gsrsearch ?chemicalname;
      mwapi:gsrlimit "max".
      ?item wikibase:apiOutputItem mwapi:title.
    }
    ?item wdt:P1476 ?title .
    MINUS {?item wdt:P921 target: }
    FILTER (REGEX(LCASE(?title), LCASE(CONCAT( "\\", "b", ?chemicalname ,"\\", "b"))))
  } LIMIT 200
} AS %items WHERE {
  INCLUDE %items
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

[egonw]

Implemented, but did not finalize the patch yet:

cc @fnielsen @Daniel-Mietchen

[egonw]

@Adafede, pull request submitted.