forked from junegunn-x/dotfiles
-
Notifications
You must be signed in to change notification settings - Fork 0
/
Copy pathvimrc
1743 lines (1509 loc) · 56.1 KB
/
vimrc
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
" vim: set foldmethod=marker foldlevel=0 nomodeline:
" ============================================================================
" .vimrc of Junegunn Choi {{{
" ============================================================================
" Vim 8 defaults
unlet! skip_defaults_vim
silent! source $VIMRUNTIME/defaults.vim
augroup vimrc
autocmd!
augroup END
let s:darwin = has('mac')
let s:windows = has('win32') || has('win64')
let mapleader = ' '
let maplocalleader = ' '
" }}}
" ============================================================================
" VIM-PLUG BLOCK {{{
" ============================================================================
silent! if plug#begin('~/.vim/plugged')
if s:darwin
let g:plug_url_format = '[email protected]:%s.git'
else
let $GIT_SSL_NO_VERIFY = 'true'
endif
" My plugins
Plug 'junegunn/vim-easy-align'
Plug 'junegunn/vim-github-dashboard'
let g:github_dashboard = { 'username': 'junegunn' }
Plug 'junegunn/vim-emoji'
command! -range EmojiReplace <line1>,<line2>s/:\([^:]\+\):/\=emoji#for(submatch(1), submatch(0))/g
Plug 'junegunn/vim-pseudocl'
Plug 'junegunn/vim-slash'
if has('timers')
noremap <expr> <plug>(slash-after) slash#blink(2, 50)
endif
Plug 'junegunn/vim-fnr'
Plug 'junegunn/vim-peekaboo'
Plug 'junegunn/vim-journal'
Plug 'junegunn/seoul256.vim'
Plug 'junegunn/gv.vim'
function! s:gv_expand()
let line = getline('.')
GV --name-status
call search('\V'.line, 'c')
normal! zz
endfunction
autocmd! FileType GV nnoremap <buffer> <silent> + :call <sid>gv_expand()<cr>
Plug 'junegunn/goyo.vim'
Plug 'junegunn/limelight.vim'
Plug 'junegunn/vader.vim'
Plug 'junegunn/fzf', { 'do': './install --all' }
Plug 'junegunn/fzf.vim'
Plug 'junegunn/rainbow_parentheses.vim'
Plug 'junegunn/heytmux'
Plug 'junegunn/vim-after-object'
autocmd VimEnter * silent! call after_object#enable('=', ':', '#', ' ', '|')
if s:darwin
Plug 'junegunn/vim-xmark'
endif
unlet! g:plug_url_format
" Colors
Plug 'tomasr/molokai'
Plug 'chriskempson/vim-tomorrow-theme'
Plug 'morhetz/gruvbox'
let g:gruvbox_contrast_dark = 'soft'
Plug 'yuttie/hydrangea-vim'
Plug 'tyrannicaltoucan/vim-deep-space'
Plug 'AlessandroYorba/Despacio'
Plug 'cocopon/iceberg.vim'
Plug 'w0ng/vim-hybrid'
Plug 'nightsense/snow'
Plug 'nightsense/stellarized'
Plug 'arcticicestudio/nord-vim'
Plug 'nightsense/cosmic_latte'
" Edit
Plug 'tpope/vim-repeat'
Plug 'tpope/vim-surround'
Plug 'tpope/vim-endwise'
Plug 'tpope/vim-commentary'
map gc <Plug>Commentary
nmap gcc <Plug>CommentaryLine
Plug 'mbbill/undotree', { 'on': 'UndotreeToggle' }
let g:undotree_WindowLayout = 2
nnoremap U :UndotreeToggle<CR>
Plug 'vim-scripts/ReplaceWithRegister'
Plug 'AndrewRadev/splitjoin.vim'
let g:splitjoin_split_mapping = ''
let g:splitjoin_join_mapping = ''
nnoremap gss :SplitjoinSplit<cr>
nnoremap gsj :SplitjoinJoin<cr>
Plug 'AndrewRadev/switch.vim'
let g:switch_mapping = '-'
let g:switch_custom_definitions = [
\ ['MON', 'TUE', 'WED', 'THU', 'FRI']
\ ]
Plug 'sgur/vim-editorconfig'
if exists('##TextYankPost')
Plug 'machakann/vim-highlightedyank'
let g:highlightedyank_highlight_duration = 100
endif
" Browsing
Plug 'Yggdroot/indentLine', { 'on': 'IndentLinesEnable' }
autocmd! User indentLine doautocmd indentLine Syntax
let g:indentLine_color_term = 239
let g:indentLine_color_gui = '#616161'
Plug 'scrooloose/nerdtree', { 'on': 'NERDTreeToggle' }
augroup nerd_loader
autocmd!
autocmd VimEnter * silent! autocmd! FileExplorer
autocmd BufEnter,BufNew *
\ if isdirectory(expand('<amatch>'))
\| call plug#load('nerdtree')
\| execute 'autocmd! nerd_loader'
\| endif
augroup END
Plug 'majutsushi/tagbar', { 'on': 'TagbarToggle' }
let g:tagbar_sort = 0
Plug 'justinmk/vim-gtfo'
" Git
Plug 'tpope/vim-fugitive'
nmap <Leader>g :Gstatus<CR>gg<c-n>
nnoremap <Leader>d :Gdiff<CR>
Plug 'rhysd/git-messenger.vim'
Plug 'tpope/vim-rhubarb'
Plug 'mhinz/vim-signify'
let g:signify_vcs_list = ['git']
let g:signify_skip_filetype = { 'journal': 1 }
let g:signify_sign_add = '│'
let g:signify_sign_change = '│'
let g:signify_sign_changedelete = '│'
" Lang
Plug 'kovisoft/paredit', { 'for': 'clojure' }
let g:paredit_smartjump = 1
Plug 'tpope/vim-fireplace', { 'for': 'clojure' }
Plug 'guns/vim-clojure-static'
let g:clojure_maxlines = 60
set lispwords+=match
let g:clojure_fuzzy_indent_patterns = ['^with', '^def', '^let']
Plug 'guns/vim-clojure-highlight'
Plug 'guns/vim-slamhound'
Plug 'venantius/vim-cljfmt'
let g:clj_fmt_autosave = 0
autocmd vimrc BufWritePre *.clj call cljfmt#AutoFormat()
autocmd vimrc BufWritePre *.cljc call cljfmt#AutoFormat()
Plug 'tpope/vim-bundler', { 'for': 'ruby' }
if v:version >= 800
Plug 'fatih/vim-go', { 'do': ':GoInstallBinaries' }
endif
Plug 'groenewege/vim-less'
Plug 'pangloss/vim-javascript'
Plug 'MaxMEllon/vim-jsx-pretty'
Plug 'alvan/vim-closetag'
let g:closetag_filenames = '*.js'
Plug 'kchmck/vim-coffee-script'
Plug 'slim-template/vim-slim'
Plug 'Glench/Vim-Jinja2-Syntax'
Plug 'rust-lang/rust.vim'
Plug 'tpope/vim-rails', { 'for': [] }
Plug 'derekwyatt/vim-scala'
Plug 'honza/dockerfile.vim'
Plug 'solarnz/thrift.vim'
Plug 'dag/vim-fish'
Plug 'chrisbra/unicode.vim', { 'for': 'journal' }
Plug 'octol/vim-cpp-enhanced-highlight'
Plug 'mzlogin/vim-markdown-toc'
if v:version >= 800 && !s:windows
Plug 'python-mode/python-mode', { 'for': 'python', 'branch': 'develop' }
Plug 'iamcco/markdown-preview.nvim', { 'do': ':call mkdp#util#install()', 'for': 'markdown', 'on': 'MarkdownPreview' }
Plug 'neoclide/coc.nvim', {'do': { -> coc#util#install() }}
endif
" Lint
Plug 'w0rp/ale'
let g:ale_linters = {'java': [], 'yaml': [], 'scala': [], 'clojure': []}
let g:ale_fixers = {'ruby': ['rubocop']}
let g:ale_lint_delay = 1000
nmap ]a <Plug>(ale_next_wrap)
nmap [a <Plug>(ale_previous_wrap)
call plug#end()
endif
" }}}
" ============================================================================
" BASIC SETTINGS {{{
" ============================================================================
set nu
set autoindent
set smartindent
set lazyredraw
set laststatus=2
set showcmd
set visualbell
set backspace=indent,eol,start
set timeoutlen=500
set whichwrap=b,s
set shortmess=aIT
set hlsearch " CTRL-L / CTRL-R W
set incsearch
set hidden
set ignorecase smartcase
set wildmenu
set wildmode=full
set tabstop=2
set shiftwidth=2
set expandtab smarttab
set scrolloff=5
set encoding=utf-8
set list
set listchars=tab:\|\ ,
set virtualedit=block
set nojoinspaces
set diffopt=filler,vertical
set autoread
set clipboard=unnamed
set foldlevelstart=99
set grepformat=%f:%l:%c:%m,%f:%l:%m
set completeopt=menuone,preview
set nocursorline
set nrformats=hex
silent! set cryptmethod=blowfish2
set formatoptions+=1
if has('patch-7.3.541')
set formatoptions+=j
endif
if has('patch-7.4.338')
let &showbreak = '↳ '
set breakindent
set breakindentopt=sbr
endif
if has('termguicolors')
let &t_8f = "\<Esc>[38;2;%lu;%lu;%lum"
let &t_8b = "\<Esc>[48;2;%lu;%lu;%lum"
set termguicolors
endif
function! s:statusline_expr()
let mod = "%{&modified ? '[+] ' : !&modifiable ? '[x] ' : ''}"
let ro = "%{&readonly ? '[RO] ' : ''}"
let ft = "%{len(&filetype) ? '['.&filetype.'] ' : ''}"
let fug = "%{exists('g:loaded_fugitive') ? fugitive#statusline() : ''}"
let sep = ' %= '
let pos = ' %-12(%l : %c%V%) '
let pct = ' %P'
return '[%n] %F %<'.mod.ro.ft.fug.sep.pos.'%*'.pct
endfunction
let &statusline = s:statusline_expr()
set modelines=2
set synmaxcol=1000
" For MacVim
set noimd
set imi=1
set ims=-1
" ctags
set tags=./tags;/
" Annoying temporary files
set backupdir=/tmp//,.
set directory=/tmp//,.
" Semi-persistent undo
if has('persistent_undo')
set undodir=/tmp,.
set undofile
endif
" Shift-tab on GNU screen
" http://superuser.com/questions/195794/gnu-screen-shift-tab-issue
set t_kB=[Z
" set complete=.,w,b,u,t
set complete-=i
" mouse
silent! set ttymouse=xterm2
set mouse=a
" 80 chars/line
set textwidth=0
if exists('&colorcolumn')
set colorcolumn=80
endif
" Keep the cursor on the same column
set nostartofline
" FOOBAR=~/<CTRL-><CTRL-F>
set isfname-==
if exists('&fixeol')
set nofixeol
endif
silent! colo seoul256
if has('nvim')
" https://github.com/neovim/neovim/issues/2897#issuecomment-115464516
let g:terminal_color_0 = '#4e4e4e'
let g:terminal_color_1 = '#d68787'
let g:terminal_color_2 = '#5f865f'
let g:terminal_color_3 = '#d8af5f'
let g:terminal_color_4 = '#85add4'
let g:terminal_color_5 = '#d7afaf'
let g:terminal_color_6 = '#87afaf'
let g:terminal_color_7 = '#d0d0d0'
let g:terminal_color_8 = '#626262'
let g:terminal_color_9 = '#d75f87'
let g:terminal_color_10 = '#87af87'
let g:terminal_color_11 = '#ffd787'
let g:terminal_color_12 = '#add4fb'
let g:terminal_color_13 = '#ffafaf'
let g:terminal_color_14 = '#87d7d7'
let g:terminal_color_15 = '#e4e4e4'
set fillchars=vert:\|,fold:-
autocmd BufReadPost *
\ if line("'\"") >= 1 && line("'\"") <= line("$") |
\ exe "normal! g`\"" |
\ endif
else
let g:terminal_ansi_colors = [
\ '#4e4e4e', '#d68787', '#5f865f', '#d8af5f',
\ '#85add4', '#d7afaf', '#87afaf', '#d0d0d0',
\ '#626262', '#d75f87', '#87af87', '#ffd787',
\ '#add4fb', '#ffafaf', '#87d7d7', '#e4e4e4']
endif
" }}}
" ============================================================================
" MAPPINGS {{{
" ============================================================================
" ----------------------------------------------------------------------------
" Basic mappings
" ----------------------------------------------------------------------------
noremap <C-F> <C-D>
noremap <C-B> <C-U>
" Open new line below and above current line
nnoremap <leader>o o<esc>
nnoremap <leader>O O<esc>
" Save
inoremap <C-s> <C-O>:update<cr>
nnoremap <C-s> :update<cr>
nnoremap <leader>s :update<cr>
nnoremap <leader>w :update<cr>
" Disable CTRL-A on tmux or on screen
if $TERM =~ 'screen'
nnoremap <C-a> <nop>
nnoremap <Leader><C-a> <C-a>
endif
" Quit
inoremap <C-Q> <esc>:q<cr>
nnoremap <C-Q> :q<cr>
vnoremap <C-Q> <esc>
nnoremap <Leader>q :q<cr>
nnoremap <Leader>Q :qa!<cr>
" Tags
nnoremap <C-]> g<C-]>
nnoremap g[ :pop<cr>
" Jump list (to newer position)
nnoremap <C-p> <C-i>
" <leader>n | NERD Tree
nnoremap <leader>n :NERDTreeToggle<cr>
" jk | Escaping!
inoremap jk <Esc>
xnoremap jk <Esc>
cnoremap jk <C-c>
" Movement in insert mode
inoremap <C-h> <C-o>h
inoremap <C-l> <C-o>a
inoremap <C-j> <C-o>j
inoremap <C-k> <C-o>k
inoremap <C-^> <C-o><C-^>
" Make Y behave like other capitals
nnoremap Y y$
" qq to record, Q to replay
nnoremap Q @q
" Zoom
function! s:zoom()
if winnr('$') > 1
tab split
elseif len(filter(map(range(tabpagenr('$')), 'tabpagebuflist(v:val + 1)'),
\ 'index(v:val, '.bufnr('').') >= 0')) > 1
tabclose
endif
endfunction
nnoremap <silent> <leader>z :call <sid>zoom()<cr>
" Last inserted text
nnoremap g. :normal! `[v`]<cr><left>
" ----------------------------------------------------------------------------
" nvim
" ----------------------------------------------------------------------------
if has('nvim')
tnoremap <a-a> <esc>a
tnoremap <a-b> <esc>b
tnoremap <a-d> <esc>d
tnoremap <a-f> <esc>f
endif
" ----------------------------------------------------------------------------
" Quickfix
" ----------------------------------------------------------------------------
nnoremap ]q :cnext<cr>zz
nnoremap [q :cprev<cr>zz
nnoremap ]l :lnext<cr>zz
nnoremap [l :lprev<cr>zz
" ----------------------------------------------------------------------------
" Buffers
" ----------------------------------------------------------------------------
nnoremap ]b :bnext<cr>
nnoremap [b :bprev<cr>
" ----------------------------------------------------------------------------
" Tabs
" ----------------------------------------------------------------------------
nnoremap ]t :tabn<cr>
nnoremap [t :tabp<cr>
" ----------------------------------------------------------------------------
" <tab> / <s-tab> | Circular windows navigation
" ----------------------------------------------------------------------------
nnoremap <tab> <c-w>w
nnoremap <S-tab> <c-w>W
" ----------------------------------------------------------------------------
" tmux
" ----------------------------------------------------------------------------
function! s:tmux_send(content, dest) range
let dest = empty(a:dest) ? input('To which pane? ') : a:dest
let tempfile = tempname()
call writefile(split(a:content, "\n", 1), tempfile, 'b')
call system(printf('tmux load-buffer -b vim-tmux %s \; paste-buffer -d -b vim-tmux -t %s',
\ shellescape(tempfile), shellescape(dest)))
call delete(tempfile)
endfunction
function! s:tmux_map(key, dest)
execute printf('nnoremap <silent> %s "tyy:call <SID>tmux_send(@t, "%s")<cr>', a:key, a:dest)
execute printf('xnoremap <silent> %s "ty:call <SID>tmux_send(@t, "%s")<cr>gv', a:key, a:dest)
endfunction
call s:tmux_map('<leader>tt', '')
call s:tmux_map('<leader>th', '.left')
call s:tmux_map('<leader>tj', '.bottom')
call s:tmux_map('<leader>tk', '.top')
call s:tmux_map('<leader>tl', '.right')
call s:tmux_map('<leader>ty', '.top-left')
call s:tmux_map('<leader>to', '.top-right')
call s:tmux_map('<leader>tn', '.bottom-left')
call s:tmux_map('<leader>t.', '.bottom-right')
" ----------------------------------------------------------------------------
" Markdown headings
" ----------------------------------------------------------------------------
nnoremap <leader>1 m`yypVr=``
nnoremap <leader>2 m`yypVr-``
nnoremap <leader>3 m`^i### <esc>``4l
nnoremap <leader>4 m`^i#### <esc>``5l
nnoremap <leader>5 m`^i##### <esc>``6l
" ----------------------------------------------------------------------------
" Moving lines
" ----------------------------------------------------------------------------
nnoremap <silent> <C-k> :move-2<cr>
nnoremap <silent> <C-j> :move+<cr>
nnoremap <silent> <C-h> <<
nnoremap <silent> <C-l> >>
xnoremap <silent> <C-k> :move-2<cr>gv
xnoremap <silent> <C-j> :move'>+<cr>gv
xnoremap <silent> <C-h> <gv
xnoremap <silent> <C-l> >gv
xnoremap < <gv
xnoremap > >gv
" ----------------------------------------------------------------------------
" <Leader>c Close quickfix/location window
" ----------------------------------------------------------------------------
nnoremap <leader>c :cclose<bar>lclose<cr>
" ----------------------------------------------------------------------------
" Readline-style key bindings in command-line (excerpt from rsi.vim)
" ----------------------------------------------------------------------------
cnoremap <C-A> <Home>
cnoremap <C-B> <Left>
cnoremap <expr> <C-D> getcmdpos()>strlen(getcmdline())?"\<Lt>C-D>":"\<Lt>Del>"
cnoremap <expr> <C-F> getcmdpos()>strlen(getcmdline())?&cedit:"\<Lt>Right>"
cnoremap <M-b> <S-Left>
cnoremap <M-f> <S-Right>
silent! exe "set <S-Left>=\<Esc>b"
silent! exe "set <S-Right>=\<Esc>f"
" ----------------------------------------------------------------------------
" #gi / #gpi | go to next/previous indentation level
" ----------------------------------------------------------------------------
function! s:go_indent(times, dir)
for _ in range(a:times)
let l = line('.')
let x = line('$')
let i = s:indent_len(getline(l))
let e = empty(getline(l))
while l >= 1 && l <= x
let line = getline(l + a:dir)
let l += a:dir
if s:indent_len(line) != i || empty(line) != e
break
endif
endwhile
let l = min([max([1, l]), x])
execute 'normal! '. l .'G^'
endfor
endfunction
nnoremap <silent> gi :<c-u>call <SID>go_indent(v:count1, 1)<cr>
nnoremap <silent> gpi :<c-u>call <SID>go_indent(v:count1, -1)<cr>
" ----------------------------------------------------------------------------
" <leader>bs | buf-search
" ----------------------------------------------------------------------------
nnoremap <leader>bs :cex []<BAR>bufdo vimgrepadd @@g %<BAR>cw<s-left><s-left><right>
" ----------------------------------------------------------------------------
" #!! | Shebang
" ----------------------------------------------------------------------------
inoreabbrev <expr> #!! "#!/usr/bin/env" . (empty(&filetype) ? '' : ' '.&filetype)
" ----------------------------------------------------------------------------
" <leader>ij | Open in IntelliJ
" ----------------------------------------------------------------------------
if s:darwin
nnoremap <silent> <leader>ij :call system('nohup "/Applications/IntelliJ IDEA.app/Contents/MacOS/idea" '.expand('%:p').'> /dev/null 2>&1 < /dev/null &')<cr>
endif
" ----------------------------------------------------------------------------
" Heytmux
" ----------------------------------------------------------------------------
xnoremap <leader>ht :Heytmux<cr>
" }}}
" ============================================================================
" FUNCTIONS & COMMANDS {{{
" ============================================================================
" ----------------------------------------------------------------------------
" :NL
" ----------------------------------------------------------------------------
command! -range=% -nargs=1 NL
\ <line1>,<line2>!nl -w <args> -s '. ' | perl -pe 's/^.{<args>}..$//'
" ----------------------------------------------------------------------------
" :Chomp
" ----------------------------------------------------------------------------
command! Chomp %s/\s\+$// | normal! ``
" ----------------------------------------------------------------------------
" :Count
" ----------------------------------------------------------------------------
command! -nargs=1 Count execute printf('%%s/%s//gn', escape(<q-args>, '/')) | normal! ``
" ----------------------------------------------------------------------------
" :M
" ----------------------------------------------------------------------------
command! M execute printf('!bundle exec m %s:%d', expand('%'), line('.'))
" ----------------------------------------------------------------------------
" :CopyRTF
" ----------------------------------------------------------------------------
function! s:colors(...)
return filter(map(filter(split(globpath(&rtp, 'colors/*.vim'), "\n"),
\ 'v:val !~ "^/usr/"'),
\ 'fnamemodify(v:val, ":t:r")'),
\ '!a:0 || stridx(v:val, a:1) >= 0')
endfunction
function! s:copy_rtf(line1, line2, ...)
let [ft, cs, nu] = [&filetype, g:colors_name, &l:nu]
let lines = getline(1, '$')
tab new
setlocal buftype=nofile bufhidden=wipe nonumber
let &filetype = ft
call setline(1, lines)
doautocmd BufNewFile filetypedetect
execute 'colo' get(a:000, 0, 'seoul256-light')
hi Normal ctermbg=NONE guibg=NONE
let lines = getline(a:line1, a:line2)
let indent = repeat(' ', min(map(filter(copy(lines), '!empty(v:val)'), 'len(matchstr(v:val, "^ *"))')))
call setline(a:line1, map(lines, 'substitute(v:val, indent, "", "")'))
call tohtml#Convert2HTML(a:line1, a:line2)
g/^\(pre\|body\) {/s/background-color: #[0-9]*; //
silent %write !textutil -convert rtf -textsizemultiplier 1.3 -stdin -stdout | ruby -e 'puts STDIN.read.sub(/\\\n}$/m, "\n}")' | pbcopy
bd!
tabclose
let &l:nu = nu
execute 'colorscheme' cs
endfunction
if s:darwin
command! -range=% -nargs=? -complete=customlist,s:colors CopyRTF call s:copy_rtf(<line1>, <line2>, <f-args>)
endif
" ----------------------------------------------------------------------------
" :Root | Change directory to the root of the Git repository
" ----------------------------------------------------------------------------
function! s:root()
let root = systemlist('git rev-parse --show-toplevel')[0]
if v:shell_error
echo 'Not in git repo'
else
execute 'lcd' root
echo 'Changed directory to: '.root
endif
endfunction
command! Root call s:root()
" ----------------------------------------------------------------------------
" <F5> / <F6> | Run script
" ----------------------------------------------------------------------------
function! s:run_this_script(output)
let head = getline(1)
let pos = stridx(head, '#!')
let file = expand('%:p')
let ofile = tempname()
let rdr = " 2>&1 | tee ".ofile
let win = winnr()
let prefix = a:output ? 'silent !' : '!'
" Shebang found
if pos != -1
execute prefix.strpart(head, pos + 2).' '.file.rdr
" Shebang not found but executable
elseif executable(file)
execute prefix.file.rdr
elseif &filetype == 'ruby'
execute prefix.'/usr/bin/env ruby '.file.rdr
elseif &filetype == 'tex'
execute prefix.'latex '.file. '; [ $? -eq 0 ] && xdvi '. expand('%:r').rdr
elseif &filetype == 'dot'
let svg = expand('%:r') . '.svg'
let png = expand('%:r') . '.png'
" librsvg >> imagemagick + ghostscript
execute 'silent !dot -Tsvg '.file.' -o '.svg.' && '
\ 'rsvg-convert -z 2 '.svg.' > '.png.' && open '.png.rdr
else
return
end
redraw!
if !a:output | return | endif
" Scratch buffer
if exists('s:vim_exec_buf') && bufexists(s:vim_exec_buf)
execute bufwinnr(s:vim_exec_buf).'wincmd w'
%d
else
silent! bdelete [vim-exec-output]
silent! vertical botright split new
silent! file [vim-exec-output]
setlocal buftype=nofile bufhidden=wipe noswapfile
let s:vim_exec_buf = winnr()
endif
execute 'silent! read' ofile
normal! gg"_dd
execute win.'wincmd w'
endfunction
nnoremap <silent> <F5> :call <SID>run_this_script(0)<cr>
nnoremap <silent> <F6> :call <SID>run_this_script(1)<cr>
" ----------------------------------------------------------------------------
" <F8> | Color scheme selector
" ----------------------------------------------------------------------------
function! s:rotate_colors()
if !exists('s:colors')
let s:colors = s:colors()
endif
let name = remove(s:colors, 0)
call add(s:colors, name)
execute 'colorscheme' name
redraw
echo name
endfunction
nnoremap <silent> <F8> :call <SID>rotate_colors()<cr>
" ----------------------------------------------------------------------------
" :Shuffle | Shuffle selected lines
" ----------------------------------------------------------------------------
function! s:shuffle() range
ruby << RB
first, last = %w[a:firstline a:lastline].map { |e| VIM::evaluate(e).to_i }
(first..last).map { |l| $curbuf[l] }.shuffle.each_with_index do |line, i|
$curbuf[first + i] = line
end
RB
endfunction
command! -range Shuffle <line1>,<line2>call s:shuffle()
" ----------------------------------------------------------------------------
" Syntax highlighting in code snippets
" ----------------------------------------------------------------------------
function! s:syntax_include(lang, b, e, inclusive)
let syns = split(globpath(&rtp, "syntax/".a:lang.".vim"), "\n")
if empty(syns)
return
endif
if exists('b:current_syntax')
let csyn = b:current_syntax
unlet b:current_syntax
endif
let z = "'" " Default
for nr in range(char2nr('a'), char2nr('z'))
let char = nr2char(nr)
if a:b !~ char && a:e !~ char
let z = char
break
endif
endfor
silent! exec printf("syntax include @%s %s", a:lang, syns[0])
if a:inclusive
exec printf('syntax region %sSnip start=%s\(%s\)\@=%s ' .
\ 'end=%s\(%s\)\@<=\(\)%s contains=@%s containedin=ALL',
\ a:lang, z, a:b, z, z, a:e, z, a:lang)
else
exec printf('syntax region %sSnip matchgroup=Snip start=%s%s%s ' .
\ 'end=%s%s%s contains=@%s containedin=ALL',
\ a:lang, z, a:b, z, z, a:e, z, a:lang)
endif
if exists('csyn')
let b:current_syntax = csyn
endif
endfunction
function! s:file_type_handler()
if &ft =~ 'jinja' && &ft != 'jinja'
call s:syntax_include('jinja', '{{', '}}', 1)
call s:syntax_include('jinja', '{%', '%}', 1)
elseif &ft =~ 'mkd\|markdown'
for lang in ['ruby', 'yaml', 'vim', 'sh', 'bash=sh', 'python', 'java', 'c',
\ 'clojure', 'clj=clojure', 'scala', 'sql', 'gnuplot', 'json=javascript']
call s:syntax_include(split(lang, '=')[-1], '```'.split(lang, '=')[0], '```', 0)
endfor
highlight def link Snip Folded
setlocal textwidth=78
setlocal completefunc=emoji#complete
elseif &ft == 'sh'
call s:syntax_include('ruby', '#!ruby', '/\%$', 1)
endif
endfunction
" ----------------------------------------------------------------------------
" SaveMacro / LoadMacro
" ----------------------------------------------------------------------------
function! s:save_macro(name, file)
let content = eval('@'.a:name)
if !empty(content)
call writefile(split(content, "\n"), a:file)
echom len(content) . " bytes save to ". a:file
endif
endfunction
command! -nargs=* SaveMacro call <SID>save_macro(<f-args>)
function! s:load_macro(file, name)
let data = join(readfile(a:file), "\n")
call setreg(a:name, data, 'c')
echom "Macro loaded to @". a:name
endfunction
command! -nargs=* LoadMacro call <SID>load_macro(<f-args>)
" ----------------------------------------------------------------------------
" HL | Find out syntax group
" ----------------------------------------------------------------------------
function! s:hl()
" echo synIDattr(synID(line('.'), col('.'), 0), 'name')
echo join(map(synstack(line('.'), col('.')), 'synIDattr(v:val, "name")'), '/')
endfunction
command! HL call <SID>hl()
" ----------------------------------------------------------------------------
" :A
" ----------------------------------------------------------------------------
function! s:a(cmd)
let name = expand('%:r')
let ext = tolower(expand('%:e'))
let sources = ['c', 'cc', 'cpp', 'cxx']
let headers = ['h', 'hh', 'hpp', 'hxx']
for pair in [[sources, headers], [headers, sources]]
let [set1, set2] = pair
if index(set1, ext) >= 0
for h in set2
let aname = name.'.'.h
for a in [aname, toupper(aname)]
if filereadable(a)
execute a:cmd a
return
end
endfor
endfor
endif
endfor
endfunction
command! A call s:a('e')
command! AV call s:a('botright vertical split')
" ----------------------------------------------------------------------------
" Todo
" ----------------------------------------------------------------------------
function! s:todo() abort
let entries = []
for cmd in ['git grep -niI -e TODO -e FIXME -e XXX 2> /dev/null',
\ 'grep -rniI -e TODO -e FIXME -e XXX * 2> /dev/null']
let lines = split(system(cmd), '\n')
if v:shell_error != 0 | continue | endif
for line in lines
let [fname, lno, text] = matchlist(line, '^\([^:]*\):\([^:]*\):\(.*\)')[1:3]
call add(entries, { 'filename': fname, 'lnum': lno, 'text': text })
endfor
break
endfor
if !empty(entries)
call setqflist(entries)
copen
endif
endfunction
command! Todo call s:todo()
" ----------------------------------------------------------------------------
" ConnectChrome
" ----------------------------------------------------------------------------
if s:darwin
function! s:connect_chrome(bang)
augroup connect-chrome
autocmd!
if !a:bang
autocmd BufWritePost <buffer> call system(join([
\ "osascript -e 'tell application \"Google Chrome\"".
\ "to tell the active tab of its first window\n",
\ " reload",
\ "end tell'"], "\n"))
endif
augroup END
endfunction
command! -bang ConnectChrome call s:connect_chrome(<bang>0)
endif
" ----------------------------------------------------------------------------
" AutoSave
" ----------------------------------------------------------------------------
function! s:autosave(enable)
augroup autosave
autocmd!
if a:enable
autocmd TextChanged,InsertLeave <buffer>
\ if empty(&buftype) && !empty(bufname(''))
\| silent! update
\| endif
endif
augroup END
endfunction
command! -bang AutoSave call s:autosave(<bang>1)
" ----------------------------------------------------------------------------
" TX
" ----------------------------------------------------------------------------
command! -nargs=1 TX
\ call system('tmux split-window -d -l 16 '.<q-args>)
cnoremap !! TX<space>
command! GP TX git push
" ----------------------------------------------------------------------------
" EX | chmod +x
" ----------------------------------------------------------------------------
command! EX if !empty(expand('%'))
\| write
\| call system('chmod +x '.expand('%'))
\| silent e
\| else
\| echohl WarningMsg
\| echo 'Save the file first'
\| echohl None
\| endif
" ----------------------------------------------------------------------------
" Profile
" ----------------------------------------------------------------------------
function! s:profile(bang)
if a:bang
profile pause
noautocmd qall
else
profile start /tmp/profile.log
profile func *
profile file *
endif
endfunction
command! -bang Profile call s:profile(<bang>0)
" ----------------------------------------------------------------------------
" call LSD()
" ----------------------------------------------------------------------------
function! LSD()
syntax clear
for i in range(16, 255)
execute printf('highlight LSD%s ctermfg=%s', i - 16, i)
endfor
let block = 4
for l in range(1, line('$'))
let c = 1
let max = len(getline(l))
while c < max
let stride = 4 + reltime()[1] % 8
execute printf('syntax region lsd%s_%s start=/\%%%sl\%%%sc/ end=/\%%%sl\%%%sc/ contains=ALL', l, c, l, c, l, min([c + stride, max]))
let rand = abs(reltime()[1] % (256 - 16))
execute printf('hi def link lsd%s_%s LSD%s', l, c, rand)
let c += stride
endwhile
endfor
endfunction
" ----------------------------------------------------------------------------
" Open FILENAME:LINE:COL
" ----------------------------------------------------------------------------
function! s:goto_line()
let tokens = split(expand('%'), ':')
if len(tokens) <= 1 || !filereadable(tokens[0])
return
endif
let file = tokens[0]
let rest = map(tokens[1:], 'str2nr(v:val)')
let line = get(rest, 0, 1)
let col = get(rest, 1, 1)
bd!
silent execute 'e' file
execute printf('normal! %dG%d|', line, col)
endfunction
autocmd vimrc BufNewFile * nested call s:goto_line()
" ----------------------------------------------------------------------------