build.gradle

buildscript {

    repositories {
        mavenLocal()
        mavenCentral()
        jcenter()
    }
    dependencies {
        classpath 'org.akhikhl.wuff:wuff-plugin:0.0.12'
        classpath 'com.jfrog.bintray.gradle:gradle-bintray-plugin:0.5'
    }
}

apply plugin: 'java'
apply plugin: 'maven'
apply plugin: 'org.akhikhl.wuff.eclipse-bundle'
apply plugin: 'com.jfrog.bintray'

sourceCompatibility = 1.7
group = 'io.github.kewne'
version = '1.0.2-SNAPSHOT'

repositories {
    mavenLocal()
    mavenCentral()
}

task release {}

if (version.endsWith('RELEASE')) {
    release.dependsOn bintrayUpload
}

dependencies {
    compile (group: 'org.eclipse.birt.runtime', name: 'org.eclipse.birt.runtime', version: '4.4.1') {
        exclude module: 'flute'
    }
    compile group: 'javax.servlet', name: 'javax.servlet-api', version: '3.1.0'
    compile group: 'org.springframework', name: 'spring-webmvc', version: '4.1.2.RELEASE'
    testCompile group: 'junit', name: 'junit', version: '4.11'
}

jar {
    manifest {
        instruction 'Require-Bundle: org.eclipse.core.runtime'
        instruction 'Require-Bundle: org.eclipse.birt.report.engine'
    }
}
task wrapper(type: Wrapper) {
    gradleVersion = '2.2.1'
}

task sourceJar(type: Jar) {
    from sourceSets.main.allSource
    classifier = 'sources'
}
task javadocJar(type: Jar, dependsOn: javadoc) {
    classifier = 'javadoc'
    from javadoc.destinationDir
}

artifacts {
    archives sourceJar
    archives javadocJar
}

bintray {
    user = System.getProperty("bintray_user")
    key = System.getProperty("bintray_apikey")

    configurations = ['archives']
    dryRun = false
    publish = true
    pkg {
        repo = 'maven'
        name = 'spring-birt'
        websiteUrl = 'https://github.com/kewne/spring-birt'
        issueTrackerUrl = 'https://github.com/kewne/spring-birt/issues'
        vcsUrl = 'git@github.com:kewne/spring-birt'
        licenses = ['Apache-2.0']
        publicDownloadNumbers = true
        version {
            name = project.version
        }
    }
}