Add 'coverage' make target

Assignment to OBJECTS_DIR, MOC_DIR and similar qmake variables must be
removed for coverage analysis to work. Please consider using shadow
build to keep your source tree clean of build artifacts:

cd build && qmake .. && make

Author: martyone

build/.gitignore

@@ -0,0 +1 @@
+*

coverage.pri

@@ -0,0 +1,23 @@
+COVERAGE_EXCLUDES = \
+    /usr/* \
+    */moc_*.cpp \
+    */*.moc \
+    */qrc_*.cpp \
+    /build/* \
+    /json/* \
+    /tests/* \
+    mnotificationmanagerproxy.h \
+    mnotificationmanagerproxy.cpp \
+
+coverage.CONFIG = phony
+coverage.commands = '\
+        @echo "--- coverage: extracting info"$$escape_expand(\\n\\t) \
+        lcov -c -o lcov.info -d .$$escape_expand(\\n\\t) \
+        @echo "--- coverage: excluding $$join(COVERAGE_EXCLUDES, ", ")"$$escape_expand(\\n\\t) \
+        lcov -r lcov.info $$join(COVERAGE_EXCLUDES, "' '", "'", "'") -o lcov.info$$escape_expand(\\n\\t) \
+        @echo "--- coverage: generating html"$$escape_expand(\\n\\t) \
+        genhtml -o coverage lcov.info --demangle-cpp$$escape_expand(\\n\\t) \
+        @echo -e "--- coverage: done\\n\\n\\tfile://$${OUT_PWD}/coverage/index.html\\n" \
+        '
+
+QMAKE_EXTRA_TARGETS += coverage

mlite.pro

@@ -3,3 +3,6 @@ CONFIG += ordered
 SUBDIRS = \
         src \
         tests \
+
+# Adds 'coverage' make target
+include(coverage.pri)

src/src.pro

@@ -75,9 +75,6 @@ HEADERS += $$INSTALL_HEADERS
 
 DEFINES += MLITE_LIBRARY
 
-OBJECTS_DIR = .obj
-MOC_DIR = .moc
-
 PCFILE=mlite$${NODASH_QT_VERSION}.pc
 configure($${PWD}/$${PCFILE}.in)
 pcfiles.files = $$PCFILE