build.gradle

buildscript {
    repositories {
        mavenLocal()
        mavenCentral()
        gradlePluginPortal()
    }
    dependencies {
        classpath 'com.vanniktech:gradle-maven-publish-plugin:0.29.0'
    }
}

apply plugin: 'java-library'
apply plugin: 'com.vanniktech.maven.publish'

compileJava {
    // Java 20 and up are unable to release for version 7.
    if(JavaVersion.current().isCompatibleWith(JavaVersion.VERSION_20)){
        sourceCompatibility = 8
        targetCompatibility = 8
        options.release.set(8)
    }
    else {
        sourceCompatibility = 7
        targetCompatibility = 7
        if (JavaVersion.current().isJava9Compatible()) {
            options.release.set(7)
        }
    }
}

compileTestJava {
    sourceCompatibility = 8
    targetCompatibility = 8
    if (JavaVersion.current().isJava9Compatible()) {
        options.release.set(8)
    }
}

def projectName = 'anim8-gdx'
version "$VERSION_NAME"
group 'com.github.tommyettinger'

//api "com.github.tommyettinger:anim8-gdx:0.4.3"

[compileJava, compileTestJava, javadoc]*.options*.encoding = 'UTF-8'

// Disable JDK 8's doclint
// http://blog.joda.org/2014/02/turning-off-doclint-in-jdk-8-javadoc.html
if (JavaVersion.current().isJava8Compatible()) {
    allprojects {
        tasks.withType(Javadoc).tap {
            configureEach {
                // The -quiet is because of some sort of weird JDK JavaCompiler bug:
                // https://discuss.gradle.org/t/passing-arguments-to-compiler-and-javadoc/1661
                options.addStringOption('Xdoclint:none,-missing', '-quiet')
            }
        }
    }
}

javadoc.destinationDir = file('docs/apidocs')

//sourceSets.test.resources.srcDirs += [ file('src/test/resources').path ]

jar {
    archiveBaseName.set(projectName)
    duplicatesStrategy(DuplicatesStrategy.EXCLUDE)
    manifest {
        attributes 'Implementation-Title': projectName, 'Implementation-Version': archiveVersion
    }
}

repositories {
    mavenCentral()
    maven { url 'https://oss.sonatype.org/content/repositories/snapshots/' }
}

dependencies {
    api "com.badlogicgames.gdx:gdx:$gdxVersion"
    testImplementation "com.badlogicgames.gdx:gdx-backend-lwjgl3:$gdxVersion"
    testImplementation "com.badlogicgames.gdx:gdx-platform:$gdxVersion:natives-desktop"
}