Добавлен LRU кеш для лямбда выражений

Author: sfaqer

packagedef

@@ -1,5 +1,5 @@
 Описание.Имя("lambdas")
-        .Версия("0.3.0")
+        .Версия("0.3.1")
         .Автор("Кирилл Черненко")
         .АдресАвтора("https://github.com/sfaqer")
         .Описание("API для реализации функциональных интерфейсов для OneScript")

src/internal/Модули/ЛямбдыКешируемыеЗначения.os

@@ -1,6 +1,8 @@
 Перем ЭтоЛямбдаВыражение;      // Кеш регулярного выражения лямбда выражения
 Перем СодержитВозвратЗначения; // Кеш регулярного выражения содержит возврат значения
 
+Перем КешСозданныхЛямбд; // LRU кеш созданных лямбд
+
 Функция РегулярноеВыражениеЭтоЛямбдаВыражение() Экспорт
 
 	Если ЭтоЛямбдаВыражение = Неопределено Тогда
@@ -24,3 +26,46 @@
 	Возврат СодержитВозвратЗначения;
 
 КонецФункции
+
+Функция ДостатьИзКеша(Выражение, Интерфейс, Контекст, ЗахватываемыйОбъект) Экспорт
+
+	Строки = КешСозданныхЛямбд.НайтиСтроки(
+		Новый Структура(
+			"Выражение, Интерфейс, Контекст, ЗахватываемыйОбъект",
+			Выражение,
+			Интерфейс,
+			Контекст,
+			ЗахватываемыйОбъект
+		)
+	);
+
+	Если Строки.Количество() = 0 Тогда
+		Возврат Неопределено;
+	КонецЕсли;
+
+	КешСозданныхЛямбд.Сдвинуть(Строки[0], -КешСозданныхЛямбд.Индекс(Строки[0]));
+	Возврат Строки[0].Объект;
+
+КонецФункции
+
+Процедура ПоложитьВКеш(Выражение, Интерфейс, Контекст, ЗахватываемыйОбъект, Объект) Экспорт
+
+	Строка = КешСозданныхЛямбд.Вставить(0);
+	Строка.Выражение           = Выражение;
+	Строка.Интерфейс           = Интерфейс;
+	Строка.Контекст            = Контекст;
+	Строка.ЗахватываемыйОбъект = ЗахватываемыйОбъект;
+	Строка.Объект              = Объект;
+
+	Если КешСозданныхЛямбд.Количество() > 20 Тогда
+		КешСозданныхЛямбд.Удалить(КешСозданныхЛямбд.Количество() - 1);
+	КонецЕсли;
+
+КонецПроцедуры
+
+КешСозданныхЛямбд = Новый ТаблицаЗначений();
+КешСозданныхЛямбд.Колонки.Добавить("Выражение");
+КешСозданныхЛямбд.Колонки.Добавить("Интерфейс");
+КешСозданныхЛямбд.Колонки.Добавить("Контекст");
+КешСозданныхЛямбд.Колонки.Добавить("ЗахватываемыйОбъект");
+КешСозданныхЛямбд.Колонки.Добавить("Объект");

src/Классы/ЛямбдаВыражение.os

@@ -141,80 +141,19 @@
 //   Сценарий - Созданный сценарий
 //
 Функция ВОбъект() Экспорт
-	
+
 	Если Не ЗначениеЗаполнено(мИнтерфейс) Тогда
 		ОпределитьИнтерфейс();
 	КонецЕсли;
 
-	МетодИнтерфейса = мИнтерфейс.ПолучитьКартуИнтерфейса()[0];
+	Объект = ЛямбдыКешируемыеЗначения.ДостатьИзКеша(мВыражение, мИнтерфейс, мКонтекст, мОбъект);
+	ОбработкаДекоратора.СинхронизироватьПоля(мОбъект, Объект);
 
