Making nixGL works with Home Manager

[thanhnguyen2187]

Hi.

Thanks for the awesome work!

I am using Home Manager within Pop OS 22.04 and have got stuck trying to make nixGL works. My configuration basically looks like this:

{ config, pkgs, ... }:
let
  # TODO: find a way to make the config more declarative
  #   nix-channel --add https://nixos.org/channels/nixpkgs-unstable nixpkgs-unstable
  #   nix-channel --add https://github.com/guibou/nixGL/archive/main.tar.gz nixgl && nix-channel --update
  pkgsUnstable = import <nixpkgs-unstable> {};
  nixGL = import <nixgl> {};
in
{
  programs.alacritty = {
    enable = true;
    settings = {
      font = {
        size = 12;
        normal = {
          family = "JetBrains Mono Nerd Font";
          style = "Regular";
        };
      };
    };
    package = pkgs.writeShellScriptBin "alacritty" ''
      #!/bin/sh

      ${nixGL.auto.nixGLNvidia}/bin/nixGLNvidia ${pkgs.alacritty}/bin/alacritty "$@"
    '';
  };
}

Try running home-manager switch gives me this:

building '/nix/store/38na3sdwf8j5gfhh4mm5x337q0ph384f-impure-nvidia-version-file.drv'...
error: 'submoduleWith' at /nix/store/z2w2v2hv8y3pacq2bjjk5sxmsrnlq188-nixpkgs/nixpkgs/lib/types.nix:570:7 called with unexpected argument 'description'

       at /home/thanh/.nix-defexpr/channels/home-manager/nixos/common.nix:14:14:

           13|
           14|   hmModule = types.submoduleWith {
             |              ^
           15|     description = "Home Manager module";
(use '--show-trace' to show detailed location information)

While nix-env -iA nixgl.auto.nixGLDefault, and then nixGL alacritty works as expected.

I found a few issues on nixGL is not a proper package of nixpkgs, and guess that it probably is the issue. I wonder if there is a workaround? Using nix and Home Manager feels so good that I do not want to come back to good old apt...

Thanks!

[SuperSandro2000]

  # TODO: find a way to make the config more declarative

flakes is what you are searching for.

    package = pkgs.writeShellScriptBin "alacritty" ''
      #!/bin/sh

      ${nixGL.auto.nixGLNvidia}/bin/nixGLNvidia ${pkgs.alacritty}/bin/alacritty "$@"
    '';

I don't think you can do this. I would try to add this to home.package instead and hope it gets in $PATH before alacrity. If that does not work I would try to make the wrapper you created a full package, without writeShellScript*.

[thanhnguyen2187]

Thanks a lot for the comment @SuperSandro2000. Forgot to mention that I did add nixGL.auto.nixGLNvidia to my home.packages, but the error was the same. Do you have any other idea?

[Gerschtli]

For some inspiration, I wrapped my google-chrome with nixGL like this: Gerschtli/nix-config@ab51b30

Maybe there could be a library function exported by this flake to get the needed lines directly without reading the package. @guibou What do you think? If we can agree on an API, I could create a PR :)

[dali99]

https://github.com/dali99/nix-dotfiles/blob/9639108c536fd7f1ab4d5606d5f5ee1b51bd0a4c/profiles/xsession/default.nix#L121 I have this for my non-nixos machines.

This successfully starts my window manager and lets me run gui programs without wrapping those induvidually

[gzagatti]

If anyone lands here also see my answer in Issue #114. You can wrap packages with nixGL such that they will start without any issues.

This way you don't necessarily need to install another window manager. My use case is to use Home Manager as a replacement for brew.

[rengare]

