dependency.get_option('foo') doesn't work

[danielcjacobs]

I'm wanting to grab an option/variable from a subproject fallback, but get_option and get_variable won't work.

This is how I attempt to access the option in my main project:

bar_dep = dependency('bar', fallback: ['bar', 'bar_dep'])
opt = bar_dep.get_option('foo') # doesn't work
opt = bar_dep.get_variable('foo') # also doesn't work

This is how the dependency is declared in the subproject:

foo = get_option('foo') # even if I make the option a variable as well, still doesn't work

bar_dep = declare_dependency(link_with: bar_libs.get_static_lib(),
    include_directories: incdir,
    dependencies: deps)

Note, I believe I know what the problem is.

• get_option doesn't work because bar_dep is a dependency and not a subproject (even though the subproject is used as the fallback to satisfy the dependency).
• Additionally, get_variable doesn't work, because the subproject must pass the variable to the root project via the variables parameter inside declare_dependency. If the subproject was used via subproject() instead of dependency(), then get_variable('foo') would work.

Is my understanding correct?

Is there a way to grab the foo option in the root project without having to add it to the variables param in declare_dependency?

My thought is that if I can see the value of the subproject option via meson configure build | grep foo, there's got to be a way for me to grab the option from within my meson.build file without modifying the subproject.

[xclaesse]

Would need to be more specific about your exact use-case, usually the recommended way is to have in the subproject:

vars = ['foo=' + get_option('foo')]
bar_dep = declare_dependency(link_with: bar_lib, variables: vars)
pkg.generate(bar_lib, variables: vars)

And in the parent project:

bar_dep = dependency('bar', fallback...)
foo = bar_dep.get_variable('foo')

That way it works regardless whether bar is from subproject or pkgconfig.

[eli-schwartz]

Note, I believe I know what the problem is.

• get_option doesn't work because bar_dep is a dependency and not a subproject (even though the subproject is used as the fallback to satisfy the dependency).

No.

obj.get_option() isn't a method of anywhere. It's a function get_option().

The reason it doesn't work would, presumably, be because you got an error message stating that dependency objects don't have any such method, right? ;)

• Additionally, get_variable doesn't work, because the subproject must pass the variable to the root project via the variables parameter inside declare_dependency. If the subproject was used via subproject() instead of dependency(), then get_variable('foo') would work.

Kind of sort of maybe.

Subprojects have an obj.get_variable() method which retrieves Meson language variable assignments. These respect Meson's type system and can be various different types, maybe a string, maybe a built executable, maybe a files() object, maybe a declared dependency...

Dependencies have an obj.get_variable() method which retrieves "export variables". This corresponds to pkg-config's --variable option, which allows you to print custom variables written as text strings into a *.pc file which is installed.

declare_dependency() supports the same interface. You may write the same strings you'd write into a pkg-config dependency, into a declared dependency. This makes the two interchangeable, you can use a declared dependency from a subproject the same way you'd use a dependency installed on the system via a Linux package manager.