build.gradle

buildscript {
    repositories {
        mavenCentral()
        maven {
            url projectRepositoriesMavenUrl
        }
    }
    dependencies {
        classpath "io.freefair.gradle:lombok-plugin:$gradlePluginLombokVersion"
        classpath "com.github.ben-manes:gradle-versions-plugin:$gradlePluginVersionsVersion"
        classpath "gradle.plugin.com.hierynomus.gradle.plugins:license-gradle-plugin:$licenseGradlePluginVersion"
        classpath "org.ajoberstar.grgit:grgit-gradle:$grgitGradlePluginVersion"
        classpath "com.diffplug.spotless:spotless-plugin-gradle:$spotlessGradlePluginVersion"
        classpath "nl.littlerobots.vcu:plugin:$versionCatalogUpdateVersion"
    }
}

apply plugin: "org.ajoberstar.grgit"
apply plugin: "com.github.ben-manes.versions"
apply plugin: "nl.littlerobots.version-catalog-update"

apply from: "gradle/grgit.gradle"
apply from: "gradle/version-catalog-update.gradle"

description = "$rootProject.name"

allprojects {
    group = "$groupPackage" as Object
    version = "$projectVersion" as Object
}

subprojects {
    apply plugin: "java"
    apply plugin: "java-library"
    apply plugin: "maven-publish"
    apply plugin: "signing"
    apply plugin: "jacoco"
    apply plugin: "com.github.ben-manes.versions"
    apply plugin: "com.github.hierynomus.license"
    apply plugin: "com.diffplug.spotless"
    // import gradle files
    apply from: "../gradle/dependencies.gradle"
    apply from: "../gradle/formatting.gradle"
    apply from: "../gradle/repositories.gradle"
    apply from: "../gradle/testing.gradle"
    //

    java {
        sourceCompatibility = "$projectSourceCompatibility" as Object
        toolchain {
            languageVersion = JavaLanguageVersion.of("$projectSourceCompatibility")
        }
    }

    javadoc {
        if(JavaVersion.current().isJava9Compatible()) {
            options.addBooleanOption("html5", true)
        }
    }

    tasks.withType(JavaCompile).configureEach { javaCompiler ->
        options.encoding = "UTF-8"
        // uncomment the next line for build with compiler argument -Xlint:deprecation
        // options.compilerArgs << "-Xlint:deprecation"
        // uncomment the next line for build with compiler argument -Xlint:unchecked
        // options.compilerArgs << "-Xlint:unchecked"
    }

}