build.gradle

//
// Copyright (c) ZeroC, Inc. All rights reserved.
//

def demoIceGridProject(name) {
    project(name) {
        slice {
            java {
                include = ["${projectDir}"]
                srcDir = '.'
            }
        }

        sourceSets {
            main {
                java {
                    srcDir '.'
                }
            }
        }

        dependencies {
            implementation "com.zeroc:ice-compat:${project.iceArtifactVersion}"
            implementation "com.zeroc:icegrid-compat:${project.iceArtifactVersion}"
            implementation "com.zeroc:icelocatordiscovery-compat:${project.iceArtifactVersion}"
            runtimeOnly "org.apache.commons:commons-compress:1.14"
        }

        task makeDbDirs {
            doLast {
                file('db/registry').mkdirs()
                file('db/node').mkdirs()
            }
        }
        compileJava.dependsOn(makeDbDirs)

        clean {
            delete 'db'
        }

        // Don't create the default jar.
        jar.enabled = false
    }
}

demoIceGridProject(":demoIceGridSimple")
demoIceGridProject(":demoIceGridIcebox")

project(":demoIceGridSimple") {
    demoJar("client")
    demoJar("server")
}

project(":demoIceGridIcebox") {
    dependencies {
        implementation "com.zeroc:icebox-compat:${project.iceArtifactVersion}"
    }
    demoJar("client")
    demoJar("service")
    demoIceBoxServer()
}