build.gradle

apply plugin: 'com.android.application'

def keystorePropertiesFile = rootProject.file("keystore.properties")
def keystoreProperties = new Properties()

keystoreProperties.load(new FileInputStream(keystorePropertiesFile))

def getDropboxToken() {
    Properties properties = new Properties()
    properties.load(project.rootProject.file('settings.properties').newDataInputStream())
    return properties.getProperty("dropbox_token");
}

android {
    lintOptions {
        checkReleaseBuilds false
        abortOnError false
    }

    signingConfigs {
        config {
            keyAlias keystoreProperties['keyAlias']
            keyPassword keystoreProperties['keyPassword']
            storeFile file(keystoreProperties['storeFile'])
            storePassword keystoreProperties['storePassword']
        }
    }
    compileSdkVersion 33
    buildToolsVersion "30.0.2"
    defaultConfig {
        applicationId "com.kristurek.polskatv"
        minSdkVersion 22
        targetSdkVersion 28
        versionCode 119
        versionName "119"
        testInstrumentationRunner "androidx.test.runner.AndroidJUnitRunner"
        multiDexEnabled true
        buildConfigField "String", "DROPBOX_TOKEN", "\""+getDropboxToken()+"\""
    }
    buildTypes {
        release {
            minifyEnabled false
            proguardFiles getDefaultProguardFile('proguard-android-optimize.txt'), 'proguard-rules.pro'
            signingConfig signingConfigs.config
        }
        debug {
            signingConfig signingConfigs.config
        }
    }
    buildFeatures {
        dataBinding = true
    }
    android.applicationVariants.all { variant ->
        variant.outputs.all { output ->
            outputFileName = "polskatv-${variant.versionCode}.apk"
        }
    }
    compileOptions {
        sourceCompatibility JavaVersion.VERSION_11
        targetCompatibility JavaVersion.VERSION_11
    }
    sourceSets.test.resources.srcDirs += ["src/test/resources"]
}

dependencies {
    implementation fileTree(dir: 'libs', include: ['*.jar'])

    implementation 'androidx.appcompat:appcompat:1.4.0'

    implementation 'androidx.preference:preference:1.1.1'
    implementation 'androidx.constraintlayout:constraintlayout:2.1.2'
    implementation 'androidx.lifecycle:lifecycle-extensions:2.2.0'
    //implementation 'androidx.databinding:databinding-compiler:3.4.2'

    implementation 'com.squareup.retrofit2:retrofit:2.9.0'
    implementation 'com.squareup.retrofit2:converter-gson:2.9.0'
    implementation 'com.squareup.okhttp3:okhttp:5.0.0-alpha.3'
    implementation 'com.squareup.okhttp3:okhttp-urlconnection:5.0.0-alpha.3'

    implementation 'joda-time:joda-time:2.10.13'
    implementation 'org.greenrobot:eventbus:3.2.0'
    implementation 'org.apache.commons:commons-text:1.9'
    implementation 'org.apache.commons:commons-collections4:4.4'
    implementation 'com.dropbox.core:dropbox-core-sdk:5.0.0'
    api 'com.google.guava:guava:31.0.1-android' //remember - android, not jre

    annotationProcessor 'com.google.dagger:dagger-compiler:2.40.2'
    implementation 'com.google.dagger:dagger:2.40.2'

    androidTestImplementation 'androidx.test:runner:1.4.0'
    androidTestImplementation 'androidx.test.espresso:espresso-core:3.4.0'

    testImplementation 'junit:junit:4.13.2'
    testImplementation 'org.mockito:mockito-core:4.1.0'
    testImplementation 'org.mockito:mockito-inline:4.1.0'
    testImplementation 'com.squareup.retrofit2:retrofit-mock:2.9.0'
    testImplementation 'com.squareup.okhttp3:mockwebserver:5.0.0-alpha.3'
    testImplementation 'org.hamcrest:hamcrest-library:2.2'

    implementation 'io.reactivex.rxjava2:rxjava:2.2.21'
    implementation 'io.reactivex.rxjava2:rxandroid:2.1.1'

    implementation 'com.google.android.exoplayer:exoplayer-core:2.18.3'
    implementation 'com.google.android.exoplayer:exoplayer-ui:2.18.3'
    implementation 'com.google.android.exoplayer:exoplayer-hls:2.18.3'

    implementation 'com.google.android.material:material:1.4.0'
}