build.gradle

plugins {
    id 'org.springframework.boot' version '2.6.3'
    id 'io.spring.dependency-management' version '1.0.11.RELEASE'
    id 'java'
    id 'jacoco'
    id 'scala'
    id 'io.gatling.gradle' version '3.7.4'
    id 'org.sonarqube' version '3.3'
}

group = 'ch.uzh.ifi.access'
version = '0.0.1-SNAPSHOT'

dependencies {
    implementation 'org.scala-lang:scala-library:2.13.6'
    implementation 'com.fasterxml.jackson.datatype:jackson-datatype-jsr310:2.13.1'
    implementation 'com.fasterxml.jackson.dataformat:jackson-dataformat-yaml:2.13.1'

    // Spring Framework
    implementation 'org.springframework.boot:spring-boot-starter-web:2.6.3'
    implementation 'org.springframework.boot:spring-boot-starter-security:2.6.3'
    implementation 'org.springframework.boot:spring-boot-starter-data-mongodb:2.6.3'
    implementation 'org.springframework.boot:spring-boot-starter-aop:2.6.3'
    implementation 'org.springframework.boot:spring-boot-configuration-processor:2.6.3'
    testImplementation 'org.springframework.boot:spring-boot-starter-test:2.6.3'
    implementation 'org.springframework.security.oauth.boot:spring-security-oauth2-autoconfigure:2.6.3'
    implementation 'org.springframework.boot:spring-boot-starter-oauth2-resource-server:2.6.3'
    implementation 'org.springframework.security:spring-security-test:5.6.1'
    implementation 'org.springframework.statemachine:spring-statemachine-core:3.0.1'
    implementation 'org.springframework.retry:spring-retry:1.3.1'
    annotationProcessor 'org.springframework.boot:spring-boot-configuration-processor:2.6.3'
    developmentOnly 'org.springframework.boot:spring-boot-devtools:2.6.3'

    // JGit
    implementation 'org.eclipse.jgit:org.eclipse.jgit:6.0.0.202111291000-r'
    implementation 'org.eclipse.jgit:org.eclipse.jgit.ssh.jsch:6.0.0.202111291000-r'

    // Keycloak
    implementation 'org.keycloak:keycloak-spring-boot-starter:16.1.0'
    implementation 'org.keycloak.bom:keycloak-adapter-bom:16.1.0'
    implementation 'org.keycloak:keycloak-admin-client:16.1.0'

    // Lombok
    implementation 'org.projectlombok:lombok:1.18.22'
    annotationProcessor 'org.projectlombok:lombok:1.18.22'
    implementation 'com.google.flogger:flogger:0.7.4'

    // Open API
    implementation 'org.springdoc:springdoc-openapi-ui:1.6.4'
    implementation 'org.springdoc:springdoc-openapi-security:1.6.4'

    // Docker runner
    implementation 'com.spotify:docker-client:8.16.0:shaded'

    // Gatling
    implementation 'io.gatling.highcharts:gatling-charts-highcharts:3.7.4'
}

test {
    useJUnitPlatform()
    finalizedBy jacocoTestReport

    if (project.hasProperty('excludeDockerTests')) {
        exclude '**/CodeRunnerTest.class'
        exclude '**/SubmissionCodeRunnerTest.class'
    }
}

jacocoTestReport {
    dependsOn test
    reports {
        xml.required = true
    }
}

sonarqube {
    properties {
        property "sonar.projectKey", "mp-access_Backend"
        property "sonar.organization", "access"
        property "sonar.host.url", "https://sonarcloud.io"
    }
}

/**
 * Build and push a Docker image of the backend to Docker Hub via the built-in gradle task bootBuildImage.
 * Requires 4 environment variables:
 * (1) image        - name to assign to the generated Docker image
 * (2) tag          - tag to assign to the generated Docker image
 * (3) login        - username to utilize for logging into Docker Hub
 * (4) password     - password to utilize for logging into Docker Hub
 *
 * These variables already exist when running the task on CircleCI, see .circleci/config.yml.
 */
bootBuildImage {
    if (project.hasProperty("image")) {
        imageName = project.property("image") + ":" + project.property("tag").toString().toLowerCase()
        publish = true
        docker.publishRegistry {
            username = project.property("login")
            password = project.property("password")
        }
    }
}