build.gradle

plugins {
	id 'fabric-loom' version '1.1-SNAPSHOT'
	id 'maven-publish'
}

sourceCompatibility = JavaVersion.VERSION_17
targetCompatibility = JavaVersion.VERSION_17

archivesBaseName = project.archives_base_name
version = project.mod_version
group = project.maven_group


loom {
	accessWidenerPath = file("src/main/resources/quickshulker.accesswidener")
}

repositories {
	maven { url 'https://maven.fabricmc.net' }
	maven { url 'https://maven.kyrptonaught.dev' }
	maven { url "https://maven.terraformersmc.com/releases" }
}

dependencies {
	minecraft "com.mojang:minecraft:${project.minecraft_version}"
	mappings "net.fabricmc:yarn:${project.yarn_mappings}:v2"
	modImplementation "net.fabricmc:fabric-loader:${project.loader_version}"
	modImplementation "net.fabricmc.fabric-api:fabric-api:${project.fabric_version}"

	modImplementation include("net.kyrptonaught:kyrptconfig:1.5.2-1.19.4") { exclude group: "net.fabricmc.fabric-api" }

	//update modmenu when kyrptconfig is pulling old version
	modImplementation ("com.terraformersmc:modmenu:6.1.0-rc.1"){
		transitive(false)
	}

	//shulkerutils
	modImplementation 'net.kyrptonaught:shulkerutils:1.0.4-1.19'
	include 'net.kyrptonaught:shulkerutils:1.0.4-1.19'
}

tasks.withType(JavaCompile).configureEach {
	it.options.release = 17
}

java {
	withSourcesJar()
}

jar {
	from("LICENSE") {
		rename { "${it}_${project.archivesBaseName}" }
	}
}

// configure the maven publication
publishing {
	publications {
		mavenJava(MavenPublication) {
			artifactId archivesBaseName
			from components.java
		}
	}
	repositories {
		maven {
			url ='s3://maven.kyrptonaught.dev'
			credentials(AwsCredentials) {
				accessKey = System.getenv('maven-key-id')
				secretKey = System.getenv('maven-key')
			}
		}
	}
}