-
Notifications
You must be signed in to change notification settings - Fork 3
/
flipperzero-chat-esp32.ino
2021 lines (1945 loc) · 58.6 KB
/
flipperzero-chat-esp32.ino
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
/* FlipperZero Sub-Ghz Chat Bridge
*
* A sketch for the ESP32 to allow communication with the FlipperZero's SubGhz chat feature
* Requires a TI-CC1101 to be connected to the SPI port
*
* xitiomet - 2023
* openstatic.org
*
* Hookup between devices:
*
* ESP-32 to CC1101
* ------ -- ------
* 3.3v to VIN
* GND to GND
* 5 to CS
* 18 to SCLK
* 19 to MISO / SO
* 23 to MOSI / SI
*/
#define ARDUINOJSON_USE_LONG_LONG 1
#include <ELECHOUSE_CC1101_SRC_DRV.h>
#include <WiFi.h>
#include <WiFiMulti.h>
#include <WiFiUdp.h>
#include <ESPmDNS.h>
#include <WebServer.h>
#include <WebSocketsServer.h>
#include <ArduinoJson.h>
#include <FFat.h>
#include "./DNSServer.h"
#include <Wire.h>
#include <Adafruit_GFX.h>
#include <Adafruit_SSD1306.h>
#include <NTPClient.h>
#include "TimeLib.h"
#include "BluetoothSerial.h"
#define OLED_RESET -1
#define SCREEN_WIDTH 128 // OLED display width, in pixels
#define SCREEN_HEIGHT 64 // OLED display height, in pixels
#define SCREEN_ADDRESS 0x3c ///< See datasheet for Address; 0x3D for 128x64, 0x3C for 128x32
Adafruit_SSD1306 display(SCREEN_WIDTH, SCREEN_HEIGHT, &Wire, OLED_RESET);
#define PIX_ROW_1 0
#define PIX_ROW_1p5 14
#define PIX_ROW_2 24
#define PIX_ROW_3 40
#define PIX_ROW_4 56
#define MAX_IRC_CLIENTS 7
#define MAX_MEMBERS 40
#define HISTORY_SIZE 15
#define SS_PIN 5
float frequency = 433.92;
WiFiMulti wifiMulti;
WiFiServer ircServer(6667);
WiFiClient ircClients[MAX_IRC_CLIENTS];
char ircBuffers[MAX_IRC_CLIENTS][1024];
int ircBufferPos[MAX_IRC_CLIENTS];
int ircUserId[MAX_IRC_CLIENTS];
String ircUsernames[MAX_IRC_CLIENTS];
String ircNicknames[MAX_IRC_CLIENTS];
bool ircGreeted[MAX_IRC_CLIENTS];
WebSocketsServer webSocketServer(81);
WebServer httpServer(80);
IPAddress apIP(10, 10, 10, 1);
DNSServer dnsServer;
WiFiUDP ntpUDP;
NTPClient timeClient(ntpUDP, "time.nist.gov", 0, 60000);
String history[HISTORY_SIZE];
int historyPosition = 0;
//member storage for all users, irc, websocket, radio, flipper
String members[MAX_MEMBERS];
String member_sources[MAX_MEMBERS];
int member_nums[MAX_MEMBERS];
int member_rssi[MAX_MEMBERS];
long member_last_active[MAX_MEMBERS];
uint8_t wl_status;
boolean mdns_started = false;
boolean apMode = true;
boolean captiveDNS = false;
boolean displayInit = false;
boolean replayChatHistory = true;
int tick = 0;
int maxFlippers = 0;
long radioRxCount = 0;
long lastSecondAt = 0;
int flipperCount = 0;
int networkCount = 0;
String line1 = "";
String line2 = "";
String line3 = "";
String local_ip = "";
String local_ssid = "";
String hostname = "FlipperZeroChat";
String flashMessageTitle = "";
String flashMessageBody = "";
long flashMessageAt = 0;
byte radioBuffer[2048] = {0};
int radioBufferPos = 0;
long radioBufferTimer = 0;
int radioRssi = 0;
String Serial2Nickname = "";
String Serial2Buffer = "";
//furi_hal_subghz_preset_gfsk_9_99kb_async_regs
void flipperChatPreset()
{
ELECHOUSE_cc1101.setMHZ(frequency);
//ELECHOUSE_cc1101.SpiWriteReg(CC1101_IOCFG0, 0x0D); //GDO0 Output Pin Configuration
ELECHOUSE_cc1101.SpiWriteReg(CC1101_FIFOTHR, 0x47); //RX FIFO and TX FIFO Thresholds
//1 : CRC calculation in TX and CRC check in RX enabled,
//1 : Variable packet length mode. Packet length configured by the first byte after sync word
ELECHOUSE_cc1101.SpiWriteReg(CC1101_PKTCTRL0, 0x05);
ELECHOUSE_cc1101.SpiWriteReg(CC1101_FSCTRL1, 0x06); //Frequency Synthesizer Control
ELECHOUSE_cc1101.SpiWriteReg(CC1101_SYNC1, 0x46);
ELECHOUSE_cc1101.SpiWriteReg(CC1101_SYNC0, 0x4C);
ELECHOUSE_cc1101.SpiWriteReg(CC1101_ADDR, 0x00);
ELECHOUSE_cc1101.SpiWriteReg(CC1101_PKTLEN, 0x00);
ELECHOUSE_cc1101.SpiWriteReg(CC1101_MDMCFG4, 0xC8); //Modem Configuration 9.99
ELECHOUSE_cc1101.SpiWriteReg(CC1101_MDMCFG3, 0x93); //Modem Configuration
ELECHOUSE_cc1101.SpiWriteReg(CC1101_MDMCFG2, 0x12); // 2: 16/16 sync word bits detected
ELECHOUSE_cc1101.SpiWriteReg(CC1101_DEVIATN, 0x34); //Deviation = 19.042969
ELECHOUSE_cc1101.SpiWriteReg(CC1101_MCSM0, 0x18); //Main Radio Control State Machine Configuration
ELECHOUSE_cc1101.SpiWriteReg(CC1101_FOCCFG, 0x16); //Frequency Offset Compensation Configuration
ELECHOUSE_cc1101.SpiWriteReg(CC1101_AGCCTRL2, 0x43);
ELECHOUSE_cc1101.SpiWriteReg(CC1101_AGCCTRL1, 0x40);
ELECHOUSE_cc1101.SpiWriteReg(CC1101_AGCCTRL0, 0x91);
ELECHOUSE_cc1101.SpiWriteReg(CC1101_WORCTRL, 0xFB);
}
void advertiseGateway()
{
int uc = userCount();
String message = "\x1B[0;93mSubGhz Chat Bridge (" + hostname + ") - Online\x1B[0m\r\n FREQUENCY " + String(frequency) + " Mhz\r\n SSID " + local_ssid + "\r\n IP " + local_ip + "\r\n USERS " + String(uc) + "\r\n\r\n";
streamToRadio(message);
Serial2.print(message);
}
// The CC1101 has a buffer limit of like 53, this will break up outbound messages to small enough chunks for the flipper to receive
void streamToRadio(String &outData)
{
int data_len = outData.length();
if (data_len < 53)
{
char data_array[data_len+1];
outData.toCharArray(data_array, data_len+1);
ELECHOUSE_cc1101.SendData(data_array, data_len+1);
} else {
int chunksNeeded = (data_len / 50);
int lastChunkSize = (data_len % 50);
for(int i = 0; i <= chunksNeeded; i++)
{
int chunkLen = 50;
if (i == chunksNeeded)
{
chunkLen = lastChunkSize;
}
int startAt = i * 50;
int endAt = startAt + chunkLen;
char data_array[chunkLen+1];
outData.substring(startAt, endAt).toCharArray(data_array, chunkLen+1);
ELECHOUSE_cc1101.SendData(data_array, chunkLen+1);
delay(15);
}
}
}
void saveHistory(String &jsonData)
{
if (replayChatHistory)
{
history[historyPosition] = jsonData;
historyPosition++;
if (historyPosition >= HISTORY_SIZE)
historyPosition = 0;
}
}
void replayHistory(int wsnum)
{
if (replayChatHistory)
{
int t = historyPosition;
for(int i = 0; i < HISTORY_SIZE; i++)
{
if (!history[t].equals(""))
{
webSocketServer.sendTXT(wsnum, history[t]);
}
t++;
if (t >= HISTORY_SIZE)
{
t = 0;
}
}
}
}
void replayHistorySerial2()
{
int t = historyPosition;
for(int i = 0; i < HISTORY_SIZE; i++)
{
if (!history[t].equals(""))
{
DynamicJsonDocument histObj(2048);
DeserializationError error = deserializeJson(histObj, history[t]);
if (error)
{
Serial.println(error.c_str());
} else if (histObj.containsKey("username") && histObj.containsKey("event") && histObj.containsKey("text") && histObj.containsKey("source")){
String username = histObj["username"].as<String>();
String event = histObj["event"].as<String>();
String text = histObj["text"].as<String>();
String source = histObj["source"].as<String>();
if (event.equals("chat"))
{
if (source.equals("flipper"))
{
String line = "\x1B[0;33m" + username + "\x1B[0m: " + text + "\r\n";
Serial2.print(line);
} else {
String line = "\x1B[0;91m" + username + "\x1B[0m: " + text + "\r\n";
Serial2.print(line);
}
} else if (event.equals("info")) {
String line = "\x1B[0;94m" + text + "\x1B[0m\r\n";
Serial2.print(line);
}
}
}
t++;
if (t >= HISTORY_SIZE)
{
t = 0;
}
}
}
void changeFrequency(String &username, float frq)
{
if ((frq >= 300.00 && frq <= 348.00) || (frq >= 387.00 && frq <= 464.00) || (frq >= 779.00 && frq <= 928.00))
{
frequency = frq;
ELECHOUSE_cc1101.setMHZ(frequency);
broadcastIrc(":TheReaper!~TheReaper@void TOPIC #lobby :" + String(frequency) + " Mhz");
broadcastIrc(":TheReaper!~TheReaper@void NOTICE #lobby :The frequency has been changed to " + String(frequency) + " Mhz (by " + username + ")");
String line = "\x1B[0;94mThe frequency has been changed to " + String(frequency) + " Mhz (by " + username + ")\x1B[0m\r\n";
Serial2.print(line);
String out;
int uid = findUser(username);
if (uid >= 0)
{
StaticJsonDocument<1024> jsonBuffer;
jsonBuffer["username"] = members[uid];
jsonBuffer["event"] = "frequency";
jsonBuffer["rssi"] = member_rssi[uid];
jsonBuffer["mhz"] = frequency;
jsonBuffer["source"] = member_sources[uid];
jsonBuffer["utc"] = now();
serializeJson(jsonBuffer, out);
webSocketServer.broadcastTXT(out);
} else {
StaticJsonDocument<1024> jsonBuffer;
jsonBuffer["username"] = username;
jsonBuffer["event"] = "frequency";
jsonBuffer["mhz"] = frequency;
jsonBuffer["utc"] = now();
serializeJson(jsonBuffer, out);
webSocketServer.broadcastTXT(out);
}
}
}
// Handle JSON payloads from the websocket on port 81
void processJSONPayload(int num, uint8_t * payload)
{
IPAddress ip = webSocketServer.remoteIP(num);
String source = "ws_" + ip.toString();
char* data = (char *) payload;
DynamicJsonDocument root(3072);
DeserializationError error = deserializeJson(root, data);
if (error)
{
Serial.println(error.c_str());
} else {
if (root.containsKey("username") && root.containsKey("event"))
{
String username = root["username"].as<String>();
String event = root["event"].as<String>();
int uid = findUser(username);
if (uid >= 0 && uid < MAX_MEMBERS)
{
member_last_active[uid] = millis();
}
// Lets set the time if this user is providing it!
if (timeStatus() != timeSet && root.containsKey("utc"))
{
time_t utc = root["utc"].as<time_t>();
setTime(utc);
}
if (root.containsKey("text") && event.equals("chat"))
{
String text = root["text"].as<String>();
//Serial.print("(");
//Serial.print(source);
//Serial.print(") ");
//Serial.print(username);
//Serial.print(": ");
//Serial.println(text);
String xmitData = "\x1B[0;91m" + username + "\x1B[0m: " + text + "\r\n";
Serial2.print(xmitData);
streamToRadio(xmitData);
flashMessage(username, text);
lobbyPrivmsg(username,text);
root["source"] = source;
root["num"] = num;
if (!root.containsKey("utc") && timeStatus() == timeSet)
{
root["utc"] = now();
}
String out;
serializeJson(root, out);
for(int i = 0; i < webSocketServer.connectedClients(); i++)
{
if (i != num)
webSocketServer.sendTXT(i, out);
}
saveHistory(out);
} else {
if (event.equals("join"))
{
uid = registerUser(num, username, source, WiFi.RSSI());
} else if (event.equals("part")) {
deleteUser(username);
} if (event.equals("frequency")) {
changeFrequency(username, root["mhz"].as<float>());
} else if (event.equals("raw")) {
String data = root["data"].as<String>();
streamToRadio(data);
} else if (event.equals("restart")) {
ESP.restart();
} else if (event.equals("radioReset")) {
flipperChatPreset();
} else if (event.equals("name") && root.containsKey("to")) {
String to = root["to"].as<String>();
userChangeName(username, to, true);
} else if (event.equals("advertise")) {
advertiseGateway();
} else if (event.equals("history")) {
replayHistory(num);
} else if (event.equals("private") && root.containsKey("to") && root.containsKey("text")) {
bool isAction = false;
if (root.containsKey("action"))
{
isAction = root["action"].as<bool>();
}
String to = root["to"].as<String>();
String text = root["text"].as<String>();
realPrivateMessage(to, text, isAction, uid);
}
}
}
}
}
void realPrivateMessage(String &to, String &text, bool isAction, int from_uid)
{
if (from_uid >= 0)
{
int num = member_nums[from_uid];
int findIrcId = findIrcNick(to);
if (findIrcId >= 0)
{
if (isAction)
{
String line = ":" + members[from_uid] + "!~" + members[from_uid] + "@" + member_sources[from_uid] + " PRIVMSG " + ircNicknames[findIrcId] + " :\001ACTION " + text + "\001\r\n";
ircClients[findIrcId].print(line);
} else {
String line = ":" + members[from_uid] + "!~" + members[from_uid] + "@" + member_sources[from_uid] + " PRIVMSG " + ircNicknames[findIrcId] + " :" + text + "\r\n";
ircClients[findIrcId].print(line);
}
} else {
int findUserId = findUser(to);
if (findUserId >= 0)
{
int wsNum = member_nums[findUserId];
if (wsNum >= 0)
{
StaticJsonDocument<3072> jsonBuffer;
jsonBuffer["username"] = members[from_uid];
jsonBuffer["text"] = text;
jsonBuffer["event"] = "private";
jsonBuffer["rssi"] = WiFi.RSSI();
jsonBuffer["utc"] = now();
jsonBuffer["action"] = isAction;
jsonBuffer["source"] = member_sources[from_uid];
jsonBuffer["to"] = members[findUserId];
String out;
serializeJson(jsonBuffer, out);
//Serial.println(out);
webSocketServer.sendTXT(wsNum, out);
} else {
StaticJsonDocument<1024> jsonBuffer;
jsonBuffer["for"] = members[from_uid];
jsonBuffer["text"] = "User cannot receive private messages";
jsonBuffer["event"] = "error";
jsonBuffer["utc"] = now();
jsonBuffer["to"] = to;
String out;
serializeJson(jsonBuffer, out);
webSocketServer.sendTXT(num, out);
}
} else {
StaticJsonDocument<1024> jsonBuffer;
jsonBuffer["for"] = members[from_uid];
jsonBuffer["text"] = "Couldn't find user";
jsonBuffer["event"] = "error";
jsonBuffer["utc"] = now();
jsonBuffer["to"] = to;
String out;
serializeJson(jsonBuffer, out);
webSocketServer.sendTXT(num, out);
}
}
}
}
bool isCleanUsername(String &username)
{
for(int i = 0; i < username.length(); i++)
{
char cc = username.charAt(i);
if (cc >= 32 && cc <= 126)
{
// character is ok
} else {
return false;
}
}
return true;
}
int userCount()
{
int mc = 0;
for(int i = 0; i < MAX_MEMBERS; i++)
{
if (members[i] != "")
{
mc++;
}
}
return mc;
}
int registerUser(int wsNum, String &username, String &source, int rssi)
{
if (isCleanUsername(username))
{
// lets make sure they aren't already registerd
for(int i = 0; i < MAX_MEMBERS; i++)
{
if (members[i].equals(username))
{
member_nums[i] = wsNum;
member_sources[i] = source;
member_rssi[i] = rssi;
member_last_active[i] = millis();
return i;
}
}
// ok lets find them a slot
for(int i = 0; i < MAX_MEMBERS; i++)
{
if (members[i].equals(""))
{
//Serial.print(username);
//Serial.println(" joined the chat");
String bdy = "Joined the chat";
flashMessage(username, bdy);
members[i] = username;
member_nums[i] = wsNum;
member_sources[i] = source;
member_rssi[i] = rssi;
member_last_active[i] = millis();
String out;
StaticJsonDocument<1024> jsonBuffer;
jsonBuffer["username"] = members[i];
jsonBuffer["event"] = "join";
jsonBuffer["rssi"] = rssi;
jsonBuffer["source"] = source;
serializeJson(jsonBuffer, out);
for(int i = 0; i < webSocketServer.connectedClients(); i++)
{
if (i != wsNum)
webSocketServer.sendTXT(i, out);
}
String xmitData = "\x1B[0;92m" + username + " joined chat.\x1B[0m\r\n";
if (!source.equals("radio") && !source.equals("flipper"))
{
streamToRadio(xmitData);
}
Serial2.print(xmitData);
String ircJoin = ":" + username + "!~" + username + "@" + source + " JOIN :#lobby";
broadcastIrc(ircJoin);
return i;
}
}
}
return -1;
}
// delete all users connected to a specific websocket
void deleteUsersForNum(int wsNum)
{
if (wsNum >= 0)
{
for(int i = 0; i < MAX_MEMBERS; i++)
{
if (member_nums[i] == wsNum && !members[i].equals("") && member_sources[i].startsWith("ws"))
{
deleteUser(i);
}
}
}
}
// find user id by username
int findUser(String &username)
{
for(int i = 0; i < MAX_MEMBERS; i++)
{
if (members[i].equals(username))
{
return i;
}
}
return -1;
}
// delete user by username
int deleteUser(String &username)
{
int idx = findUser(username);
if (idx >= 0)
{
deleteUser(idx);
}
return idx;
}
// delete user by user id
void deleteUser(int idx)
{
if (!members[idx].equals(""))
{
//Serial.print(members[idx]);
//Serial.println(" left the chat");
String bdy = "Left the chat";
flashMessage(members[idx], bdy);
String out;
StaticJsonDocument<1024> jsonBuffer;
jsonBuffer["username"] = members[idx];
jsonBuffer["event"] = "part";
jsonBuffer["rssi"] = member_rssi[idx];
jsonBuffer["source"] = member_sources[idx];
serializeJson(jsonBuffer, out);
webSocketServer.broadcastTXT(out);
String xmitData = "\x1B[0;90m" + members[idx] + " left chat.\x1B[0m\r\n";
if (!member_sources[idx].equals("radio") && !member_sources[idx].equals("flipper"))
{
streamToRadio(xmitData);
}
Serial2.print(xmitData);
String ircPart = ":" + members[idx] + "!~" + members[idx] + "@" + member_sources[idx] + " PART #lobby";
broadcastIrc(ircPart);
}
members[idx] = "";
member_nums[idx] = -1;
member_sources[idx] = "";
member_rssi[idx] = 0;
member_last_active[idx] = -1;
}
void setup()
{
for(int i = 0; i < MAX_MEMBERS; i++)
{
members[i] = "";
member_nums[i] = -1;
member_sources[i] = "";
member_rssi[i] = 0;
member_last_active[i] = -1;
}
for(int i = 0; i < HISTORY_SIZE; i++)
{
history[i] = "";
}
for(int i = 0; i < MAX_IRC_CLIENTS; i++)
{
ircBufferPos[i] = 0;
ircBuffers[i][0] = 0;
ircUserId[i] = -1;
ircUsernames[i] = "";
ircNicknames[i] = "";
ircGreeted[i] = false;
}
clearRadioBuffer();
Serial.begin(115200);
Serial.println("INIT");
if (ELECHOUSE_cc1101.getCC1101())
{
Serial.println("CC1101 Connection OK");
} else {
Serial.println("CC1101 Connection Error");
}
FFat.begin();
loadSettings();
webSocketServer.begin();
webSocketServer.onEvent(webSocketServerEvent);
httpServer.on("/", handleRoot);
httpServer.onNotFound(handleNotFound);
httpServer.begin();
ircServer.begin();
ircServer.setNoDelay(true);
if (display.begin(SSD1306_SWITCHCAPVCC, SCREEN_ADDRESS))
{
Serial.println("Display INIT OK");
display.display();
display.clearDisplay();
display.setTextSize(1);
display.setTextColor(WHITE);
display.display();
displayInit = true;
} else {
Serial.println("Display INIT FAIL");
displayInit = false;
}
Serial.println("INIT_COMPLETE");
}
void clearRadioBuffer()
{
radioBufferTimer = 0;
radioBufferPos = 0;
for(int n = 0; n < 2048; n++)
{
radioBuffer[n] = '\0';
}
//Serial.println("radio buffer cleared");
}
void appendToRadioBuffer(byte c)
{
if (radioBufferPos == 0)
radioBufferTimer = millis();
if (radioBufferPos < 2047)
{
radioBuffer[radioBufferPos] = c;
radioBufferPos++;
radioBuffer[radioBufferPos] = '\0';
} else {
clearRadioBuffer();
}
}
byte buffer[255] = {0};
void readChatFromRadioBuffer()
{
char nick[20];
char msg[1024];
int mStart = 0;
for(int i = 7; i < 2048; i++)
{
if (radioBuffer[i] != 27)
{
nick[i-7] = radioBuffer[i];
} else {
nick[i-7] = '\0';
mStart = i+6;
break;
}
}
for(int i = mStart; i < 2048; i++)
{
if (radioBuffer[i] != 0)
{
msg[i-mStart] = radioBuffer[i];
} else {
msg[i-mStart] = '\0';
break;
}
}
radioRxCount++;
String username = String(nick);
String text = String(msg);
text.trim();
String source = "radio";
if (radioBuffer[4] == 51 && radioBuffer[5] == 51)
{
source = "flipper";
}
int uid = findUser(username);
if (uid == -1)
{
uid = registerUser(-1, username, source, radioRssi);
} else {
member_rssi[uid] = radioRssi;
}
if (uid >= 0 && uid < MAX_MEMBERS)
{
member_last_active[uid] = millis();
}
String out;
StaticJsonDocument<3072> jsonBuffer;
jsonBuffer["username"] = username;
jsonBuffer["text"] = text;
jsonBuffer["event"] = "chat";
jsonBuffer["rssi"] = radioRssi;
jsonBuffer["utc"] = now();
jsonBuffer["source"] = source;
serializeJson(jsonBuffer, out);
webSocketServer.broadcastTXT(out);
flashMessage(username,text);
lobbyPrivmsg(username,text);
saveHistory(out);
if (source.equals("flipper"))
{
Serial2.print("\x1B[0;33m" + username + "\x1B[0m: " + text + "\r\n");
} else {
Serial2.print("\x1B[0;91m" + username + "\x1B[0m: " + text + "\r\n");
}
}
void readInfoFromRadioBuffer()
{
char info[1024];
int mStart = 0;
for(int i = 7; i < 2048; i++)
{
if (radioBuffer[i] != 27)
{
info[i-7] = radioBuffer[i];
} else {
info[i-7] = '\0';
mStart = i+6;
break;
}
}
radioRxCount++;
String text = String(info);
text.trim();
int nnal = text.indexOf(" is now known as ");
if (nnal >= 0)
{
String formerNick = text.substring(0, nnal);
int uid = findUser(formerNick);
if (uid >= 0)
{
if (member_sources[uid].equals("radio") || member_sources[uid].equals("flipper"))
{
String newNick = text.substring(nnal+17,text.length());
userChangeName(formerNick, newNick, false);
}
}
} else {
String username = "";
if (get_token(text, username, 0, ' '))
{
int uid = findUser(username);
if (uid >= 0)
{
member_rssi[uid] = radioRssi;
String out;
StaticJsonDocument<3072> jsonBuffer;
jsonBuffer["username"] = username;
jsonBuffer["text"] = text;
jsonBuffer["event"] = "info";
jsonBuffer["rssi"] = member_rssi[uid];
jsonBuffer["utc"] = now();
jsonBuffer["source"] = member_sources[uid];
serializeJson(jsonBuffer, out);
webSocketServer.broadcastTXT(out);
saveHistory(out);
Serial2.print("\x1B[0;94m" + text + "\x1B[0m\r\n");
text.replace(username,"\001ACTION");
text += "\001";
lobbyPrivmsg(username, text);
}
}
}
}
void checkRadio()
{
bool rxed = false;
if(ELECHOUSE_cc1101.CheckRxFifo(50))
{
int len = ELECHOUSE_cc1101.ReceiveData(buffer);
radioRssi = ELECHOUSE_cc1101.getRssi();
buffer[len] = '\0';
for(int i = 0; i < len; i++)
{
byte c = buffer[i];
if (radioBufferPos == 0 && c != 27)
{
// keep scanning
} else if (radioBufferPos == 1 && c != 91) {
// reset not message start
radioBufferPos = 0;
radioBufferTimer = 0;
} else if ((c >= 32 && c <= 126) || c == 27 || c == 10 || c == 13) {
appendToRadioBuffer(c);
}
}
rxed = true;
ELECHOUSE_cc1101.SetRx();
}
if (rxed && radioBufferPos > 0)
{
if ((radioBuffer[0] == 27 && radioBuffer[1] == 91 && radioBuffer[2] == 48) && radioBuffer[radioBufferPos-1] == 10)
{
//Serial.print("color: ");
//Serial.print((int)radioBuffer[4]);
//Serial.print((int)radioBuffer[5]);
//Serial.print(" ");
//Serial.print((char)radioBuffer[4]);
//Serial.println((char)radioBuffer[5]);
if ((radioBuffer[4] == 51 && radioBuffer[5] == 51) || (radioBuffer[4] == 57 && radioBuffer[5] == 49))
{
readChatFromRadioBuffer();
} else if (radioBuffer[4] == 57 && radioBuffer[5] == 52) {
readInfoFromRadioBuffer();
} else {
String source = "radio";
if (radioBuffer[4] == 51 && (radioBuffer[5] == 52 || radioBuffer[5] == 49))
{
source = "flipper";
}
String data = String((char *)radioBuffer);
if (data.indexOf(" joined chat.") >= 0)
{
String realUsername = String(data.substring(7, data.length() - 19));
registerUser(-1, realUsername, source, radioRssi);
} else if (data.indexOf(" left chat.") >= 0) {
String realUsername = String(data.substring(7, data.length() - 17));
deleteUser(realUsername);
}
}
clearRadioBuffer();
}
}
if (radioBufferTimer > 0)
{
//if a transmission started 3 seconds ago and never finished, flush the buffer.
if ((millis() - radioBufferTimer) > 3000)
{
//Serial.print("Timer Flushed Buffer @");
//Serial.println(radioBufferPos);
clearRadioBuffer();
}
}
}
// show a message on the OLED screen of the device
void flashMessage(String &title, String &body)
{
flashMessageAt = millis();
flashMessageTitle = title;
flashMessageBody = body;
}
// Refresh the OLED screen
void redraw()
{
if (displayInit)
{
display.clearDisplay();
if (flashMessageAt > 0 && (millis() - flashMessageAt) < 10000)
{
display.setCursor(0,PIX_ROW_1);
display.setTextSize(1);
display.print(flashMessageTitle);
display.drawLine(0, 10, display.width()-1, 10, SSD1306_WHITE);
display.setCursor(0,PIX_ROW_1p5);
display.print(flashMessageBody);
} else {
display.setCursor(0,PIX_ROW_1);
display.setTextSize(2);
display.print(line1);
display.setTextSize(1);
display.setCursor(0,PIX_ROW_2);
display.print(line2);
display.setCursor(0,PIX_ROW_3);
display.print(line3);
display.setCursor(0,PIX_ROW_4);
display.print(local_ip);
}
display.display();
}
}
void clearIrcBuffer(int num)
{
ircBufferPos[num] = 0;
for(int n = 0; n < 2048; n++)
{
ircBuffers[num][n] = '\0';
}
}
void sendIrcServerResponse(int num, String code, String data)
{
int uid = ircUserId[num];
String output = ":" + hostname + " " + code + " " + ircNicknames[num] + " " + data + "\r\n";
//Serial.print("IRC RESP: ");
//Serial.print(output);
ircClients[num].print(output);
}
void ircMOTD(int num)
{
sendIrcServerResponse(num, "375", ":- " + local_ip + " Message of the day -");
sendIrcServerResponse(num, "372", ":- _____ __ ________ ________ __");
sendIrcServerResponse(num, "372", ":- / ___/__ __/ /_ / ____/ /_ ____ / ____/ /_ ____ _/ /_");
sendIrcServerResponse(num, "372", ":- \\__ \\/ / / / __ \\/ / __/ __ \\/_ / / / / __ \\/ __ `/ __/");
sendIrcServerResponse(num, "372", ":- ___/ / /_/ / /_/ / /_/ / / / / / /_ / /___/ / / / /_/ / /_");
sendIrcServerResponse(num, "372", ":- /____/\\__,_/_.___/\\____/_/ /_/ /___/ \\____/_/ /_/\\__,_/\\__/");
sendIrcServerResponse(num, "372", ":-");
sendIrcServerResponse(num, "372", ":- https://github.com/xitiomet/flipperzero-chat-esp32");
sendIrcServerResponse(num, "372", ":-");
sendIrcServerResponse(num, "372", ":- FlipperZero's - Online: " + String(flipperCount) + " Seen: " + String(maxFlippers));
sendIrcServerResponse(num, "372", ":- Network Connections: " + String(networkCount));
sendIrcServerResponse(num, "372", ":- Radio Messages RX Total: " + String(radioRxCount));
sendIrcServerResponse(num, "372", ":-");
sendIrcServerResponse(num, "376", ":End of MOTD command");
}
void ircGreet(int num)
{
sendIrcServerResponse(num, "001", ":Welcome to the SubGHZ Chat Network");
sendIrcServerResponse(num, "002", ":Your host is " + local_ip + ", running FlipperZero SubGhz Chat Relay");
sendIrcServerResponse(num, "003", ":This server was created on unknown");
sendIrcServerResponse(num, "004", hostname + " SubGhzChat * *");
sendIrcServerResponse(num, "005", "RFC2812 IRCD=FZSubGhzChat CHARSET=UTF-8 CASEMAPPING=ascii PREFIX=(qaohv)~&@%+ CHANTYPES=# CHANMODES=beI,k,l,imMnOPQRstVz CHANLIMIT=#&+:10 :are supported on this server");
sendIrcServerResponse(num, "005", "CHANNELLEN=50 NICKLEN=20 TOPICLEN=490 AWAYLEN=127 KICKLEN=400 MODES=5 MAXLIST=beI:50 EXCEPTS=e INVEX=I PENALTY FNC :are supported on this server");
sendIrcServerResponse(num, "251", ":There are " + String(userCount()) + " users on 1 server");
sendIrcServerResponse(num, "252", "1 :IRC Operators online");
sendIrcServerResponse(num, "254", "1 :channels formed");
ircMOTD(num);
ircClients[num].print(":TheReaper INVITE " + ircNicknames[num] + " #lobby\r\n");
ircGreeted[num] = true;
}
// a stringtokenizer
bool get_token(String &from, String &to, uint8_t index, char separator)
{
uint16_t start = 0, idx = 0;
uint8_t cur = 0;
while (idx < from.length())
{
if (from.charAt(idx) == separator)
{
if (cur == index)
{
to = from.substring(start, idx);
return true;
}
cur++;
while ((idx < from.length() - 1) && (from.charAt(idx + 1) == separator)) idx++;
start = idx + 1;
}
idx++;
}
if ((cur == index) && (start < from.length()))
{
to = from.substring(start, from.length());
return true;
}
return false;
}
void handleIrcCommand(int num)
{
String line = String(ircBuffers[num]);
if (line.equals("")) return;