build.gradle

apply plugin: 'groovy'
apply plugin: 'maven'
apply plugin: 'signing'

group = "com.pokitdok"
archivesBaseName = "pokitdok-java"
version = "0.7"
sourceCompatibility = 1.6
targetCompatibility = 1.6

repositories {
	mavenCentral()
	jcenter()
}

configurations {
    compile {
        transitive = true
    }
    runtime {
        extendsFrom compile, testCompile
    }
    testCompile {
    	extendsFrom compile
    	transitive = true
    }
}

dependencies {
	compile "org.apache.httpcomponents:httpclient:4.3.6"
	compile "com.googlecode.json-simple:json-simple:1.1.1"

	// We currently need to use Groovy 2.2.x due to a Betamax/Groovy bug
	// See: https://github.com/robfletcher/betamax/issues/141
	testCompile "org.codehaus.groovy:groovy-all:2.2.0"
	testCompile "co.freeside:betamax:1.1.2"
	testCompile "commons-io:commons-io:2.4"
}

if (hasProperty("sonatypeUsername") && hasProperty("sonatypePassword")) {
	// Sonatype Publishing Configurations
	task javadocJar(type: Jar, dependsOn: javadoc) {
		classifier = "javadoc"
		from "build/docs/javadoc"
	}

	task sourcesJar(type: Jar) {
		from sourceSets.main.allSource
		classifier = "sources"
	}

	artifacts {
		archives jar
		archives javadocJar
		archives sourcesJar
	}

	signing {
		sign configurations.archives
	}


	uploadArchives {
		repositories {
			mavenDeployer {
				beforeDeployment { MavenDeployment deployment -> signing.signPom(deployment) }

				repository(url: "https://oss.sonatype.org/service/local/staging/deploy/maven2/") {
					authentication(userName: sonatypeUsername, password: sonatypePassword)
				}

				snapshotRepository(url: "https://oss.sonatype.org/content/repositories/snapshots/") {
					authentication(userName: sonatypeUsername, password: sonatypePassword)
				}

				pom.project {
					name "pokitdok-java"
					packaging "jar"
					description "A Java client library for the PokitDok Platform APIs."
					url "https://github.com/pokitdok/pokitdok-java"

					scm {
						url 'scm:git@github.com:pokitdok/pokitdok-java.git'
						connection 'scm:git@github.com:pokitdok/pokitdok-java.git'
					}

					licenses {
						license {
							name "The MIT License (MIT)"
							url "http://opensource.org/licenses/MIT"
						}
					}

					developers {
						developer {
							name "PokitDok, Inc."
							email "platform@pokitdok.com"
						}
					}
				}
			}
		}
	}
}