Simple volume spot light

Author: przemyslawzaworski

VolumeSpotLight.cs

@@ -0,0 +1,64 @@
+// Add script to Main Camera. Volume spot light will be rendered in world position (0,0,0).
+// Script will be improved in future.
+
+using UnityEngine;
+
+public class VolumeSpotLight: MonoBehaviour
+{
+	public Shader VolumeLightShader;
+	Material _Material;
+	Camera _Camera;
+		
+	private Matrix4x4 GetFrustumCorners(Camera cam)
+	{
+		Matrix4x4 frustumCorners = Matrix4x4.identity;
+		float fovWHalf = cam.fieldOfView * 0.5f;
+		float tan_fov = Mathf.Tan(fovWHalf * Mathf.Deg2Rad);
+		Vector3 toRight = Vector3.right * tan_fov * cam.aspect;
+		Vector3 toTop = Vector3.up * tan_fov;
+		Vector3 topLeft = (-Vector3.forward - toRight + toTop);
+		Vector3 topRight = (-Vector3.forward + toRight + toTop);
+		Vector3 bottomRight = (-Vector3.forward + toRight - toTop);
+		Vector3 bottomLeft = (-Vector3.forward - toRight - toTop);
+		frustumCorners.SetRow(0, topLeft);
+		frustumCorners.SetRow(1, topRight);
+		frustumCorners.SetRow(2, bottomRight);
+		frustumCorners.SetRow(3, bottomLeft);
+		return frustumCorners;
+	} 
+
+	void Blit(RenderTexture source, RenderTexture dest, Material fxMaterial, int passNr)
+	{
+		RenderTexture.active = dest;
+		fxMaterial.SetTexture("_MainTex", source);
+		GL.PushMatrix();
+		GL.LoadOrtho(); 
+		fxMaterial.SetPass(passNr);
+		GL.Begin(GL.QUADS);
+		GL.MultiTexCoord2(0, 0.0f, 0.0f);
+		GL.Vertex3(0.0f, 0.0f, 3.0f);
+		GL.MultiTexCoord2(0, 1.0f, 0.0f);
+		GL.Vertex3(1.0f, 0.0f, 2.0f);
+		GL.MultiTexCoord2(0, 1.0f, 1.0f);
+		GL.Vertex3(1.0f, 1.0f, 1.0f);
+		GL.MultiTexCoord2(0, 0.0f, 1.0f);
+		GL.Vertex3(0.0f, 1.0f, 0.0f);       
+		GL.End();
+		GL.PopMatrix();
+	}
+	
+	void Start ()
+	{
+		_Camera = Camera.main;
+		_Material = new Material(VolumeLightShader);
+	}
+	
+	void OnRenderImage(RenderTexture source, RenderTexture destination)
+	{
+		_Material.SetMatrix("_FrustumCornersES", GetFrustumCorners(_Camera));
+		_Material.SetMatrix("_CameraInvViewMatrix", _Camera.cameraToWorldMatrix);
+		_Material.SetVector("_CameraWS", _Camera.transform.position);
+		Blit(source, destination, _Material, 0);
+	}
+
+}

VolumeSpotLight.shader

@@ -0,0 +1,99 @@
+Shader "VolumeSpotLight"
+{
+	SubShader
+	{
+		Cull Off ZWrite Off ZTest Always
+		Pass
+		{
+			CGPROGRAM
+			#pragma vertex VSMain
+			#pragma fragment PSMain
+			
+			sampler2D _CameraDepthTexture;
+			sampler2D _MainTex;
+			float4x4 _CameraInvViewMatrix;
+			float4x4 _FrustumCornersES;
+			float4 _CameraWS;
+
+			bool cone(float3 org, float3 dir, out float near, out float far, float d)
+			{
+				org.x += 0.5;
+				float s = 0.5;
+				org.x *= s;
+				dir.x *= s;
+				float a = dir.y * dir.y + dir.z * dir.z - dir.x * dir.x;
+				float b = org.y * dir.y + org.z * dir.z - org.x * dir.x;
+				float c = org.y * org.y + org.z * org.z - org.x * org.x;	
+				float cap = (s - org.x) / dir.x;	
+				if( a == 0.0 )
+				{
+					near = -0.5 * c/b;
+					float x = org.x + near * dir.x;
+					if( x < 0.0 || x > s ) return false; 
+					far = cap;
+					float temp = min(far, near); 
+					far = max(far, near);
+					near = temp;
+					return far > 0.0;
+				}
+				float delta = b * b - a * c;
+				if( delta < 0.0 ) return false;
+				float deltasqrt = sqrt(delta);
+				float arcp = 1.0 / a;
+				near = (-b - deltasqrt) * arcp;
+				far = (-b + deltasqrt) * arcp;
+				float temp = min(far, near);
+				far = max(far, near);
+				near = temp;
+				float xnear = org.x + near * dir.x;
+				float xfar = org.x + far * dir.x;	
+				if( xnear < 0.0 )
+				{
+					if( xfar < 0.0 || xfar > s ) return false;		
+					near = far;
+					far = cap;
+				}
+				else if( xnear > s )
+				{
+					if( xfar < 0.0 || xfar > s ) return false;		
+					near = cap;
+				}
+				else if( xfar < 0.0 )
+				{
+					far = near;
+					near = cap;
+				}
+				else if( xfar > s )
+				{
+					far = cap;
+				}		
+				if (far>d) return false;
+				return far > 0.0;
+			}		
+						
+			void VSMain (inout float4 vertex : POSITION, inout float2 uv : TEXCOORD0, out float3 ray:TEXCOORD1)
+			{			
+				half index = vertex.z;
+				vertex.z = 0.1;				
+				vertex = UnityObjectToClipPos(vertex);
+				ray = _FrustumCornersES[(int)index].xyz;
+				ray /= abs(ray.z);
+				ray = mul(_CameraInvViewMatrix, ray);
+			}
+			
+			float4 PSMain (float4 vertex : POSITION, float2 uv : TEXCOORD0, float3 ray:TEXCOORD1) : SV_Target
+			{		
+				float far=0.0, near=0.0;
+				float depth = 1.0 / (_ZBufferParams.z * tex2D(_CameraDepthTexture,uv).r + _ZBufferParams.w) * length(ray);   
+				float4 color = tex2D(_MainTex,uv);			
+				if (cone (_CameraWS, normalize(ray), near, far, depth))
+				{
+					float k = far - max(near, 0.0);
+					color += float4(k,k,0.9*k,k);
+				}			
+				return color;
+			}
+			ENDCG
+		}
+	}
+}