build.gradle

plugins {
    id "java"
    id "eclipse"
    id "idea"
    id "jacoco"
    id 'com.github.johnrengelman.shadow' version '1.2.3'
}

//Easy semantic version based off describe + tags
def getVersionName = { ->
    def stdout = new ByteArrayOutputStream()
    exec {
        commandLine 'git', 'describe', '--tags', '--dirty', '--long'
        standardOutput = stdout
    }
    def tagVer = stdout.toString().trim()
    def semVer = (tagVer =~ /v?([\d\.]+)/)[0][1]

    if (tagVer.contains('dev')) {
        semVer += "-SNAPSHOT"
    }
    return semVer
}

description = "Kryptnostic Spark HA Library"
group = "com.kryptnostic"
version = getVersionName()
ext.projectName = "hazelcast-spark-ha"

ext.sourceCompatibility=JavaVersion.VERSION_1_8
ext.targetCompatibility=JavaVersion.VERSION_1_8

repositories {
  // Hit the local maven repo
  mavenLocal()
  mavenCentral()
}

ext.cassandra_driver_version='3.0.2'
ext.snappy_version='1.1.2.1'
ext.lz4_version='1.3'
ext.netty_epoll_version='4.0.36.Final'
ext.netty_os_arch='linux-x86_64'
ext.spark_version='1.6.2'
ext.hazelcast_version='3.7'
ext.mockito_version='1.10.19'
ext.slf4j_version='1.7.12'
ext.log4j_version='2.5'
ext.guava_version='18.0'

configurations {
    provided
}

sourceSets {
    main.compileClasspath += configurations.provided
    test.compileClasspath += configurations.provided
    test.runtimeClasspath += configurations.provided
}

dependencies {
    provided "org.apache.spark:spark-core_2.10:${spark_version}"


    compile "com.google.guava:guava:${guava_version}"
    
    compile "com.hazelcast:hazelcast-client:${hazelcast_version}"

    compile group: "org.slf4j", name: "slf4j-api", version:"${slf4j_version}"

    compile group: 'org.apache.logging.log4j', name: 'log4j-slf4j-impl', version: "${log4j_version}" 
    compile group: 'org.apache.logging.log4j', name: 'log4j-api', version: "${log4j_version}" 
    compile group: 'org.apache.logging.log4j', name: 'log4j-core', version: "${log4j_version}" 

    testCompile 'junit:junit:4.12'
    testCompile "org.mockito:mockito-all:${mockito_version}"
 }

eclipse {
    ext.downloadSources = true
    ext.downloadJavadoc = true
    ext.sourceCompatibility=JavaVersion.VERSION_1_8
    ext.targetCompatibility=JavaVersion.VERSION_1_8
}

idea {
    ext.downloadSources = true
    ext.downloadJavadoc = true
    ext.sourceCompatibility = JavaVersion.VERSION_1_8
    ext.targetCompatibility = JavaVersion.VERSION_1_8
}

eclipse.classpath.plusConfigurations += [configurations.provided] 

task sourcesJar(type : Jar) {
  classifier = 'sources'
  from sourceSets.main.allSource
}

task javadocJar(type: Jar) {
    classifier = 'javadoc'
    from javadoc
}