build.gradle

import org.gradle.nativeplatform.platform.internal.DefaultNativePlatform

buildscript {
    repositories {
        jcenter()
    }

    dependencies {
        classpath "org.jetbrains.dokka:dokka-gradle-plugin:0.9.17"
        classpath "com.netflix.nebula:nebula-kotlin-plugin:1.3.61"
        classpath "com.netflix.nebula:nebula-publishing-plugin:14.1.1"
        classpath "com.netflix.nebula:nebula-release-plugin:13.2.0"
        classpath "com.netflix.nebula:nebula-bintray-plugin:7.5.0"
    }
}


apply plugin: 'org.jetbrains.dokka'

project.ext {
    lwjglVersion = '3.2.3'
    ffmpeg_version = '4.2.1-1.5.2'
    kotlinVersion = '1.3.61'
    spekVersion = '2.0.9'
}



dokka {
    moduleName = "$rootProject.name"
    outputDirectory = "$buildDir/docs"
    outputFormat = "html"
    includes = ['Module.md']



    sourceDirs = files(subprojects.collect { p -> new File(p.projectDir, "/src/main/kotlin") })
    if (!System.properties['os.name'].toLowerCase().contains('windows')) {
        doLast {
            exec {
                executable "./dokka/postbuild.sh"
            }
        }
    }
}

allprojects {
    apply plugin: 'idea'
    apply plugin: 'java'
    apply plugin: 'nebula.kotlin'
    apply plugin: 'nebula.contacts'

    // -- work-around for problem with nebula.info on arm64, which is currently not used a build host platform
    def arch = new DefaultNativePlatform("current").architecture.name
    if (arch != 'aarch64') {
        apply plugin: 'nebula.info'
    }
//    apply plugin: 'nebula.dependency-lock'

    apply plugin: 'nebula.release'
    // selectively apply only the bintray plugin, snapshots are not published
    // nebula-bintray needs to happened after nebula-release since version isn't lazy in the bintray extension

    apply plugin: 'nebula.maven-publish'
    apply plugin: 'nebula.source-jar'
    apply plugin: 'nebula.javadoc-jar'
    apply plugin: 'nebula.nebula-bintray-publishing'

    group 'org.openrndr'

    repositories {
        jcenter()
        maven {
            url "https://dl.bintray.com/spekframework/spek"
        }
    }

    dependencies {
        implementation 'io.github.microutils:kotlin-logging:1.7.8'
        implementation 'org.jetbrains.kotlinx:kotlinx-coroutines-core:1.3.3'

        testImplementation "org.spekframework.spek2:spek-dsl-jvm:$spekVersion"
        testImplementation "org.amshove.kluent:kluent:1.59"
        testImplementation "org.jetbrains.kotlin:kotlin-test:$kotlinVersion"
        testRuntimeOnly "org.spekframework.spek2:spek-runner-junit5:$spekVersion"
        testRuntimeOnly "org.jetbrains.kotlin:kotlin-reflect:$kotlinVersion"

    }

    test {
        useJUnitPlatform {
            includeEngines 'spek2'
        }
    }

    javadoc {
        options.addBooleanOption 'Xdoclint:none', true
    }



    /*
    if (System.getenv('TRAVIS') == null) {
        task runJupiter(type: JavaExec) {
            if (System.properties['os.name'].toLowerCase().contains('mac')) {
               jvmArgs '-XstartOnFirstThread'
            }
            classpath = project.sourceSets.test.runtimeClasspath
            main 'org.junit.platform.console.ConsoleLauncher'
            args '--scan-class-path'
            args "--reports-dir=$project.testReportDir"
        }
        test.dependsOn runJupiter
    }*/

    contacts {
        'edwin@openrndr.org' {
            moniker 'Edwin Jakobs'
            github 'edwinRNDR'
        }
    }

    bintray {
        user = findProperty('bintrayUser') ?: System.getenv('BINTRAY_USER')
        apiKey = findProperty('bintrayKey') ?: System.getenv('BINTRAY_KEY')
        userOrg = 'openrndr'
        repo = 'openrndr'
        pkgName = 'openrndr'
        gppSign = false
        syncToMavenCentral = false
        licenses = ['BSD-2-Clause']
        vcsUrl = 'https://github.com/openrndr/openrndr.git'
        websiteUrl = 'https://www.openrndr.org'
        issueTrackerUrl = 'https://github.com/openrndr/openrndr/issues'
        labels = ['creative-coding', 'realtime-rendering', 'opengl']
    }
}

configure(subprojects) {
    tasks.withType(org.jetbrains.kotlin.gradle.tasks.AbstractKotlinCompile).all {
        kotlinOptions.freeCompilerArgs += ["-Xuse-experimental=kotlinx.coroutines.InternalCoroutinesApi"]
    }
}