feat(sugar): support chain cmp, e.g. 1<x<3

Author: litlighilit

src/pylib/pysugar/stmt/chainCmp.nim

@@ -0,0 +1,58 @@
+
+import std/macros
+from std/strutils import nimIdentNormalize, toLowerAscii
+
+proc isOfComparisions(op: NimNode): bool =
+  ##[ "<" | ">" | "==" | ">=" | "<=" | "!="
+                  | "is" ["not"] | ["not"] "in"]##
+  if not op.len == 0: return
+  let sop = $op
+  case sop.len
+  of 1:
+    sop[0] in {'<', '>'}
+  of 2:
+    sop in ["==", ">=", "<=", "!="] or
+      sop[0] == 'i' and sop[1].toLowerAscii in {'s', 'n'}  # is/in
+  else:
+    sop.nimIdentNormalize in ["is_not", "not_in"]
+
+proc newInfix(op, l, r: NimNode): NimNode = nnkInfix.newTree(op, l, r)
+
+proc expandChainImpl(resStmt: NimNode, cExp: NimNode): NimNode =
+  let
+    op = cExp[0]
+    lhs = cExp[1]
+    rhs = cExp[2]
+  template shallChain: bool =
+    lhs.len == 3 and op.isOfComparisions and lhs[0].isOfComparisions
+  if shallChain:
+    let med = lhs[2]
+    if med.len != 0:
+      let id = genSym(nskLet, "cmpMed")
+      resStmt.add newLetStmt(id, med)
+      lhs[2] = id
+    nnkInfix.newTree(bindSym"and",
+      expandChainImpl(resStmt, lhs),
+      newInfix(op, lhs[2], rhs))
+  else:  # if isCmpOp: # but lhs is not
+    cExp
+
+proc expandChainImpl*(cExp: NimNode): NimNode =
+  result = newStmtList()
+  result.add expandChainImpl(result, cExp)
+
+macro expandChain*(cExp): bool =
+  expectKind cExp, nnkInfix
+  expandChainImpl(cExp)
+
+when isMainModule:
+  template tCmp(m) =
+    assert expandChain(1 < m <= 3)
+    assert expandChain(1 < m > 2)
+  tCmp 3
+  var g = 0
+  proc f(): int =
+    g.inc
+    3
+  tCmp f()
+  assert g == 2, $g

src/pylib/pysugar/stmt/exprRewrite.nim

@@ -4,7 +4,7 @@ import std/macrocache
 from std/strutils import toLowerAscii, normalize
 import ../../pystring/[strimpl, strprefix]
 import ../../builtins/[list_decl, set, dict, pyslice]
-import ./frame
+import ./frame, ./chainCmp
 
 const CollectionSyms = CacheSeq"CollectionSyms"
 static:
@@ -153,17 +153,25 @@ proc toTuple(mparser; e): NimNode =
   for i in e:
     result.add mparser.toPyExpr i
 
-proc rewriteEqualMinus(mparser; e; k=nnkAsgn): NimNode =
+proc tryRewriteEqualMinus(mparser; e; res: var NimNode; k=nnkAsgn): bool =
   ## x==-1 -> x == -1
   ## x=-1 -> x = -1
 
   let lhs = mparser.toPyExpr e[1]
   template rhs: NimNode = newCall("-", mparser.toPyExpr e[2])
+  template ret(n: NimNode) =
+    res = n
+    return true
   if e[0].eqIdent"=-":
-    k.newTree lhs, rhs
+    ret k.newTree(lhs, rhs)
   elif e[0].eqIdent"==-":
-    newCall "==", lhs, rhs
-  else: e
+    ret newCall("==", lhs, rhs)
+
+
+proc rewriteInfix(mparser; e; k=nnkAsgn): NimNode =
+  if mparser.tryRewriteEqualMinus(e, result, k=k):
+    return
+  result = expandChainImpl(e)
 
 proc callToPyExpr*(mparser; e): NimNode
 
@@ -182,7 +190,7 @@ template toPyExprImpl(mparser; atm: NimNode; toListCb; equalMinusAs=nnkAsgn): Ni
   of nnkPar:
     nnkPar.newTree mparser.toPyExpr atm[0]
   of nnkInfix:
-    mparser.rewriteEqualMinus atm, equalMinusAs
+    mparser.rewriteInfix atm, equalMinusAs
 
   of nnkTripleStrLit,
       nnkStrLit, nnkRStrLit: