forked from google/automotive-design-compose
-
Notifications
You must be signed in to change notification settings - Fork 0
/
build.gradle.kts
96 lines (84 loc) · 3.23 KB
/
build.gradle.kts
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
/*
* Copyright 2023 Google LLC
*
* Licensed under the Apache License, Version 2.0 (the "License");
* you may not use this file except in compliance with the License.
* You may obtain a copy of the License at
*
* http://www.apache.org/licenses/LICENSE-2.0
*
* Unless required by applicable law or agreed to in writing, software
* distributed under the License is distributed on an "AS IS" BASIS,
* WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
* See the License for the specific language governing permissions and
* limitations under the License.
*/
import com.github.benmanes.gradle.versions.updates.DependencyUpdatesTask
import com.google.devtools.ksp.gradle.KspTask
import com.ncorti.ktfmt.gradle.tasks.KtfmtFormatTask
buildscript {
repositories {
google()
mavenCentral()
}
dependencies {
// These are plugins that are published as external jars, integrating directly into the
// build scripts
classpath(libs.kotlin.gradlePlugin)
classpath(libs.android.gradlePlugin)
classpath(libs.dokka.gradlePlugin)
classpath(libs.android.gms.strictVersionMatcher)
classpath(libs.android.gms.ossLicensesPlugin)
}
}
@Suppress("DSL_SCOPE_VIOLATION") // TODO: Remove once KTIJ-19369 is fixed
plugins {
alias(libs.plugins.ktfmt)
alias(libs.plugins.versions)
alias(libs.plugins.versionCatalogUpdate)
alias(libs.plugins.rustAndroidGradle) apply false
alias(libs.plugins.ksp) apply false
}
versionCatalogUpdate {
keep {
// The version catalog plugin seems to be very aggressive in removing versions it things are
// unused.
keepUnusedVersions.set(true)
keepUnusedLibraries.set(true)
}
}
// Function to determine whether a release is final or not.
fun String.isNonStable(): Boolean {
val stableKeyword = listOf("RELEASE", "FINAL", "GA").any { toUpperCase().contains(it) }
val regex = "^[0-9,.v-]+(-r)?$".toRegex()
val isStable = stableKeyword || regex.matches(this)
return isStable.not()
}
// https://github.com/ben-manes/gradle-versions-plugin
// Prevent the versions plugin from updating versions to non-stable releases,
// unless the dependency is already using a non-stable release
tasks.withType<DependencyUpdatesTask> {
rejectVersionIf { candidate.version.isNonStable() && !currentVersion.isNonStable() }
}
ktfmt { kotlinLangStyle() }
val fmtBuildScriptsTask =
tasks.register<KtfmtFormatTask>("ktfmtFormatBuildScripts") {
source = project.fileTree(rootDir)
include("**/*.gradle.kts")
}
subprojects {
apply {
plugin(rootProject.libs.plugins.ktfmt.get().pluginId)
plugin(rootProject.libs.plugins.strictVersionMatcher.get().pluginId)
}
configure<com.ncorti.ktfmt.gradle.KtfmtExtension> { kotlinLangStyle() }
// Replace dependencies on DesignCompose with our project
configurations.all {
resolutionStrategy.dependencySubstitution {
substitute(module("com.android.designcompose:designcompose"))
.using(project(":designcompose"))
substitute(module("com.android.designcompose:codegen")).using(project(":codegen"))
}
}
tasks.withType<KspTask>() { group = "DesignCompose Developer" }
}