build.gradle

import org.jetbrains.kotlin.gradle.tasks.KotlinCompile

plugins {
    id 'java'
    id 'org.jetbrains.kotlin.jvm' version '2.1.0'
    id 'org.springframework.boot' version '3.4.0'
    id 'org.jetbrains.kotlin.plugin.spring' version '2.1.0'
    id 'jacoco'
}

repositories {
    maven {
        url uri("lib")
    }
    mavenLocal()
    mavenCentral()
}

tasks.withType(KotlinCompile).configureEach {
    kotlinOptions {
        jvmTarget = "17"
    }
}

jacocoTestReport {
    dependsOn test
    reports {
        csv.required = true
    }
}

dependencies {
    implementation platform('org.springframework.boot:spring-boot-dependencies:3.4.0')
    implementation 'org.springframework.boot:spring-boot-starter-web'
    implementation 'org.springframework.boot:spring-boot-starter-actuator'
    implementation 'org.springframework.boot:spring-boot-starter-validation'
    implementation 'org.springframework.boot:spring-boot-starter-data-jpa'
    implementation 'org.apache.kafka:kafka-clients:3.7.0'
    implementation 'javax.validation:validation-api:2.0.1.Final'
    implementation 'com.h2database:h2'
    implementation 'org.liquibase:liquibase-core'
    implementation 'com.fasterxml.jackson.module:jackson-module-kotlin:2.15.0'

    testApi "io.specmatic:junit5-support:2.7.4"
    testImplementation 'org.springframework.boot:spring-boot-starter-test'
    testImplementation('io.specmatic.kafka:specmatic-kafka:0.29.0')
    testImplementation(
            'org.assertj:assertj-core:3.24.2',
            'org.junit.jupiter:junit-jupiter-api:5.10.1'
    )
    testImplementation 'org.junit.jupiter:junit-jupiter:5.6.0'
}

sourceSets {
    test {
        resources {
            srcDir file('src/test/kotlin')
            exclude '**/*.java'
            exclude '**/*.kt}'
        }
    }
}

test {
    useJUnitPlatform {
        includeEngines("junit-jupiter")
    }
    testLogging.showStandardStreams = true

    afterSuite { desc, result ->
        if (!desc.parent) {
            def resultLine = "Results: ${result.resultType} (${result.testCount} tests, ${result.successfulTestCount} successes, ${result.failedTestCount} failures, ${result.skippedTestCount} skipped)"
            def lineLength = resultLine.length()
            def separator = "-" * lineLength

            println separator
            println resultLine
            println separator
        }
    }

}

group = 'io.specmatic.sample'
version = '1.0'
sourceCompatibility = '17'

configurations {
    all {
        exclude group: 'org.springframework.boot', module: 'spring-boot-starter-logging'
        exclude group: 'ch.qos.logback', module: 'logback-classic'
        exclude group: 'org.apache.logging.log4j', module: 'log4j-to-slf4j'
    }
}