-	Метод = Новый Метод(МетодИнтерфейса.Имя)
-		.Публичный()
-		.ТелоМетода(РазобранноеВыражение.Тело);
-
-	Если Не МетодИнтерфейса.ЭтоФункция Тогда
-		Метод.ЭтоПроцедура();
+	Если Не ЗначениеЗаполнено(Объект) Тогда
+		Объект = СоздатьОбъект();
+		ЛямбдыКешируемыеЗначения.ПоложитьВКеш(мВыражение, мИнтерфейс, мКонтекст, мОбъект, Объект);
 	КонецЕсли;
 
-	Для Каждого Аннотация Из РазобранноеВыражение.Аннотации Цикл
-
-		АннотацияМетода = Новый Аннотация(Аннотация.Имя);
-
-		Для Каждого ПараметрАннотации Из Аннотация.Параметры Цикл
-			АннотацияМетода.Параметр(ПараметрАннотации.Значение, ПараметрАннотации.Имя);
-		КонецЦикла;
-
-		Метод.Аннотация(АннотацияМетода);
-
-	КонецЦикла;
-
-	Для каждого Параметр Из РазобранноеВыражение.Параметры Цикл
-
-		ПараметрМетода = Новый ПараметрМетода(Параметр.Имя);
-
-		Для Каждого Аннотация Из Параметр.Аннотации Цикл
-
-			АннотацияПараметра = Новый Аннотация(Аннотация.Имя);
-
-			Для Каждого ПараметрАннотации Из Аннотация.Параметры Цикл
-				АннотацияПараметра.Параметр(ПараметрАннотации.Значение, ПараметрАннотации.Имя);
-			КонецЦикла;
-
-			ПараметрМетода.Аннотация(АннотацияПараметра);
-
-		КонецЦикла;
-
-		Метод.Параметр(ПараметрМетода);
-
-	КонецЦикла;
-
-	Построитель = Новый ПостроительДекоратора(мОбъект)
-		.Отладка(Отладка)
-		.Поле(Новый Поле("Выражение").ЗначениеПоУмолчанию(мВыражение))
-		.Метод(Метод)
-		.Метод(
-			Новый Метод("ОбработкаПолученияПредставления")
-				.ЭтоПроцедура()
-				.Параметр(Новый ПараметрМетода("Представление"))
-				.Параметр(Новый ПараметрМетода("СтандартнаяОбработка"))
-				.ТелоМетода("СтандартнаяОбработка = Ложь; Представление = Выражение;")
-		);
-
-	Для каждого ПеременнаяИЗначение Из мКонтекст Цикл
-		
-		Построитель.Поле(
-			Новый Поле(ПеременнаяИЗначение.Ключ)
-				.ЗначениеПоУмолчанию(ПеременнаяИЗначение.Значение)
-		);
-
-	КонецЦикла;
-	
-	Объект = Построитель.Построить();
-
-	Рефлектор = Новый РефлекторОбъекта(Объект);
-
-	Рефлектор.РеализуетИнтерфейс(мИнтерфейс, Истина);
-
 	Возврат Объект;
 
 КонецФункции
@@ -295,14 +234,90 @@
 
 КонецПроцедуры
 
