Generate blocks dynamically

[StoffelCPR]

Introduction

Hello together,

I'm struggling with something and I can't find a solution in the documentation nor can ChatGPT.

I've written my own module to generate virtualmachines inside a Proxmox cluster.

Code basis

resource "proxmox_vm_qemu" "virtualmachine" {
  name        = var.vm_name
  desc        = var.vm_description
  target_node = var.target_node
  vmid        = var.vm_id

  clone = var.clone_vm_name
  agent = var.agent
  pool  = var.pool

  os_type = var.os_name
  cores   = var.cores
  sockets = var.sockets
  memory  = var.memory
  balloon = var.memory
  tags    = var.tags

  scsihw = var.scsihw

  disks {
    ide {
      dynamic "ide3" {
        for_each = var.cloudinit == true ? [1] : []
        content {
          cloudinit {
            storage = var.storage
          }
        }
      }
    }
    scsi {
      scsi0 {
        disk {
          size    = var.main_disk_size
          storage = var.storage
        }
      }
    }
  }

  network {
    bridge   = var.bridge
    model    = "virtio"
    firewall = var.firewall
    tag      = var.network_tag
  }

  ipconfig0 = var.ipconfig0
  ciuser    = var.ciuser
  cipassword = var.cipassword
  sshkeys   = var.ssh_keys

  boot = "order=scsi0"
}

My question is about the disks{}

I have my main disk and a possible cloudinit disk set up for all VMs. They will always be the same.

Some VMs will receive multiple disks for LVM encryption so I need to generate these.

Question

Can I somehow generate additional SCSI disks here with tofu code that depend on a variable?

e.g.

variable "additional_disks" {
  description = "List of additional disks to be attached to the VM"
  type        = list(object({
    size     = string
    storage  = string
  }))
  default     = []
}

With this variable I'd like to have scsi1, scsi2 and scsi3 generated if they're present in the additional_disks variable.

Any ideas?

[abstractionfactory]

Hi @StoffelCPR you could use a local to prepare the data and then for_each over the data in a dynamic block.

[mivalsten]

I don't think that would work, what @StoffelCPR wants to achieve is to have dynamically generated block names. As far as I'm aware, you can't use count like dynamic "scsi{count.index}" {count = length(var.dynamic_disks)}, so the only solution would be to preemtively write all scsi{1..20} blocks and use count or for_each to create them if they exist. That would require rewriting the variable to be a map in my opinion.

This solution is by no means pretty, but given the data structure of proxmox vm it's probably the only solution aside from making a PR to them to introduce alternative structure based on properties, not blocks.

variable "additional_disks" {
  type = map(object({ size = string }))
  default = {
    "scsi1" = { size = "20G" },
    "scsi2" = { size = "15G" }
  }
}

resource "proxmox_vm_qemu" "virtualmachine" {
 # ...
  disks {
    scsi0 {
      size    = var.main_disk_size
      storage = var.storage
      
    }

    dynamic "scsi1" {
      for_each = { for k, v in var.dynamic_disks : k => v if k == "scsi1" }
      content {
        size = scsi1.value.size
      }
    }

    dynamic "scsi2" {
      for_each = { for k, v in var.dynamic_disks : k => v if k == "scsi2" }
      content {
        size = scsi2.value.size
      }
    }
    # ...
    dynamic "scsi20" {
      for_each = { for k, v in var.dynamic_disks : k => v if k == "scsi20" }
      content {
        size = scsi20.value.size
      }
    }
  }
}

[apparentlymart]

The way this disks block type is designed is quite unusual and indeed doesn't really match the OpenTofu language's design assumptions for dynamic block generation. 🤔

From the docs it seems like there is an alternative block type disk (singular) which seems to be there specifically to make it easier to use with dynamic blocks. I'm not familiar with Proxmox so I'm not sure if that would actually help, but if it works then it would hopefully avoid the oddity of a separate dynamic block for each nested block type of disks.

[cob-web-corner]

Take a look at bgp/terraform-provider-proxmox, I find it to be a lot more extensible than the other proxmox providers

https://github.com/bpg/terraform-provider-proxmox/blob/aa249857605ea7275649824d1962fe4589858540/example/resource_virtual_environment_vm.tf#L216-L228