build.gradle

// FYI: this is actually gen/templates/libraries/okhttp-gson/build.gradle.mustache
buildscript {
    repositories {
        mavenCentral()
    }
    dependencies {
    }
}

plugins {
    id 'idea'
    id 'signing'
    id 'java'
    id 'maven-publish'
    id('io.github.gradle-nexus.publish-plugin') version '1.1.0'
}

group = 'com.mux'
version = '0.17.0'

repositories {
    mavenCentral()
}
sourceSets {
    main.java.srcDirs = ['src/main/java']
}


sourceCompatibility = JavaVersion.VERSION_1_8
targetCompatibility = JavaVersion.VERSION_1_8

tasks.named('jar') {
    archiveBaseName = 'mux-sdk-java'
}

java {
    withSourcesJar()
    withJavadocJar()
}

nexusPublishing {
    repositories {
        sonatype()
    }
}

publishing {
    publications {
        mavenJava(MavenPublication) {
            from(components.java)
            pom {
                groupId = 'com.mux'
                name = 'mux-sdk-java'
                description = 'Mux SDK for Java'
                url = 'https://github.com/muxinc/mux-java'
                licenses {
                    license {
                        name = 'MIT'
                        url = 'http://www.apache.org/licenses/LICENSE-2.0.txt'
                    }
                }
                developers {
                    developer {
                        id = 'mux-sdk'
                        name = 'Mux DevEx Team'
                    }
                }
                scm {
                    url = 'https://github.com/muxinc/mux-java'
                    connection = 'scm:git://github.com/muxinc/mux-java.git'
                    developerConnection = 'scm:git://github.com/muxinc/mux-java.git'
                }
            }
        }
    }
}

signing {
    def signingKey = findProperty("signingKey")
    def signingPassword = findProperty("signingPassword")

    useInMemoryPgpKeys(signingKey, signingPassword)
    sign publishing.publications.mavenJava
}

task execute(type:JavaExec) {
    mainClass = System.getProperty('mainClass')
    classpath = sourceSets.main.runtimeClasspath
}

dependencies {
    implementation 'io.swagger:swagger-annotations:1.5.24'
    implementation "com.google.code.findbugs:jsr305:3.0.2"
    implementation 'com.squareup.okhttp3:okhttp:3.14.7'
    implementation 'com.squareup.okhttp3:logging-interceptor:3.14.7'
    implementation 'com.google.code.gson:gson:2.8.6'
    implementation 'io.gsonfire:gson-fire:1.8.4'
    implementation group: 'org.apache.commons', name: 'commons-lang3', version: '3.10'
    implementation 'javax.annotation:javax.annotation-api:1.3.2'
    testImplementation 'com.google.guava:guava:30.1.1-jre'
    testImplementation 'junit:junit:4.13.1'
}

javadoc {
    options.tags = [ "http.response.details:a:Http Response Details" ]
}