Bug fixes + adding possibility to switch from bytecode interpreter to DAST interpreter and vice-versa

DebuggableASTDebugger/BlockClosure.extension.st

@@ -0,0 +1,10 @@
+Extension { #name : #BlockClosure }
+
+{ #category : #'*DebuggableASTDebugger' }
+BlockClosure >> bcToDASTValue [
+
+	^ DASTBlock new
+		  initializeWith: self compiledBlock ast;
+		  pharoOuterContext: self outerContext;
+		  yourself
+]

DebuggableASTDebugger/Context.extension.st

@@ -0,0 +1,14 @@
+Extension { #name : #Context }
+
+{ #category : #'*DebuggableASTDebugger' }
+Context >> dastValueFor: anObject interpretedBy: aDASTInterpreter withClosureToBlockDictionary: closureToDASTBlock [
+
+	| value |
+	(closureToDASTBlock includesKey: anObject) ifTrue: [
+		^ closureToDASTBlock at: anObject ].
+	value := anObject bcToDASTValue.
+	value isBlock ifTrue: [
+		value outerContext: self. "aDASTInterpreter currentContext"
+		closureToDASTBlock at: anObject put: value ].
+	^ value
+]

DebuggableASTDebugger/DASTBlock.extension.st

@@ -0,0 +1,7 @@
+Extension { #name : #DASTBlock }
+
+{ #category : #'*DebuggableASTDebugger' }
+DASTBlock >> dastToBcValue [
+
+	^ self closure
+]

DebuggableASTDebugger/DASTBlockContext.extension.st

@@ -0,0 +1,15 @@
+Extension { #name : #DASTBlockContext }
+
+{ #category : #'*DebuggableASTDebugger' }
+DASTBlockContext >> tempNamed: aTempVarName [
+
+	^ [ super tempNamed: aTempVarName ]
+		  on: KeyNotFound
+		  do: [
+			  [
+			  self sender
+				  ifNotNil: [ self sender tempNamed: aTempVarName ]
+				  ifNil: [ closure outerContext tempNamed: aTempVarName ] ]
+				  on: KeyNotFound
+				  do: [ closure outerContext tempNamed: aTempVarName ] ]
+]

DebuggableASTDebugger/DASTDebugger.class.st

@@ -0,0 +1,195 @@
+Class {
+	#name : #DASTDebugger,
+	#superclass : #SpPresenter,
+	#traits : 'TDebugger',
+	#classTraits : 'TDebugger classTrait',
+	#instVars : [
+		'stack',
+		'code',
+		'interpreter',
+		'toolBar',
+		'simulatorSession',
+		'switchButton'
+	],
+	#category : #DebuggableASTDebugger
+}
+
+{ #category : #'instance creation' }
+DASTDebugger class >> debugSession: aDebugSession [
+
+	| dast |
+	dast := self basicNew.
+	dast simulatorSession: aDebugSession.
+	aDebugSession interruptedContext receiver class == DASTBreakpoint
+		ifTrue: [
+			aDebugSession stepInto.
+			aDebugSession stepInto ].
+	dast interpreter:
+		(DASTInterpreter startFromContext: aDebugSession interruptedContext).
+	dast initialize.
+	dast open
+]
+
+{ #category : #accessing }
+DASTDebugger class >> defaultDebuggerRank [
+
+	^ 10
+]
+
+{ #category : #debugging }
+DASTDebugger class >> handlesDebugSession: aDebugSession [
+
+	^ aDebugSession exception class = DASTException or: [
+		  aDebugSession interruptedContext receiver class = DASTBreakpoint ]
+]
+
+{ #category : #initialization }
+DASTDebugger >> buildToolbar [
+
+	^ self newToolbar
+		  addItem: (SpToolbarButtonPresenter new
+				   label: 'Proceed';
+				   icon: (self iconNamed: #glamorousSpawn);
+				   action: [ self proceed ];
+				   yourself);
+		  addItem: (SpToolbarButtonPresenter new
+				   label: 'Step';
+				   icon: (self iconNamed: #down);
+				   action: [ self stepInterpreter ];
+				   yourself);
+		  addItem: (SpToolbarButtonPresenter new
+				   label: 'Step over';
+				   icon: (self iconNamed: #forward);
+				   action: [ self stepOver ];
+				   yourself);
+		  addItem: (SpToolbarButtonPresenter new
+				   label: 'Step through';
+				   icon: (self iconNamed: #glamorousThrough);
+				   action: [ self stepThrough ];
+				   yourself);
+		  addItem: (SpToolbarButtonPresenter new
+				   label: 'Restart';
+				   icon: (self iconNamed: #glamorousRestart);
+				   action: [ self restart ];
+				   yourself);
+		  yourself
+]
+
+{ #category : #accessing }
+DASTDebugger >> clear [
+	simulatorSession terminate
+]
+
+{ #category : #layout }
+DASTDebugger >> defaultLayout [
+
+	^ SpBoxLayout newVertical
+		  add: (SpBoxLayout newTopToBottom
+				   add: switchButton
+				   expand: false
+				   fill: false
+				   padding: 5;
+				   add: stack;
+				   yourself);
+		  add: toolBar expand: false;
+		  add: code;
+		  yourself
+]
+
+{ #category : #initialization }
+DASTDebugger >> initializePresenters [
+
+	code := self newCode.
+	stack := self newList
+		         transmitDo: [ :ctx | self updateCodeFromContext: ctx ];
+		         yourself.
+	toolBar := self buildToolbar.
+	switchButton := self newButton action: [ self switchToOtherDebugger ].
+	self updateStack
+]
+
+{ #category : #accessing }
+DASTDebugger >> interpreter: aDASTInterpreter [
+
+	interpreter := aDASTInterpreter
+]
+
+{ #category : #menu }
+DASTDebugger >> proceed [
+
+	interpreter evaluate.
+	self updateStack
+]
+
+{ #category : #menu }
+DASTDebugger >> restart [
+
+	interpreter restart: stack selectedItem.
+	self updateStack
+]
+
+{ #category : #accessing }
+DASTDebugger >> simulatorSession: anObject [
+
+	simulatorSession := anObject
+]
+
+{ #category : #'as yet unclassified' }
+DASTDebugger >> stepInterpreter [
+
+
+	interpreter stepInto.
+	self updateStack
+]
+
+{ #category : #'debug - stepping' }
+DASTDebugger >> stepOver [
+
+	interpreter stepOver.
+	self updateStack
+]
+
+{ #category : #actions }
+DASTDebugger >> stepThrough [
+
+	interpreter stepThrough.
+	self updateStack
+]
+
+{ #category : #initialization }
+DASTDebugger >> switchToOtherDebugger [
+
+	| context process |
+	context := interpreter currentContext asContext.
+	process := Process
+		           forContext: context
+		           priority: Processor userInterruptPriority.
+	(OupsDebugRequest newForContext: context)
+		label: context compiledCode printString;
+		process: process;
+		submit.
+	self clear.
+	self window close
+]
+
+{ #category : #'presenter - code' }
+DASTDebugger >> updateCodeFromContext: aDASTContext [
+
+	aDASTContext ifNil: [ ^ nil ].
+	code text: aDASTContext sourceCode.
+	code beForContext: aDASTContext.
+	 code removeAllTextSegmentDecorations.
+
+	 code addTextSegmentDecoration: (SpTextPresenterDecorator forHighlight
+		interval: (aDASTContext currentNode start  to: aDASTContext currentNode stop + 1);
+		yourself).
+
+]
+
+{ #category : #'as yet unclassified' }
+DASTDebugger >> updateStack [
+
+	stack
+		items: interpreter contextsStack;
+		selectFirst
+]

DebuggableASTDebugger/Object.extension.st

@@ -0,0 +1,13 @@
+Extension { #name : #Object }
+
+{ #category : #'*DebuggableASTDebugger' }
+Object >> bcToDASTValue [
+
+	^ self
+]
+
+{ #category : #'*DebuggableASTDebugger' }
+Object >> dastToBcValue [
+
+	^ self
+]

DebuggableASTDebuggerExperiment/ClyAddDASTBreakpointCommand.class.st

@@ -0,0 +1,36 @@
+Class {
+	#name : #ClyAddDASTBreakpointCommand,
+	#superclass : #ClyAddStaticBreakpointCommand,
+	#category : #DebuggableASTDebuggerExperiment
+}
+
+{ #category : #testing }
+ClyAddDASTBreakpointCommand class >> canBeExecutedInContext: aBrowserContext [
+
+	^ (super canBeExecutedInContext: aBrowserContext) and: [
+		  aBrowserContext isSelectedItemHasBreakpoint not ]
+]
+
+{ #category : #activation }
+ClyAddDASTBreakpointCommand class >> contextMenuOrder [
+	<classAnnotationDependency>
+	^1
+]
+
+{ #category : #testing }
+ClyAddDASTBreakpointCommand class >> isAbstract [
+	^self = ClyAddBreakpointCommand
+]
+
+{ #category : #accessing }
+ClyAddDASTBreakpointCommand >> defaultMenuItemName [
+	^'DAST breakpoint'
+]
+
+{ #category : #execution }
+ClyAddDASTBreakpointCommand >> execute [
+
+	| breakpoint |
+	breakpoint := DASTBreakpoint new node: sourceNode.
+	breakpoint install
+]

DebuggableASTDebuggerExperiment/DASTBreakpoint.class.st

@@ -0,0 +1,12 @@
+"
+1/0.
+bp := 
+DASTBreakpoint new node: (StDebuggerObjectForTests>>#instVar) ast.
+bp install.
+StDebuggerObjectForTests new instVar
+"
+Class {
+	#name : #DASTBreakpoint,
+	#superclass : #Breakpoint,
+	#category : #DebuggableASTDebuggerExperiment
+}

DebuggableASTDebuggerExperiment/StDebugger.extension.st

@@ -0,0 +1,20 @@
+Extension { #name : #StDebugger }
+
+{ #category : #'*DebuggableASTDebuggerExperiment' }
+StDebugger class >> buildDASTCommandsGroupWith: stDebuggerInstance forRoot: aRootGroup [
+
+	<extensionCommands>
+	| configGroup dastConfigGroup |
+	configGroup := aRootGroup
+	               / StDebuggerConfigurationCommandTreeBuilder groupName.
+	dastConfigGroup := StDebuggerConfigurationCommandTreeBuilder new
+		                   dastConfigurationCommandsGroup.
+	configGroup register: dastConfigGroup
+]
+
+{ #category : #'*DebuggableASTDebuggerExperiment' }
+StDebugger >> programmaticallyClose [
+
+	programmaticallyClosed := true.
+	self withWindowDo: #close
+]

DebuggableASTDebuggerExperiment/StDebuggerConfigurationCommandTreeBuilder.extension.st

@@ -0,0 +1,33 @@
+Extension { #name : #StDebuggerConfigurationCommandTreeBuilder }
+
+{ #category : #'*DebuggableASTDebuggerExperiment' }
+StDebuggerConfigurationCommandTreeBuilder >> dastConfigurationCommandsClasses [
+
+	^ { StSwitchToDASTCommand }
+]
+
+{ #category : #'*DebuggableASTDebuggerExperiment' }
+StDebuggerConfigurationCommandTreeBuilder >> dastConfigurationCommandsGroup [
+
+	| group |
+	group := (CmCommandGroup named: self dastConfigurationGroupName)
+		         asSpecGroup.
+	group beDisplayedAsSubMenu.
+	group description: self dastConfigurationGroupDescription.
+	self dastConfigurationCommandsClasses do: [ :c |
+		group register:
+			(self buildSpecCommand: c forContext: stDebuggerInstance) ].
+	^ group
+]
+
+{ #category : #'*DebuggableASTDebuggerExperiment' }
+StDebuggerConfigurationCommandTreeBuilder >> dastConfigurationGroupDescription [
+
+	^ 'Configuration commands to perform actions with DAST interpreter'
+]
+
+{ #category : #'*DebuggableASTDebuggerExperiment' }
+StDebuggerConfigurationCommandTreeBuilder >> dastConfigurationGroupName [
+
+	^ 'DAST configuration'
+]

DebuggableASTDebuggerExperiment/StSwitchToDASTCommand.class.st

@@ -0,0 +1,29 @@
+Class {
+	#name : #StSwitchToDASTCommand,
+	#superclass : #StDebuggerCommand,
+	#category : #DebuggableASTDebuggerExperiment
+}
+
+{ #category : #initialization }
+StSwitchToDASTCommand class >> defaultIconName [
+
+	^ #halt
+]
+
+{ #category : #initialization }
+StSwitchToDASTCommand class >> defaultShortcut [
+
+	^ $d meta , $s meta
+]
+
+{ #category : #executing }
+StSwitchToDASTCommand >> execute [
+
+	| session |
+	session := self context session.
+	self context programmaticallyClose.
+	(OupsDebugRequest newForContext: context)
+		label: session interruptedContext compiledCode printString;
+		exception: (DASTException fromSignallerContext: session interruptedContext);
+		"DASTDebugger debugSession: session"submit
+]

DebuggableASTDebuggerExperiment/package.st

@@ -0,0 +1 @@
+Package { #name : #DebuggableASTDebuggerExperiment }