LLgrammar.txt

## S - init stav
ProgramBody ::= FceDefine ProgramBody
ProgramBody ::= Command ProgramBody
ProgramBody ::=''

## Command
Command ::= DeclareVariable
Command ::= Condition
Command ::= While
Command ::= Return
Command ::= Exp semicolon
Command ::= semicolon
Command ::= FceCall

## Definice funkcí
FceDefine ::= functionKey FceHeader curlyBraceLeft FunctionBody curlyBraceRight
FceHeader ::= identifierFunc leftPar FunctionDeclareParams rightPar colon FuncReturnColonType
FunctionDeclareParams ::=''
FunctionDeclareParams ::= DataType DeclareParam CommaOrEpsParams
CommaOrEpsParams ::=''
CommaOrEpsParams ::= comma DataType DeclareParam  CommaOrEpsParams
DeclareParam ::=  identifierVar

## FuncReturnType
FuncReturnColonType ::= DataType
FuncReturnColonType ::= voidKey

## Function call
FceCall ::= identifierFunc leftPar FirstFceParam rightPar
FirstFceParam ::=''
FirstFceParam ::= Statement CommaOrEpsParam
CommaOrEpsParam ::=''
CommaOrEpsParam ::= comma Statement CommaOrEpsParam

## Statement (simple expression)
Statement ::= identifierVar
Statement ::= floatLiteral
Statement ::= stringLiteral
Statement ::= integerLiteral
Statement ::= nullKey

## Exp
Exp ::= Statement
Exp ::= Exp minusOp Exp
Exp ::= Exp plusOp Exp
Exp ::= Exp divisionOp Exp
Exp ::= Exp multiplicationOp Exp
Exp ::= Exp concatenationOp Exp

Exp ::= Exp lesserThanOp Exp
Exp ::= Exp lesserEqOp Exp
Exp ::= Exp greaterThanOp Exp
Exp ::= Exp greaterEqOp Exp
Exp ::= Exp eqOp Exp
Exp ::= Exp notEqOp Exp

Exp ::= leftPar Exp rightPar


## Data types DataType
DataType ::= stringNullKey
DataType ::= floatNullKey
DataType ::= intNullKey
DataType ::= stringKey
DataType ::= floatKey
DataType ::= intKey


## Definice proměné
DeclareVariable ::=  identifierVar equals DefVarAss
DefVarAss ::= Exp semicolon
DefVarAss ::= FceCall semicolon

## Podmínky
Condition ::= ifKey leftPar Exp rightPar curlyBraceLeft FunctionBody curlyBraceRight ElseCond
ElseCond ::= elseKey curlyBraceLeft FunctionBody curlyBraceRight
ElseCond ::=''

## While
While ::= whileKey leftPar Exp rightPar curlyBraceLeft FunctionBody curlyBraceRight

## Return
Return ::= returnKey ReturnExp semicolon
ReturnExp ::= Exp
ReturnExp ::=''

## Vnítřek funkce
FunctionBody ::= Command FunctionBody
FunctionBody ::=''