build.gradle

plugins {
	id 'java'
    id("org.sonarqube") version "5.1.0.4882"
	id 'jacoco'
	id "org.owasp.dependencycheck" version "8.4.3"
    id 'signing'
    id 'maven-publish'
}

group = 'com.ldiamond'
version = '2.0.0'
sourceCompatibility = '11'
targetCompatibility = '11'

configurations {
	compileOnly {
		extendsFrom annotationProcessor
	}
}

repositories {
	mavenCentral()
	maven { url 'https://repo.spring.io/milestone' }
	maven { url 'https://repo.spring.io/snapshot' }
}

dependencies {
	implementation 'com.tngtech.archunit:archunit-junit5:1.3.0'

    testImplementation 'org.junit.jupiter:junit-jupiter-api:5.11.0'
    testImplementation 'org.junit.jupiter:junit-jupiter:5.11.0'
    testRuntimeOnly 'org.junit.platform:junit-platform-launcher:1.11.0'

    // Needed to test JPA_COHESION_RESTFUL_GET_MAPPINGS - when Java 17 has a higher market share we will upgrade to Java 17 and upgrade the Spring Dependency to latest
    testCompileOnly 'org.springframework:spring-context:5.3.39'
    testCompileOnly 'org.springframework:spring-web:5.3.39'
    testCompileOnly 'jakarta.persistence:jakarta.persistence-api:3.2.0'
}

tasks.named('test') {
	useJUnitPlatform()
}

sonarqube {
    properties {
        property "sonar.host.url", "https://sonarcloud.io"
		property "sonar.projectKey", "larrydiamond_ArchitectureUnitTests"
		property "sonar.organization", "larrydiamond-github"
        property "sonar.sourceEncoding", "UTF-8"
        property "sonar.scm.disabled", "true"
    }
}

test {
    finalizedBy jacocoTestReport // report is always generated after tests run
}
jacocoTestReport {
    dependsOn test // tests are required to run before generating the report
}

jacocoTestReport {
    reports {
        xml.required = true
        csv.required = true
        html.outputLocation = layout.buildDirectory.dir('jacocoHtml')
    }
}

java {
    withJavadocJar()
    withSourcesJar()
}

ext.isReleaseVersion = !version.endsWith("SNAPSHOT")

publishing {

    repositories {

        maven {
            name = 'myRepo'
            url = layout.buildDirectory.dir("repo")
        }

        maven {
            def releaseRepo = "https://s01.oss.sonatype.org/service/local/staging/deploy/maven2/"
            def snapshotRepo = "https://s01.oss.sonatype.org/content/repositories/snapshots/"
            
            name = "OSSRH"
            url = isReleaseVersion ? releaseRepo : snapshotRepo

            allowInsecureProtocol = false
            
            credentials {
                username = findProperty("ossrhUsername") ?: System.getenv("OSSRH_USERNAME")
                password = findProperty("ossrhPassword") ?: System.getenv("OSSRH_PASSWORD")
            }
        }
    }

    publications {
        mavenJava(MavenPublication) {
            artifactId = 'architectureunittests'
            from components.java
            pom {
                name = 'architectureunittests'
                description = 'An opinionated set of reasonable common sense ArchUnit tests safe to use on all projects to keep architecture healthy'
                inceptionYear='2024'
                url = 'https://github.com/larrydiamond/architectureunittests'
                licenses {
                    license {
                        name = 'The Apache License, Version 2.0'
                        url = 'http://www.apache.org/licenses/LICENSE-2.0.txt'
                    }
                }
                developers {
                    developer {
                        id = 'ldiamond'
                        name = 'Larry Diamond'
                        email = 'ldiamond@ldiamond.com'
                    }
                }
                scm {
                    connection = 'scm:git:git://github.com/larrydiamond/architectureunittests.git'
                    developerConnection = 'scm:git:ssh://github.com:larrydiamond/architectureunittests.git'
                    url = 'https://github.com/larrydiamond/architectureunittests'
                }
            }
        }

    }
}

/* only needed when building release version
signing {
    useGpgCmd()
    sign configurations.runtimeElements
    sign publishing.publications.mavenJava
}

publishMavenJavaPublicationToMavenLocal.dependsOn signRuntimeElements
publish.dependsOn signRuntimeElements
publishMavenJavaPublicationToOSSRHRepository.dependsOn signRuntimeElements
publishMavenJavaPublicationToMyRepoRepository.dependsOn signRuntimeElements
*/