+Функция СоздатьОбъект()
+
+	МетодИнтерфейса = мИнтерфейс.ПолучитьКартуИнтерфейса()[0];
+
+	Метод = Новый Метод(МетодИнтерфейса.Имя)
+		.Публичный()
+		.ТелоМетода(РазобранноеВыражение.Тело);
+
+	Если Не МетодИнтерфейса.ЭтоФункция Тогда
+		Метод.ЭтоПроцедура();
+	КонецЕсли;
+
+	Для Каждого Аннотация Из РазобранноеВыражение.Аннотации Цикл
+
+		АннотацияМетода = Новый Аннотация(Аннотация.Имя);
+
+		Для Каждого ПараметрАннотации Из Аннотация.Параметры Цикл
+			АннотацияМетода.Параметр(ПараметрАннотации.Значение, ПараметрАннотации.Имя);
+		КонецЦикла;
+
+		Метод.Аннотация(АннотацияМетода);
+
+	КонецЦикла;
+
+	Для каждого Параметр Из РазобранноеВыражение.Параметры Цикл
+
+		ПараметрМетода = Новый ПараметрМетода(Параметр.Имя);
+
+		Для Каждого Аннотация Из Параметр.Аннотации Цикл
+
+			АннотацияПараметра = Новый Аннотация(Аннотация.Имя);
+
+			Для Каждого ПараметрАннотации Из Аннотация.Параметры Цикл
+				АннотацияПараметра.Параметр(ПараметрАннотации.Значение, ПараметрАннотации.Имя);
+			КонецЦикла;
+
+			ПараметрМетода.Аннотация(АннотацияПараметра);
+
+		КонецЦикла;
+
+		Метод.Параметр(ПараметрМетода);
+
+	КонецЦикла;
+
+	Построитель = Новый ПостроительДекоратора(мОбъект)
+		.Отладка(Отладка)
+		.Поле(Новый Поле("Выражение").ЗначениеПоУмолчанию(мВыражение))
+		.Метод(Метод)
+		.Метод(
+			Новый Метод("ОбработкаПолученияПредставления")
+				.ЭтоПроцедура()
+				.Параметр(Новый ПараметрМетода("Представление"))
+				.Параметр(Новый ПараметрМетода("СтандартнаяОбработка"))
+				.ТелоМетода("СтандартнаяОбработка = Ложь; Представление = Выражение;")
+		);
+
+	Контекст = ?(ЗначениеЗаполнено(мКонтекст), мКонтекст, Новый Структура());
+
+	Для каждого ПеременнаяИЗначение Из Контекст Цикл
+
+		Построитель.Поле(
+			Новый Поле(ПеременнаяИЗначение.Ключ)
+				.ЗначениеПоУмолчанию(ПеременнаяИЗначение.Значение)
+		);
+
+	КонецЦикла;
+
+	Объект = Построитель.Построить();
+
+	Рефлектор = Новый РефлекторОбъекта(Объект);
+
+	Рефлектор.РеализуетИнтерфейс(мИнтерфейс, Истина);
+
+	Возврат Объект;
+
+КонецФункции
+
 Процедура ПриСозданииОбъекта(Выражение)
 
 	РазобранноеВыражение = Новый Структура(
 		"Аннотации, Параметры, Тело"
 	);
 
 	мВыражение = Выражение;
-	мКонтекст  = Новый Структура();
 	Отладка    = Ложь;
 
 	РазобратьВыражение(Выражение);

tests/ЛямбдаВыражение.os

@@ -571,6 +571,45 @@
 
 КонецПроцедуры
 
+&Тест
+Процедура ОбъектыЛямбдаВыраженийКешируются() Экспорт
+
+	// Дано
+	ЛямбдаВыражение = Новый ЛямбдаВыражение("х -> х = х + 1");
+	Объект = ЛямбдаВыражение.ВОбъект();
+
+	ЛямбдаВыражение = Новый ЛямбдаВыражение("х -> х = х + 1");
+
+	// Когда
+	Результат = ЛямбдаВыражение.ВОбъект();
+
+	// Тогда
+	Ожидаем.Что(Результат).Равно(Объект);
+
+КонецПроцедуры
+
+&Тест
+Процедура ОбъектыЛямбдаВыраженийВытесняютсяИзКеша() Экспорт
+
+	// Дано
+	ЛямбдаВыражение = Новый ЛямбдаВыражение("х -> х = х + 1");
+	Объект = ЛямбдаВыражение.ВОбъект();
+
+	Для Сч = 2 По 22 Цикл // Вытесним из кеша
+		_ = Новый ЛямбдаВыражение("х -> х = х + " + Сч)
+			.ВОбъект();
+	КонецЦикла;
+
+	ЛямбдаВыражение = Новый ЛямбдаВыражение("х -> х = х + 1");
+
+	// Когда
+	Результат = ЛямбдаВыражение.ВОбъект();
+
+	// Тогда
+	Ожидаем.Что(Результат).Не_().Равно(Объект);
+
+КонецПроцедуры
+
 Функция ЗахватываемыйОбъект()
 
 	Возврат Новый ПостроительДекоратора()