Add nix support (#31)

.gitignore

@@ -4,3 +4,7 @@ archive
 src/graphql/generated.rs
 sql_scripts
 target
+
+# direnv
+.envrc
+.direnv

cspell.json

@@ -16,7 +16,11 @@
     "src/graphql/schema/mina_schema.graphql",
     "sql/**",
     "static/scalar.standalone.min.js",
-    "target/**"
+    "target/**",
+    "flake.*",
+    "nix/**",
+    ".gitignore"
   ],
-  "useGitignore": true
+  "useGitignore": true,
+  "enabled": true
 }

flake.nix

@@ -0,0 +1,30 @@
+{
+  inputs = {
+    nixpkgs.url = "github:nixos/nixpkgs/nixpkgs-unstable";
+    flake-parts.url = "github:hercules-ci/flake-parts";
+    flake-parts.inputs.nixpkgs-lib.follows = "nixpkgs";
+    systems.url = "github:nix-systems/default";
+    rust-overlay.url = "github:oxalica/rust-overlay";
+    rust-overlay.inputs.nixpkgs.follows = "nixpkgs";
+    rust-flake.url = "github:juspay/rust-flake";
+    rust-flake.inputs.nixpkgs.follows = "nixpkgs";
+    rust-flake.inputs.rust-overlay.follows = "rust-overlay";
+    process-compose-flake.url = "github:Platonic-Systems/process-compose-flake";
+    cargo-doc-live.url = "github:srid/cargo-doc-live";
+
+    # Dev tools
+    treefmt-nix.url = "github:numtide/treefmt-nix";
+  };
+
+  outputs = inputs:
+    inputs.flake-parts.lib.mkFlake { inherit inputs; } {
+      systems = import inputs.systems;
+
+      # See ./nix/modules/*.nix for the modules that are imported here.
+      imports = with builtins;
+        map
+          (fn: ./nix/modules/${fn})
+          (attrNames (readDir ./nix/modules));
+
+    };
+}

nix/modules/devshell.nix

@@ -0,0 +1,21 @@
+{ inputs, ... }:
+{
+  perSystem = { config, self', pkgs, lib, ... }: {
+    devShells.default = pkgs.mkShell {
+      name = "rust-nix-mina_mesh-shell";
+      inputsFrom = [
+        self'.devShells.rust
+        config.treefmt.build.devShell
+      ];
+      nativeBuildInputs = with pkgs; [
+        sqlx-cli
+      ];
+      packages = with pkgs; [
+        nixd # Nix language server
+        nixfmt # Nix formatter
+        cargo-watch
+        config.process-compose.cargo-doc-live.outputs.package
+      ];
+    };
+  };
+}

nix/modules/formatting.nix

@@ -0,0 +1,17 @@
+{ inputs, ... }:
+{
+  imports = [
+    inputs.treefmt-nix.flakeModule
+  ];
+  perSystem = { config, self', pkgs, lib, ... }: {
+    # Add your auto-formatters here.
+    # cf. https://nixos.asia/en/treefmt
+    treefmt.config = {
+      projectRootFile = "flake.nix";
+      programs = {
+        nixpkgs-fmt.enable = true;
+        rustfmt.enable = true;
+      };
+    };
+  };
+}

nix/modules/rust.nix

@@ -0,0 +1,20 @@
+{ inputs, ... }:
+{
+  imports = [
+    inputs.rust-flake.flakeModules.default
+    inputs.rust-flake.flakeModules.nixpkgs
+    inputs.process-compose-flake.flakeModule
+    inputs.cargo-doc-live.flakeModule
+  ];
+  perSystem = { config, self', pkgs, lib, ... }: {
+    rust-project.crates."mina_mesh".crane.args = {
+      buildInputs = lib.optionals pkgs.stdenv.isDarwin (
+        with pkgs.darwin.apple_sdk.frameworks; [
+          IOKit
+        ]
+      );
+      nativeBuildInputs = [ pkgs.openssl ];
+    };
+    packages.default = self'.packages.mina_mesh;
+  };
+}