@thanhnguyen2187
Here is my wrapper example musing both GL and Vulkan drivers

  nixGLVulkanMesaWrap = pkg:
    pkgs.runCommand "${pkg.name}-nixgl-wrapper" { } ''
      mkdir $out
      ln -s ${pkg}/* $out
      rm $out/bin
      mkdir $out/bin
      for bin in ${pkg}/bin/*; do
       wrapped_bin=$out/bin/$(basename $bin)
       echo "${lib.getExe pkgs.nixgl.nixGLIntel} ${
         lib.getExe pkgs.nixgl.nixVulkanIntel
       } $bin \$@" > $wrapped_bin
       chmod +x $wrapped_bin
      done
    '';

here you can see what I have done so you can easly set it up
rengare/dotfiles

[Smona]

I have been following a similar approach, but combining pkgs.symlinkJoin with pkgs.makeWrapper. Unfortunately, this fails for firefox in home manager, since home manager tries to override the package 😢.

error: attribute 'override' missing

       at /nix/store/xadqf1cap0pvxsx2yyyk57wm13fyir6x-source/modules/programs/firefox.nix:502:9:

          501|       else if versionAtLeast config.home.stateVersion "19.09" then
          502|         cfg.package.override (old: { cfg = old.cfg or { } // fcfg; })
             |         ^
          503|       else

[Smona]

Okay! After lots of hacking around I think I've found a way to solve this problem in the general case.

In one of my home-manager modules, I define this option, which i set per-machine to something like ${nixGL.packages.x86_64-linux.nixGLIntel}/bin/nixGLIntel:

{
  options.nixGLPrefix = lib.mkOption {
    type = lib.types.str;
    default = "";
    description = ''
      Will be prepended to commands which require working OpenGL.

      This needs to be set to the right nixGL package on non-NixOS systems.
    '';
  };
}

Then, I use this function to wrap any packages that I want to be run in the nixGL context:

# Call once on import to load global context
{ pkgs, config }:

# Wrap a single package
pkg:

if config.nixGLPrefix == "" then
  pkg
else
# Wrap the package's binaries with nixGL, while preserving the rest of
# the outputs and derivation attributes.
  (pkg.overrideAttrs (old: {
    name = "nixGL-${pkg.name}";
    buildCommand = ''
      set -eo pipefail

      ${
      # Heavily inspired by https://stackoverflow.com/a/68523368/6259505
      pkgs.lib.concatStringsSep "\n" (map (outputName: ''
        echo "Copying output ${outputName}"
        set -x
        cp -rs --no-preserve=mode "${pkg.${outputName}}" "''$${outputName}"
        set +x
      '') (old.outputs or [ "out" ]))}

      rm -rf $out/bin/*
      shopt -s nullglob # Prevent loop from running if no files
      for file in ${pkg.out}/bin/*; do
        echo "#!${pkgs.bash}/bin/bash" > "$out/bin/$(basename $file)"
        echo "exec -a \"\$0\" ${config.nixGLPrefix} $file \"\$@\"" >> "$out/bin/$(basename $file)"
        chmod +x "$out/bin/$(basename $file)"
      done
      shopt -u nullglob # Revert nullglob back to its normal default state
    '';
  }))

And here is an example of how I would use it:

let nixGL = import ./nixGL.nix { inherit pkgs config; };
in {
    home.packages = with pkgs;
      [
        (nixGL keybase-gui)
        (nixGL spotify)
        (nixGL vlc)
        # ...
      ];

        programs.chromium = {
          enable = true;
          package = (nixGL pkgs.chromium);
        };
}

This has worked for me for every GUI app I install with nix on Ubuntu 22. I'm using it for firefox, kitty, and the emacs-community-overlay with doom emacs, all of which are passed into their respective home manager modules and decorated with additional options after they're wrapped.

Basically, it wraps the passed derivation, preserving every attribute except the build command, which symlinks all the derivation output files to $out, and overrides solely the binary outputs to be wrapper scripts which pass the original binary file into the configured nixGL prefix.

I think with a little more work, this function could be modified to directly take a nixGLPrefix option, rather than config, and could be packaged with nixGL for user consumption.

Pros:

• Since the binary files themselves are replaced, the binaries will be launched with nixGL regardless of how they are launched, without the need for aliases.
• No dependency on home-manager.
• Does not trigger any rebuilds, binary cache can still be used for everything and the wrapper derivation is fast to build.

Cons / TODO:

• This does cause all the buildInputs of the passed packages to be fetched from the binary cache. This is an acceptable tradeoff for me, since disk space & bandwidth are cheap for me. But I'd like to explore overriding all the other build phases so that buildInputs can be zeroed out for the wrapper derivation. This should make the wrapper completely transparent.

[lamarios]

Do you mind explaning this:

{
  options.nixGLPrefix = lib.mkOption {
    type = lib.types.str;
    default = "";
    description = ''
      Will be prepended to commands which require working OpenGL.

      This needs to be set to the right nixGL package on non-NixOS systems.
    '';
  };
}

Where this should go ?

I'm using flakes so i can handle multiple users/machines. Does it go into the modules array for each homeManagerConfiguration ?

Edit: I've managed to make it work without this option by using nixGLDefault in the nixGL wrapper as below:

# Call once on import to load global context
{ pkgs, config }:

# Wrap a single package
pkg:

#if config.nixGLPrefix == "" then
#  pkg
#else
# Wrap the package's binaries with nixGL, while preserving the rest of
# the outputs and derivation attributes.
  (pkg.overrideAttrs (old: {
    name = "nixGL-${pkg.name}";
    buildCommand = ''
      set -eo pipefail

      ${
      # Heavily inspired by https://stackoverflow.com/a/68523368/6259505
      pkgs.lib.concatStringsSep "\n" (map (outputName: ''
        echo "Copying output ${outputName}"
        set -x
        cp -rs --no-preserve=mode "${pkg.${outputName}}" "''$${outputName}"
        set +x
      '') (old.outputs or [ "out" ]))}

      rm -rf $out/bin/*
      shopt -s nullglob # Prevent loop from running if no files
      for file in ${pkg.out}/bin/*; do
        echo "#!${pkgs.bash}/bin/bash" > "$out/bin/$(basename $file)"
        echo "exec -a \"\$0\" ${pkgs.nixgl.auto.nixGLDefault}/bin/nixGL $file \"\$@\"" >> "$out/bin/$(basename $file)"
        chmod +x "$out/bin/$(basename $file)"
      done
      shopt -u nullglob # Revert nullglob back to its normal default state
    '';
  }))

[Smona]

@lamarios I would recommend reading the docs about writing home manager modules, or more specifically NixOS modules. You can either add the option to your home.nix file and wrap the rest of your config in a config attribute, or better yet create a new file (module), and import it into your home.nix:

# options.nix
{ lib, ... }:

{
  options.nixGLPrefix = lib.mkOption {
    type = lib.types.str;
    default = "";
    description = ''
      Will be prepended to commands which require working OpenGL.

      This needs to be set to the right nixGL package on non-NixOS systems.
    '';
  };
}

# home.nix
{
  imports = [ ./options.nix ];
  # ...
}

[rengare]

@lamarios take a look at my dotfiles https://github.com/rengare/dotfiles/tree/main/nix

[lamarios]

Thanks both, managed to get it working. I have a bit of a hard time with how things come together in nix. I didn't know that just importing the options.nix file would actually make the option available just like that.

[bayazidbh]

So, how is the home-manager support going to look like? For example, aagl-on-nix and nix-gaming both works on a simple import, then the modules and pkgs are available to access with a prefix, and that's honestly a lot easier than learning how flakes works (I still don't really get it -- anyone have an article with good examples?).