How to read an unset infix value from another infix?

[repelliuss]

It seems like transient-args is should be used inside the body of a suffix command.
What I would like to do is take an infix value and use it to filter completions at another infix's reader slot. This may not be a good or intended way to do things and I am also open to hear about it.

[tarsius]

I don't see a problem with that approach.

[repelliuss]

Sorry for not being clear earlier.

(transient-define-argument my-value-argument ()
  "Dummy value argument."
  :class 'transient-option
  :description "Value"
  :shortarg "-v"
  :argument "--value="
  :choices '("Foo" "Zoo" "Boo")
  :always-read t)

(transient-define-argument my-reader-argument ()
  "Dummy reader argument."
  :description "Reader"
  :class 'transient-option
  :shortarg "-r"
  :argument "--reader="
  :always-read t
  :reader (lambda (_prompt _initial-input _history)
            (print (transient-arg-value "--value=" (transient-args 'my-prefix)))))

(transient-define-prefix my-prefix ()
  "Dummy prefix transient."
  ["Options"
   (my-value-argument)
   (my-reader-argument)])

my-reader-argument will print the value set (transient-set) instead of the current value of my-value-argument while the transient is active when my-reader-argument is prompted to read a value. I would like it to print latest value.

[tarsius]

I understood what you are doing, but read it as "this is what I do and it works, but I am not sure I am supposed to do that". So I didn't double-check, whether this function is supposed to handle that case.

Turns out it is not, but you can copy-past its body and only lightly modify that like so:

-(cl-mapcan #'transient--get-wrapped-value (transient-suffixes prefix))
+(cl-mapcan #'transient--get-wrapped-value (transient-suffixes transient--prefix))

I'll probably do something about this in the new year, but for now this should work.

(Of course it would be better to only get the value of the infix you are interested in, but in practice it doesn't really matter that this does more than is needed, so at least for now it should be good enough.)

[repelliuss]

It seems like transient-suffixes expects a symbol and I couldn't figure out a way to fix this or extract the value from transient--prefix.

Debugger entered--Lisp error: (wrong-type-argument symbolp #<transient-prefix transient-prefix-872dc2a090>)
  apply(debug (error (wrong-type-argument symbolp #<transient-prefix transient-prefix-872dc2a090>)))
  transient--exit-and-debug(error (wrong-type-argument symbolp #<transient-prefix transient-prefix-872dc2a090>))
  get(#<transient-prefix transient-prefix-872dc2a090> transient--prefix)
  (let ((proto (get name 'transient--prefix))) (apply #'clone proto :prototype proto :level (or (alist-get t (alist-get name transient-levels)) transient-default-level) params))
  (let ((obj (let ((proto (get name 'transient--prefix))) (apply #'clone proto :prototype proto :level (or (alist-get t (alist-get name transient-levels)) transient-default-level) params)))) (transient--setup-recursion obj) (transient-init-value obj) obj)
  transient--init-prefix(#<transient-prefix transient-prefix-872dc2a090>)
  (let ((transient--prefix (transient--init-prefix prefix))) (transient--flatten-suffixes (transient--init-suffixes prefix)))
  (if (eq transient-current-command prefix) transient-current-suffixes (let ((transient--prefix (transient--init-prefix prefix))) (transient--flatten-suffixes (transient--init-suffixes prefix))))
  transient-suffixes(#<transient-prefix transient-prefix-872dc2a090>)
  (cl-mapcan #'transient--get-wrapped-value (transient-suffixes transient--prefix))
  transient-args-active()
  (print (transient-args-active))

where

(defun transient-args-active ()
  "Return the active value of the transient prefix."
  (cl-mapcan #'transient--get-wrapped-value (transient-suffixes transient--prefix)))

[tarsius]

Right. Use this instead:

(cl-mapcan #'transient--get-wrapped-value transient--suffixes)

[repelliuss]

Thank you for your help.