build.gradle

buildscript {
	
	repositories {
        jcenter()
    }
    
    dependencies {
        classpath 'com.netflix.nebula:gradle-extra-configurations-plugin:3.0.3'
        classpath 'org.apache.ant:ant:1.9.7'
    }
}
plugins {
    id 'nebula.netflixoss' version '5.1.1'
}

// Establish version and status
ext.githubProjectName = rootProject.name // Change if github project name is not the same as the root project's name

apply plugin: 'project-report'
apply from: "$rootDir/versionsOfDependencies.gradle"


subprojects {

    apply plugin: 'nebula.netflixoss'
    apply plugin: 'nebula.provided-base'
    apply plugin: 'java'
    apply plugin: 'idea'
    apply plugin: 'eclipse'
    apply plugin: 'project-report'

    sourceCompatibility = 1.8
    targetCompatibility = 1.8

    repositories {
        jcenter()
    }

    dependencies {
    	testCompile "junit:junit-dep:${revJUnit}"
    	testCompile "org.mockito:mockito-all:${revMockito}"
    }

    group = "com.netflix.${githubProjectName}"
    
    tasks.withType(Test)  {
        maxParallelForks = 100
    }
    
    license {
		excludes(['**/*.txt', '**/*.conf', '**/*.properties', '**/*.json', '**/swagger-ui/*'])
	}
	
	task licenseFormatTests (type:nl.javadude.gradle.plugins.license.License) {
    	source = fileTree(dir: "src/test").include("**/*")
	}
	licenseFormat.dependsOn licenseFormatTests

}