replace nix shell by flake

flake.nix

@@ -0,0 +1,62 @@
+{
+  description = "Honeycomb development & build environment";
+
+  inputs = {
+    nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable";
+    flake-utils.url = "github:numtide/flake-utils";
+    rust-overlay.url = "github:oxalica/rust-overlay";
+  };
+
+  outputs = { self, nixpkgs, flake-utils, rust-overlay }:
+    flake-utils.lib.eachDefaultSystem (system:
+      let
+        pkgs = import nixpkgs {
+          inherit system;
+          overlays = [ rust-overlay.overlays.default ];
+        };
+
+        # Rust toolchain with extensions
+        rustToolchain = pkgs.rust-bin.stable.latest.default.override {
+          extensions = [ "rust-src" ];
+        };
+
+        # Platform-specific build inputs
+        linuxBuildInputs = with pkgs; [
+          xorg.libX11
+          xorg.libXcursor
+          xorg.libXi
+          libxkbcommon
+          xorg.libxcb
+          libudev-zero
+          vulkan-loader
+          glfw
+        ];
+
+        buildInputs = with pkgs; [
+          hwloc.dev
+        ] ++ (if pkgs.stdenv.isLinux then linuxBuildInputs else []);
+
+        # Platform-specific LD_LIBRARY_PATH
+        ldLibraryPath = pkgs.lib.makeLibraryPath (
+          [ pkgs.hwloc.lib ] ++
+          (if pkgs.stdenv.isLinux then linuxBuildInputs else [])
+        );
+
+      in
+      {
+        devShells.default = pkgs.mkShell {
+          nativeBuildInputs = with pkgs; [
+            rustToolchain
+            cargo
+            rust-analyzer
+            pkg-config
+          ];
+
+          buildInputs = buildInputs;
+
+          shellHook = ''
+            export LD_LIBRARY_PATH=${ldLibraryPath}:$LD_LIBRARY_PATH
+          '';
+        };
+      });
+}