LX2K Support

Add support for the SolidRun Honeycomb LX2K board.  SolidRun build
scripts were used as a starting point.  See
https://github.com/SolidRun/lx2160a_build.git

Signed-off-by: Jon Mason <[email protected]>

Author: jonmason

COPYING.MIT

@@ -0,0 +1,17 @@
+Permission is hereby granted, free of charge, to any person obtaining a copy 
+of this software and associated documentation files (the "Software"), to deal 
+in the Software without restriction, including without limitation the rights 
+to use, copy, modify, merge, publish, distribute, sublicense, and/or sell 
+copies of the Software, and to permit persons to whom the Software is 
+furnished to do so, subject to the following conditions:
+
+The above copyright notice and this permission notice shall be included in 
+all copies or substantial portions of the Software.
+
+THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR 
+IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY, 
+FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE 
+AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER 
+LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM, 
+OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN 
+THE SOFTWARE.

README.md

@@ -0,0 +1,15 @@
+# meta-lx2k
+SolidRun Honeycomb LX2K layer for OpenEmbedded/Yocto
+
+## Available Machines
+
+* honeycomb_lx2k
+
+## Yocto (Poky) Quick Start
+
+The current setup verified to work on builds for SD card images at DDR speed of 2666
+
+```text
+MACHINE=honeycomb_lx2k bitbake core-image-minimal
+dd if=tmp/deploy/images/honeycomb_lx2k/core-image-minimal-honeycomb_lx2k.wic of=/dev/sda bs=512
+```

conf/layer.conf

@@ -0,0 +1,13 @@
+# We have a conf and classes directory, add to BBPATH
+BBPATH .= ":${LAYERDIR}"
+
+# We have a recipes-* directories, add to BBFILES
+BBFILES += "${LAYERDIR}/recipes-*/*/*.bb \
+        ${LAYERDIR}/recipes-*/*/*.bbappend"
+
+BBFILE_COLLECTIONS += "lx2k-layer"
+BBFILE_PATTERN_lx2k-layer = "^${LAYERDIR}/"
+BBFILE_PRIORITY_lx2k-layer = "5"
+
+LAYERSERIES_COMPAT_lx2k-layer = "zeus"
+

conf/machine/honeycomb_lx2k.conf

@@ -0,0 +1,36 @@
+#@TYPE: Machine
+#@NAME: SolidRun HoneyComb LX2K
+#@DESCRIPTION: A NXP LX2160A based development board
+
+require conf/machine/include/arm/arch-arm64.inc
+
+PREFERRED_PROVIDER_virtual/bootloader ?= "u-boot-lx2k"
+UBOOT_MACHINE ?= "lx2160acex7_tfa_defconfig"
+UBOOT_ENTRYPOINT = "0x80080000"
+UBOOT_DTB_LOADADDRESS = "0x90000000"
+
+PREFERRED_PROVIDER_virtual/kernel ?= "linux-lx2k"
+KERNEL_IMAGETYPE = "Image.gz"
+KERNEL_DEVICETREE = "freescale/fsl-lx2160a-cex7.dtb"
+KERNEL_CLASSES = "kernel-fitimage"
+KERNEL_IMAGETYPES = "fitImage"
+
+FIT_HASH_ALG = "crc32"
+
+MACHINE_EXTRA_RRECOMMENDS += "kernel-modules"
+EXTRA_IMAGEDEPENDS += "rcw atf ddr-phy-binary qoriq-mc-binary mc-utils"
+
+IMAGE_BOOT_FILES ?= "fsl-lx2160a-cex7.dtb fitImage"
+IMAGE_FSTYPES_append = " wic ext4"
+WKS_FILE ?= "honeycomb-lx2k-sd-image.wks"
+
+SERIAL_CONSOLES = "115200;ttyAMA0"
+
+# Available DDR speed options are 2400, 2600, 2900, and 3200
+DDR_SPEED = "2600"
+
+# Available SerDes configs are 8_5_2 (8x10g), 13_5_2 (dual 100g), or 20_5_2 (dual 40g)
+SERDES = "8_5_2"
+
+# Boot image location, sd or xspi
+BOOT = "sd"

recipes-bsp/atf/atf_1.5.bb

@@ -0,0 +1,38 @@
+DESCRIPTION = "Trusted Firmware-A for lx2k"
+LICENSE = "BSD-3-Clause"
+
+inherit deploy
+
+SRC_URI = "git://source.codeaurora.org/external/qoriq/qoriq-components/atf;protocol=https;nobranch=1 \
+	   file://0001-plat-nxp-Add-lx2160acex7-module-support.patch \
+	  "
+SRCREV = "7faac4fc1f375442ec19e468471d43684c9821ca"
+
+LIC_FILES_CHKSUM = "file://license.rst;md5=e927e02bca647e14efd87e9e914b2443"
+S = "${WORKDIR}/git"
+
+export CROSS_COMPILE = "${TARGET_PREFIX}"
+CFLAGS[unexport] = "1"
+LDFLAGS[unexport] = "1"
+AS[unexport] = "1"
+LD[unexport] = "1"
+
+#PROVIDES += "fiptool"
+DEPENDS += "u-boot-lx2k rcw"
+do_compile[depends] += "u-boot-lx2k:do_deploy"
+do_compile[depends] += "rcw:do_deploy"
+
+do_clean() {
+	oe_runmake -C ${S} distclean
+}
+
+do_compile() {
+	oe_runmake PLAT=lx2160acex7 all fip pbl BL33=${DEPLOY_DIR_IMAGE}/u-boot.bin RCW=${DEPLOY_DIR_IMAGE}/rcw_*_${DDR_SPEED}_${SERDES}_${BOOT}.bin TRUSTED_BOARD_BOOT=0 GENERATE_COT=0 BOOT_MODE=${BOOT} SECURE_BOOT=false
+}
+
+do_deploy() {
+	install -m 0644 ${S}/build/lx2160acex7/release/bl2_${BOOT}.pbl ${DEPLOYDIR}/
+	install -m 0644 ${S}/build/lx2160acex7/release/fip.bin ${DEPLOYDIR}/
+	install -m 0777 ${S}/tools/fiptool/fiptool ${DEPLOYDIR}/
+}
+addtask deploy before do_build after do_compile