forked from unfrozen/stm8_libs
-
Notifications
You must be signed in to change notification settings - Fork 2
/
lib_bindec.c
429 lines (373 loc) · 7.05 KB
/
lib_bindec.c
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
/*
* File name: lib_bindec.c
* Date first: 12/22/2017
* Date last: 12/18/2018
*
* Description: Library of binary/decimal functions for STM8
*
* Author: Richard Hodges
*
* Copyright (C) 2017, 2018 Richard Hodges. All rights reserved.
* Permission is hereby granted for any use.
*
******************************************************************************
*
* SDCC and COSMIC have different calling conventions.
* Define SDCC here or in the Makefile, COSMIC defaults otherwise.
*/
#ifndef __SDCC
#define COSMIC
#endif
/******************************************************************************
*
* Binary to decimal, terminate with zero
*
* in: binary (16 bits), 5 char buffer
*/
void bin16_dec(short bin, char *dec)
{
bin, dec;
#ifdef __SDCC
__asm
ldw x, (3, sp)
#endif
#ifdef COSMIC
#asm /* binary provided in X */
#endif
sub sp, #4
ldw y, #10000
divw x, y
ld a, xl
add a, #'0'
ld (1, sp), a
ldw x, #1000
exgw x, y
divw x, y
ld a, xl
add a, #'0'
ld (2, sp), a
ldw x, #100
exgw x, y
divw x, y
ld a, xl
add a, #'0'
ld (3, sp), a
ldw x, #10
exgw x, y
divw x, y
ld a, xl
add a, #'0'
ld (4, sp), a
ld a, yl
add a, #'0'
#ifdef __SDCC
ldw x, (9, sp) /* decimal buffer */
#endif
#ifdef COSMIC
ldw x, (10, sp)
#endif
ld (4, x), a
ldw y, (1, sp)
ldw (0, x), y
ldw y, (3, sp)
ldw (2, x), y
clr (5, x)
add sp, #4
#ifdef __SDCC
__endasm;
#endif
#ifdef COSMIC
#endasm
#endif
}
/******************************************************************************
*
* Binary to decimal, terminate with zero
*
* in: binary (32 bits), 10 char buffer
*/
void bin32_dec(long bin, char *dec)
{
bin, dec;
#ifdef __SDCC
__asm
ldw x, (7, sp) ; decimal buffer pointer
ldw y, sp
addw y, #3 ; 32 bit binary on stack
clr (x) ; zero the BCD area
clr (1, x)
clr (2, x)
clr (3, x)
clr (4, x)
sub sp, #2
ld a, #32
ld (1, sp), a
00001$:
ld a, #5
ld (2, sp), a
00002$:
ld a, #0x33 ; assume DAA is needed
add a, (x)
jrmi 00003$ ; N set if nybble was 5-9
sub a, #0x30 ; nybble was 0-4, so undo DAA
00003$:
add a, #8 ; push bit-3 into HC
jrh 00004$
sub a, #3 ; undo DAA
00004$:
sub a, #8 ; undo add #8 above
ld (x), a
incw x
dec (2, sp)
jrne 00002$
subw x, #5
rlc (3, y) ; rotate 32 bit binary into BCD
rlc (2, y)
rlc (1, y)
rlc (y)
rlc (4, x)
rlc (3, x)
rlc (2, x)
rlc (1, x)
rlc (x)
dec (1, sp)
jrne 00001$
ldw y, x
addw y, #9
addw x, #4
ld a, #5
ld (1, sp), a
00005$:
ld a, (x)
and a, #0x0f
add a, #'0'
ld (y), a
decw y
ld a, (x)
swap a
and a, #0x0f
add a, #'0'
ld (y), a
decw y
decw x
dec (1, sp)
jrne 00005$
clr (11, y)
add sp, #2
__endasm;
#endif /* SDCC */
#ifdef COSMIC
#asm
ldw x, (8, sp) ; decimal buffer pointer
ldw y, sp
addw y, #4 ; 32 bit binary on stack
clr (x) ; zero the BCD area
clr (1, x)
clr (2, x)
clr (3, x)
clr (4, x)
sub sp, #2
ld a, #32
ld (1, sp), a
bit_loop:
ld a, #5
ld (2, sp), a
bcd_loop:
ld a, #0x33 ; assume DAA is needed
add a, (x)
jrmi daa_h ; N set if nybble was 5-9
sub a, #0x30 ; nybble was 0-4, so undo DAA
daa_h:
add a, #8 ; push bit-3 into HC
jrh daa_l
sub a, #3 ; undo DAA
daa_l:
sub a, #8 ; undo add #8 above
ld (x), a
incw x
dec (2, sp)
jrne bcd_loop
subw x, #5
rlc (3, y) ; rotate 32 bit binary into BCD
rlc (2, y)
rlc (1, y)
rlc (y)
rlc (4, x)
rlc (3, x)
rlc (2, x)
rlc (1, x)
rlc (x)
dec (1, sp)
jrne bit_loop
ldw y, x
addw y, #9
addw x, #4
ld a, #5
ld (1, sp), a
ascii_loop:
ld a, (x)
and a, #0x0f
add a, #'0'
ld (y), a
decw y
ld a, (x)
swap a
and a, #0x0f
add a, #'0'
ld (y), a
decw y
decw x
dec (1, sp)
jrne ascii_loop
clr (11, y)
add sp, #2
#endasm
#endif /* COSMIC */
}
/******************************************************************************
*
* Trim leading zeroes from decimal buffer
* in: buffer, maximum zeroes to remove
* out: first non-zero digit
*/
char *decimal_rlz(char *buf, char max)
{
while (max) {
if (*buf != '0')
break;
*buf = ' ';
buf++;
max--;
}
return buf;
}
/******************************************************************************
*
* * Combine 16 bit binary to decimal and remove leading zeroes
* in: 16 bit binary, 6 digit buffer
* out: first non-zero digit
*/
char *bin16_dec_rlz(short bin, char *dec)
{
bin16_dec(bin, dec);
return decimal_rlz(dec, 4);
}
/******************************************************************************
*
* Convert 8 bit unsigned binary to 2 digit decimal, terminate with zero
*/
void bin8_dec2(char bin, char *dec)
{
bin, dec;
__asm
clrw x
ld a, (3, sp)
ldw y, (4, sp)
ld xl, a
ld a, #100
div x, a
exg a, xl
ld a, #10
div x, a
or a, #'0'
ld (1, y), a
exg a, xl
or a, #'0'
ld (y), a
clr (2, y)
__endasm;
}
/******************************************************************************
*
* Convert binary byte to hex, terminate with zero
* in: binary, buffer
*/
void bin8_hex(char val, char *hex)
{
#ifdef __SDCC
val, hex;
__asm
ldw x, (4, sp)
ld a, (3, sp)
swap a
and a, #0x0f
add a, #6
jrh 00001$
sub a, #7
00001$:
add a, #'0'+1
ld (x), a
ld a, (3, sp)
and a, #0x0f
add a, #6
jrh 00002$
sub a, #7
00002$:
add a, #'0'+1
ld (1, x), a
clr (2, x)
__endasm;
#else
*hex = val >> 4;
if (*hex > 9)
*hex += 7;
*hex += '0';
hex++;
*hex = val & 0x0f;
if (*hex > 9)
*hex += 7;
*hex += '0';
hex++;
*hex = 0;
#endif
}
/******************************************************************************
*
* Convert ASCII decimal digits to 16-bit binary
* Stops on first non-decimal character
*/
#pragma disable_warning 59
int dec_bin16(char *dec)
{
dec;
__asm
ldw y, (3, sp)
clrw x
pushw x
00001$:
ld a, (y)
incw y
sub a, #'0'
jrc 00090$
cp a, #10
jrnc 00090$
ldw x, (1, sp)
sllw x
sllw x
addw x, (1, sp)
sllw x
ldw (1, sp), x
add a, (2, sp)
ld (2, sp), a
jrnc 00001$
inc (1, sp)
jra 00001$
00090$:
ldw x, (1, sp)
add sp, #2
__endasm;
}
/******************************************************************************
*
* Convert ASCII decimal digits to 16-bit binary
* Digits may be preceded with sign
* Stops on first non-decimal character
*/
int dec_bin16s(char *dec)
{
if (*dec == '-')
return -dec_bin16(dec + 1);
if (*dec == '+')
dec++;
return dec_bin16(dec);
}