build.gradle

plugins {
    id 'java'
    id 'application'
    id 'com.github.johnrengelman.shadow' version '8.1.1'
}

group = 'me.judge'
version = '1.0-SNAPSHOT'

application {
    mainClass = 'me.judge.mcnativebuilder.Main'
}

repositories {
    maven {
        url = "https://repo.u-team.info"
    }
    mavenCentral()
}

configurations {
    extraLibs
}

dependencies {
    shadow(implementation("net.hycrafthd:minecraft_downloader:1.1.1"))
    shadow(implementation("net.sourceforge.argparse4j:argparse4j:0.9.0"))

    extraLibs(implementation(project(":mc-lib"))) {
        transitive = false
    }

    testImplementation platform('org.junit:junit-bom:5.9.1')
    testImplementation 'org.junit.jupiter:junit-jupiter'
}

def copy = tasks.register('copyDependencies', Copy) {
    into "$buildDir/extraLibs"
    from configurations.extraLibs
}

jar {
    dependsOn(copy)
    from {
        "$buildDir/extraLibs"
    } {
        into 'extraLibs'
    }
}

shadowJar {
    dependsOn(copy)
    from {
        "$buildDir/extraLibs"
    } {
        into 'extraLibs'
    }
}

test {
    useJUnitPlatform()
}